lib/Catalyst/Helper/Model/DBIC/Schema.pm

   1 package Catalyst::Helper::Model::DBIC::Schema;
   2
   3 use namespace::autoclean;
   4 use Moose;
   5 no warnings 'uninitialized';
   6
   7 our $VERSION = '0.24';
   8
   9 use Carp;
  10 use Tie::IxHash ();
  11 use Data::Dumper ();
  12 use List::Util 'first';
  13 use MooseX::Types::Moose qw/Str HashRef Bool ArrayRef/;
  14 use Catalyst::Model::DBIC::Schema::Types 'CreateOption';
  15 use Moose::Autobox;
  16 use List::MoreUtils 'firstidx';
  17 use Scalar::Util 'looks_like_number';
  18
  19 =head1 NAME
  20
  21 Catalyst::Helper::Model::DBIC::Schema - Helper for DBIC Schema Models
  22
  23 =head1 SYNOPSIS
  24
  25   script/create.pl model CatalystModelName DBIC::Schema MyApp::SchemaClass \
  26     [ create=dynamic | create=static ] [ traits=trait1,trait2... ] \
  27     [ Schema::Loader opts ] [ dsn user pass ] \
  28     [ other connect_info args ]
  29
  30 =head1 DESCRIPTION
  31
  32 Helper for the DBIC Schema Models.
  33
  34 =head2 Arguments:
  35
  36 C<CatalystModelName> is the short name for the Catalyst Model class
  37 being generated (i.e. callable with C<$c-E<gt>model('CatalystModelName')>).
  38
  39 C<MyApp::SchemaClass> is the fully qualified classname of your Schema,
  40 which might or might not yet exist.  Note that you should have a good
  41 reason to create this under a new global namespace, otherwise use an
  42 existing top level namespace for your schema class.
  43
  44 C<create=dynamic> instructs this Helper to generate the named Schema
  45 class for you, basing it on L<DBIx::Class::Schema::Loader> (which
  46 means the table information will always be dynamically loaded at
  47 runtime from the database).
  48
  49 C<create=static> instructs this Helper to generate the named Schema
  50 class for you, using L<DBIx::Class::Schema::Loader> in "one shot"
  51 mode to create a standard, manually-defined L<DBIx::Class::Schema>
  52 setup, based on what the Loader sees in your database at this moment.
  53 A Schema/Model pair generated this way will not require
  54 L<DBIx::Class::Schema::Loader> at runtime, and will not automatically
  55 adapt itself to changes in your database structure.  You can edit
  56 the generated classes by hand to refine them.
  57
  58 C<traits> is the list of traits to apply to the model, see
  59 L<Catalyst::Model::DBIC::Schema> for details.
  60
  61 C<Schema::Loader opts> are described in L</TYPICAL EXAMPLES> below.
  62
  63 C<connect_info> arguments are the same as what
  64 DBIx::Class::Schema::connect expects, and are storage_type-specific.
  65 For DBI-based storage, these arguments are the dsn, username,
  66 password, and connect options, respectively.  These are optional for
  67 existing Schemas, but required if you use either of the C<create=>
  68 options.
  69
  70 username and password can be omitted for C<SQLite> dsns.
  71
  72 Use of either of the C<create=> options requires L<DBIx::Class::Schema::Loader>.
  73
  74 =head1 TYPICAL EXAMPLES
  75
  76 Use DBIx::Class::Schema::Loader to create a static DBIx::Class::Schema,
  77 and a Model which references it:
  78
  79   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  80     MyApp::SchemaClass create=static dbi:mysql:foodb myuname mypass
  81
  82 Same, with extra connect_info args
  83 user and pass can be omitted for sqlite, since they are always empty
  84
  85   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  86     MyApp::SchemaClass create=static dbi:SQLite:foo.db \
  87     AutoCommit=1 cursor_class=DBIx::Class::Cursor::Cached \
  88     on_connect_do='["select 1", "select 2"]' quote_char='"'
  89
  90 If using a 2 character quote_char:
  91
  92   script/myapp_create.pl ... quote_char='[]'
  93
  94 B<ON WINDOWS COMMAND LINES QUOTING RULES ARE DIFFERENT>
  95
  96 In C<cmd.exe> the above example would be:
  97
  98   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  99     MyApp::SchemaClass create=static dbi:SQLite:foo.db \
 100     AutoCommit=1 cursor_class=DBIx::Class::Cursor::Cached \
 101     on_connect_do="[\"select 1\", \"select 2\"]" quote_char="\""
 102
 103 Same, but with extra Schema::Loader args (separate multiple values by commas):
 104
 105   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 106     MyApp::SchemaClass create=static db_schema=foodb components=Foo,Bar \
 107     exclude='^(wibble|wobble)$' moniker_map='{ foo => "FOO" }' \
 108     dbi:Pg:dbname=foodb myuname mypass
 109
 110 See L<DBIx::Class::Schema::Loader::Base> for a list of options
 111
 112 Create a dynamic DBIx::Class::Schema::Loader-based Schema,
 113 and a Model which references it (B<DEPRECATED>):
 114
 115   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 116     MyApp::SchemaClass create=dynamic dbi:mysql:foodb myuname mypass
 117
 118 Reference an existing Schema of any kind, and provide some connection information for ->config:
 119
 120   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 121     MyApp::SchemaClass dbi:mysql:foodb myuname mypass
 122
 123 Same, but don't supply connect information yet (you'll need to do this
 124 in your app config, or [not recommended] in the schema itself).
 125
 126   script/myapp_create.pl model ModelName DBIC::Schema My::SchemaClass
 127
 128 =cut
 129
 130 has helper => (is => 'ro', isa => 'Catalyst::Helper', required => 1);
 131 has create => (is => 'rw', isa => CreateOption);
 132 has args => (is => 'ro', isa => ArrayRef);
 133 has traits => (is => 'rw', isa => ArrayRef);
 134 has schema_class => (is => 'ro', isa => Str, required => 1);
 135 has loader_args => (is => 'rw', isa => HashRef);
 136 has connect_info => (is => 'rw', isa => HashRef);
 137 has old_schema => (is => 'rw', isa => Bool, lazy_build => 1);
 138 has components => (is => 'rw', isa => ArrayRef);
 139
 140 =head1 METHODS
 141
 142 =head2 mk_compclass
 143
 144 This is called by L<Catalyst::Helper> with the commandline args to generate the
 145 files.
 146
 147 =cut
 148
 149 sub mk_compclass {
 150     my ($package, $helper, $schema_class, @args) = @_;
 151
 152     my $self = $package->new(
 153         helper => $helper,
 154         schema_class => $schema_class,
 155         args => \@args
 156     );
 157
 158     $self->run;
 159 }
 160
 161 sub BUILD {
 162     my $self   = shift;
 163     my $helper = $self->helper;
 164     my @args   = $self->args->flatten if $self->args;
 165
 166     $helper->{schema_class} = $self->schema_class;
 167
 168     @args = $self->_cleanup_args(\@args);
 169
 170     my ($traits_idx, $traits);
 171     if (($traits_idx = firstidx { ($traits) = /^traits=(\S*)\z/ } @args) != -1) {
 172         my @traits = split /,/ => $traits;
 173
 174         $self->traits(\@traits);
 175
 176         $helper->{traits} = '['
 177             .(join ',' => map { qq{'$_'} } ($self->traits->flatten))
 178             .']';
 179
 180         splice @args, $traits_idx, 1, ();
 181     }
 182
 183     if ($args[0] && $args[0] =~ /^create=(\S*)\z/) {
 184         $self->create($1);
 185         shift @args;
 186
 187         if (@args) {
 188             $self->_parse_loader_args(\@args);
 189
 190             $helper->{loader_args} = $self->_build_helper_loader_args;
 191
 192             if (first { /^dbi:/i } @args) {
 193                 $helper->{setup_connect_info} = 1;
 194
 195                 $helper->{connect_info} =
 196                     $self->_build_helper_connect_info(\@args);
 197
 198                 $self->_parse_connect_info(\@args);
 199             }
 200         }
 201     }
 202
 203     $helper->{generator} = ref $self;
 204     $helper->{generator_version} = $VERSION;
 205 }
 206
 207 =head2 run
 208
 209 Can be called on an instance to generate the files.
 210
 211 =cut
 212
 213 sub run {
 214     my $self = shift;
 215
 216     if ($self->create eq 'dynamic') {
 217         $self->_print_dynamic_deprecation_warning;
 218         $self->_gen_dynamic_schema;
 219     } elsif ($self->create eq 'static') {
 220         $self->_gen_static_schema;
 221     }
 222
 223     $self->_gen_model;
 224 }
 225
 226 sub _parse_loader_args {
 227     my ($self, $args) = @_;
 228
 229     my %loader_args = $self->_read_loader_args($args);
 230
 231     while (my ($key, $val) = each %loader_args) {
 232         next if $key =~ /^(?:components|constraint|exclude)\z/;
 233
 234         $loader_args{$key} = $self->_eval($val);
 235         die "syntax error for loader args key '$key' with value '$val': $@"
 236             if $@;
 237     }
 238
 239     my @components =
 240     $self->_build_loader_components(delete $loader_args{components});
 241
 242     $self->components(\@components);
 243
 244     for my $re_opt (qw/constraint exclude/) {
 245         $loader_args{$re_opt} = qr/$loader_args{$re_opt}/
 246         if exists $loader_args{$re_opt};
 247     }
 248
 249     tie my %result, 'Tie::IxHash';
 250
 251     %result = (
 252         relationships => 1,
 253         (%loader_args ? %loader_args : ()),
 254         (!$self->old_schema ? (
 255                 use_namespaces => 1
 256             ) : ()),
 257         (@components ? (
 258                 components => \@components
 259             ) : ())
 260     );
 261
 262     $self->loader_args(\%result);
 263
 264     wantarray ? %result : \%result;
 265 }
 266
 267 sub _read_loader_args {
 268     my ($self, $args) = @_;
 269
 270     my %loader_args;
 271
 272     while (@$args && $args->[0] !~ /^dbi:/) {
 273         my ($key, $val) = split /=/, shift(@$args), 2;
 274
 275         if ($self->_is_struct($val)) {
 276             $loader_args{$key} = $val;
 277         } elsif ((my @vals = split /,/ => $val) > 1) {
 278             $loader_args{$key} = \@vals;
 279         } else {
 280             $loader_args{$key} = $val;
 281         }
 282     }
 283
 284     wantarray ? %loader_args : \%loader_args;
 285 }
 286
 287 sub _build_helper_loader_args {
 288     my $self = shift;
 289
 290     my $args = $self->loader_args;
 291
 292     tie my %loader_args, 'Tie::IxHash';
 293
 294     while (my ($arg, $val) = each %$args) {
 295         if (ref $val) {
 296             $loader_args{$arg} = $self->_data_struct_to_string($val);
 297         } else {
 298             $loader_args{$arg} = qq{'$val'};
 299         }
 300     }
 301
 302     \%loader_args
 303 }
 304
 305 sub _build_loader_components {
 306     my ($self, $components) = @_;
 307
 308     my @components = $self->old_schema ? () : ('InflateColumn::DateTime');
 309
 310     if ($components) {
 311         $components = [ $components ] if !ref $components;
 312         push @components, @$components;
 313     }
 314
 315     wantarray ? @components : \@components;
 316 }
 317
 318 sub _build_helper_connect_info {
 319     my ($self, $connect_info) = @_;
 320
 321     my @connect_info = @$connect_info;
 322
 323     my ($dsn, $user, $password) = $self->_get_dsn_user_pass(\@connect_info);
 324
 325     tie my %helper_connect_info, 'Tie::IxHash';
 326
 327     %helper_connect_info = (
 328         dsn => qq{'$dsn'},
 329         user => qq{'$user'},
 330         password => qq{'$password'}
 331     );
 332
 333     for (@connect_info) {
 334         if (/^\s*{.*}\s*\z/) {
 335             my $hash = $self->_eval($_);
 336             die "Syntax errorr in connect_info hash: $_: $@" if $@;
 337             my %hash = %$hash;
 338
 339             for my $key (keys %hash) {
 340                 my $val = $hash{$key};
 341
 342                 if (ref $val) {
 343                     $val = $self->_data_struct_to_string($val);
 344                 } else {
 345                     $val = $self->_quote($val);
 346                 }
 347
 348                 $helper_connect_info{$key} = $val;
 349             }
 350
 351             next;
 352         }
 353
 354         my ($key, $val) = split /=/, $_, 2;
 355
 356         if ($key eq 'quote_char') {
 357             $helper_connect_info{$key} = length($val) == 1 ?
 358                 $self->_quote($val) :
 359                 $self->_data_struct_to_string([split //, $val]);
 360         } else {
 361             $helper_connect_info{$key} = $self->_quote_unless_struct($val);
 362         }
 363     }
 364
 365     \%helper_connect_info
 366 }
 367
 368 sub _build_old_schema {
 369     my $self = shift;
 370
 371     my @schema_pm   = split '::', $self->schema_class;
 372     $schema_pm[-1] .= '.pm';
 373     my $schema_file =
 374     File::Spec->catfile($self->helper->{base}, 'lib', @schema_pm);
 375
 376     if (-f $schema_file) {
 377         my $schema_code = do { local (@ARGV, $/) = $schema_file; <> };
 378         return 1 if $schema_code =~ /->load_classes/;
 379     }
 380
 381     0;
 382 }
 383
 384 sub _data_struct_to_string {
 385     my ($self, $data) = @_;
 386
 387     local $Data::Dumper::Terse = 1;
 388     local $Data::Dumper::Quotekeys = 0;
 389     local $Data::Dumper::Indent = 0;
 390     local $Data::Dumper::Useqq = 1;
 391
 392     return Data::Dumper->Dump([$data]);
 393 }
 394
 395 sub _get_dsn_user_pass {
 396     my ($self, $connect_info) = @_;
 397
 398     my $dsn = shift @$connect_info;
 399     my ($user, $password);
 400
 401     if ($dsn =~ /sqlite/i) {
 402         ($user, $password) = ('', '');
 403         shift @$connect_info while $connect_info->[0] eq '';
 404     } else {
 405         ($user, $password) = splice @$connect_info, 0, 2;
 406     }
 407
 408     ($dsn, $user, $password)
 409 }
 410
 411 sub _parse_connect_info {
 412     my ($self, $connect_info) = @_;
 413
 414     my @connect_info = @$connect_info;
 415
 416     my ($dsn, $user, $password) = $self->_get_dsn_user_pass(\@connect_info);
 417
 418     tie my %connect_info, 'Tie::IxHash';
 419     @connect_info{qw/dsn user password/} = ($dsn, $user, $password);
 420
 421     for (@connect_info) {
 422         if (/^\s*{.*}\s*\z/) {
 423             my $hash = $self->_eval($_);
 424             die "Syntax errorr in connect_info hash: $_: $@" if $@;
 425
 426             %connect_info = (%connect_info, %$hash);
 427
 428             next;
 429         }
 430
 431         my ($key, $val) = split /=/, $_, 2;
 432
 433         if ($key eq 'quote_char') {
 434             $connect_info{$key} = length($val) == 1 ? $val : [split //, $val];
 435         } elsif ($key =~ /^(?:name_sep|limit_dialect)\z/) {
 436             $connect_info{$key} = $val;
 437         } else {
 438             $connect_info{$key} = $self->_eval($val);
 439         }
 440
 441         die "syntax error for connect_info key '$key' with value '$val': $@"
 442             if $@;
 443     }
 444
 445     $self->connect_info(\%connect_info);
 446
 447     \%connect_info
 448 }
 449
 450 sub _is_struct {
 451     my ($self, $val) = @_;
 452
 453     return $val =~ /^\s*[[{]/;
 454 }
 455
 456 sub _quote {
 457     my ($self, $val) = @_;
 458
 459     return 'q{'.$val.'}';
 460 }
 461
 462 sub _quote_unless_struct {
 463     my ($self, $val) = @_;
 464
 465     $val = $self->_quote($val) if not $self->_is_struct($val);
 466
 467     return $val;
 468 }
 469
 470 sub _eval {
 471     my ($self, $code) = @_;
 472
 473     return $code if looks_like_number $code;
 474
 475     return $code if $code =~ m{^[\w;:/]*\z};
 476
 477     return eval "{no strict; $code}";
 478 }
 479
 480 sub _gen_dynamic_schema {
 481     my $self = shift;
 482
 483     my $helper = $self->helper;
 484
 485     my @schema_parts = split(/\:\:/, $self->schema_class);
 486     my $schema_file_part = pop @schema_parts;
 487
 488     my $schema_dir  = File::Spec->catfile(
 489         $helper->{base}, 'lib', @schema_parts
 490     );
 491     my $schema_file = File::Spec->catfile(
 492         $schema_dir, $schema_file_part . '.pm'
 493     );
 494
 495     $helper->mk_dir($schema_dir);
 496     $helper->render_file('schemaclass', $schema_file);
 497 }
 498
 499 sub _gen_static_schema {
 500     my $self = shift;
 501
 502     die "cannot load schema without connect info" unless $self->connect_info;
 503
 504     my $helper = $self->helper;
 505
 506     my $schema_dir = File::Spec->catfile($helper->{base}, 'lib');
 507
 508     eval { Class::MOP::load_class('DBIx::Class::Schema::Loader') };
 509     die "Cannot load DBIx::Class::Schema::Loader: $@" if $@;
 510
 511     DBIx::Class::Schema::Loader->import(
 512         "dump_to_dir:$schema_dir", 'make_schema_at'
 513     );
 514
 515     make_schema_at(
 516         $self->schema_class,
 517         $self->loader_args,
 518         [$self->connect_info]
 519     );
 520 }
 521
 522 sub _gen_model {
 523     my $self = shift;
 524     my $helper = $self->helper;
 525
 526     $helper->render_file('compclass', $helper->{file} );
 527 }
 528
 529 sub _print_dynamic_deprecation_warning {
 530     warn <<EOF;
 531 ************************************ WARNING **********************************
 532 * create=dynamic is DEPRECATED, please use create=static instead.             *
 533 *******************************************************************************
 534 EOF
 535     print "Continue? [y/n]: ";
 536     chomp(my $response = <STDIN>);
 537     exit 0 if $response =~ /^n(o)?\z/;
 538 }
 539
 540 sub _cleanup_args {
 541     my ($self, $args) = @_;
 542
 543 # remove blanks, ie. someoned doing foo \  bar
 544     my @res = grep !/^\s+\z/, @$args;
 545
 546 # remove leading whitespace, ie. foo \ bar
 547     s/^\s*// for @res;
 548
 549     @res
 550 }
 551
 552 =head1 SEE ALSO
 553
 554 General Catalyst Stuff:
 555
 556 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 557 L<Catalyst::Response>, L<Catalyst::Helper>, L<Catalyst>,
 558
 559 Stuff related to DBIC and this Model style:
 560
 561 L<DBIx::Class>, L<DBIx::Class::Schema>,
 562 L<DBIx::Class::Schema::Loader>, L<Catalyst::Model::DBIC::Schema>
 563
 564 =head1 AUTHOR
 565
 566 Brandon L Black, C<blblack@gmail.com>
 567
 568 Contributors:
 569
 570 Rafael Kitover, C<rkitover at cpan.org>
 571
 572 =head1 LICENSE
 573
 574 This library is free software, you can redistribute it and/or modify
 575 it under the same terms as Perl itself.
 576
 577 =cut
 578
 579 1;
 580
 581 __DATA__
 582
 583 =begin pod_to_ignore
 584
 585 __schemaclass__
 586 package [% schema_class %];
 587
 588 use strict;
 589 use base qw/DBIx::Class::Schema::Loader/;
 590
 591 __PACKAGE__->loader_options(
 592     [%- FOREACH key = loader_args.keys %]
 593     [% key %] => [% loader_args.${key} %],
 594     [%- END -%]
 595
 596 );
 597
 598 =head1 NAME
 599
 600 [% schema_class %] - L<DBIx::Class::Schema::Loader> class
 601
 602 =head1 SYNOPSIS
 603
 604 See L<[% app %]>
 605
 606 =head1 DESCRIPTION
 607
 608 Dynamic L<DBIx::Class::Schema::Loader> schema for use in L<[% class %]>
 609
 610 =head1 GENERATED BY
 611
 612 [% generator %] - [% generator_version %]
 613
 614 =head1 AUTHOR
 615
 616 [% author.replace(',+$', '') %]
 617
 618 =head1 LICENSE
 619
 620 This library is free software, you can redistribute it and/or modify
 621 it under the same terms as Perl itself.
 622
 623 =cut
 624
 625 1;
 626
 627 __compclass__
 628 package [% class %];
 629
 630 use strict;
 631 use base 'Catalyst::Model::DBIC::Schema';
 632
 633 __PACKAGE__->config(
 634     schema_class => '[% schema_class %]',
 635     [% IF traits %]traits => [% traits %],[% END %]
 636     [% IF setup_connect_info %]connect_info => {
 637         [%- FOREACH key = connect_info.keys %]
 638         [% key %] => [% connect_info.${key} %],
 639         [%- END -%]
 640
 641     }[% END %]
 642 );
 643
 644 =head1 NAME
 645
 646 [% class %] - Catalyst DBIC Schema Model
 647
 648 =head1 SYNOPSIS
 649
 650 See L<[% app %]>
 651
 652 =head1 DESCRIPTION
 653
 654 L<Catalyst::Model::DBIC::Schema> Model using schema L<[% schema_class %]>
 655
 656 =head1 GENERATED BY
 657
 658 [% generator %] - [% generator_version %]
 659
 660 =head1 AUTHOR
 661
 662 [% author.replace(',+$', '') %]
 663
 664 =head1 LICENSE
 665
 666 This library is free software, you can redistribute it and/or modify
 667 it under the same terms as Perl itself.
 668
 669 =cut
 670
 671 1;
 672 __END__
 673 # vim:sts=4 sw=4: