lib/Catalyst/Helper/Model/DBIC/Schema.pm

   1 package Catalyst::Helper::Model::DBIC::Schema;
   2
   3 use strict;
   4 use warnings;
   5 use Carp;
   6 use UNIVERSAL::require;
   7
   8 =head1 NAME
   9
  10 Catalyst::Helper::Model::DBIC::Schema - Helper for DBIC Schema Models
  11
  12 =head1 SYNOPSIS
  13
  14   script/create.pl model CatalystModelName DBIC::Schema MyApp::SchemaClass [ create=dynamic | create=static ] [ connect_info arguments ]
  15
  16 =head1 DESCRIPTION
  17
  18 Helper for the DBIC Schema Models.
  19
  20 =head2 Arguments:
  21
  22 C< CatalystModelName > is the short name for the Catalyst Model class
  23 being generated (i.e. callable with C< $c->model >
  24
  25 C< MyApp::SchemaClass > is the fully qualified classname of your Schema,
  26 which might or might not yet exist.  Note that you should have a good
  27 reason to create this under a new global namespace, otherwise use an
  28 existing top level namespace for your schema class.
  29
  30 C< create=dynamic > instructs this Helper to generate the named Schema
  31 class for you, basing it on L<DBIx::Class::Schema::Loader> (which
  32 means the table information will always be dynamically loaded at
  33 runtime from the database).
  34
  35 C< create=static > instructs this Helper to generate the named Schema
  36 class for you, using L<DBIx::Class::Schema::Loader> in "one shot"
  37 mode to create a standard, manually-defined L<DBIx::Class::Schema>
  38 setup, based on what the Loader sees in your database at this moment.
  39 A Schema/Model pair generated this way will not require
  40 L<DBIx::Class::Schema::Loader> at runtime, and will not automatically
  41 adapt itself to changes in your database structure.  You can edit
  42 the generated classes by hand to refine them.
  43
  44 C< connect_info > arguments are the same as what
  45 DBIx::Class::Schema::connect expects, and are storage_type-specific.
  46 For DBI-based storage, these arguments are the dsn, username,
  47 password, and connect options, respectively.  These are optional for
  48 existing Schemas, but required if you use either of the C<create=>
  49 options.
  50
  51 Use of either of the C<create=> options requires L<DBIx::Class::Schema::Loader>.
  52
  53 =head1 TYPICAL EXAMPLES
  54
  55   # Use DBIx::Class::Schema::Loader to create a static DBIx::Class::Schema,
  56   #  and a Model which references it:
  57   script/myapp_create.pl model CatalystModelName DBIC::Schema MyApp::SchemaClass create=static dbi:mysql:foodb myuname mypass
  58
  59   # Create a dynamic DBIx::Class::Schema::Loader-based Schema,
  60   #  and a Model which references it:
  61   script/myapp_create.pl model CatalystModelName DBIC::Schema MyApp::SchemaClass create=dynamic dbi:mysql:foodb myuname mypass
  62
  63   # Reference an existing Schema of any kind, and provide some connection information for ->config:
  64   script/myapp_create.pl model CatalystModelName DBIC::Schema MyApp::SchemaClass dbi:mysql:foodb myuname mypass
  65
  66   # Same, but don't supply connect information yet (you'll need to do this
  67   #  in your app config, or [not recommended] in the schema itself).
  68   script/myapp_create.pl model ModelName DBIC::Schema My::SchemaClass
  69
  70 =head2 METHODS
  71
  72 =head3 mk_compclass
  73
  74 =cut
  75
  76 sub mk_compclass {
  77     my ( $self, $helper, $schema_class, @connect_info) = @_;
  78
  79     $helper->{schema_class} = $schema_class
  80         or croak "Must supply schema class name";
  81
  82     my $create = '';
  83     if($connect_info[0] && $connect_info[0] =~ /^create=(dynamic|static)$/) {
  84         $create = $1;
  85         shift @connect_info;
  86     }
  87
  88     if(@connect_info) {
  89         $helper->{setup_connect_info} = 1;
  90         my @helper_connect_info = @connect_info;
  91         for(@helper_connect_info) {
  92             $_ = qq{'$_'} if $_ !~ /^\s*[[{]/;
  93         }
  94         $helper->{connect_info} = \@helper_connect_info;
  95     }
  96
  97     if($create eq 'dynamic') {
  98         my @schema_parts = split(/\:\:/, $helper->{schema_class});
  99         my $schema_file_part = pop @schema_parts;
 100
 101         my $schema_dir  = File::Spec->catfile( $helper->{base}, 'lib', @schema_parts );
 102         my $schema_file = File::Spec->catfile( $schema_dir, $schema_file_part . '.pm' );
 103
 104         $helper->mk_dir($schema_dir);
 105         $helper->render_file( 'schemaclass', $schema_file );
 106     }
 107     elsif($create eq 'static') {
 108         my $schema_dir  = File::Spec->catfile( $helper->{base}, 'lib' );
 109         DBIx::Class::Schema::Loader->use("dump_to_dir:$schema_dir", 'make_schema_at')
 110             or croak "Cannot load DBIx::Class::Schema::Loader: $@";
 111
 112         my @loader_connect_info = @connect_info;
 113         my $num = 6; # argument number on the commandline for "dbi:..."
 114         for(@loader_connect_info) {
 115             if(/^\s*[[{]/) {
 116                 $_ = eval "$_";
 117                 croak "Perl syntax error in commandline argument $num: $@" if $@;
 118             }
 119             $num++;
 120         }
 121
 122         make_schema_at(
 123             $schema_class,
 124             { relationships => 1 },
 125             \@loader_connect_info,
 126         );
 127     }
 128
 129     my $file = $helper->{file};
 130     $helper->render_file( 'compclass', $file );
 131 }
 132
 133 =head1 SEE ALSO
 134
 135 General Catalyst Stuff:
 136
 137 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 138 L<Catalyst::Response>, L<Catalyst::Helper>, L<Catalyst>,
 139
 140 Stuff related to DBIC and this Model style:
 141
 142 L<DBIx::Class>, L<DBIx::Class::Schema>,
 143 L<DBIx::Class::Schema::Loader>, L<Catalyst::Model::DBIC::Schema>
 144
 145 =head1 AUTHOR
 146
 147 Brandon L Black, C<blblack@gmail.com>
 148
 149 =head1 LICENSE
 150
 151 This library is free software, you can redistribute it and/or modify
 152 it under the same terms as Perl itself.
 153
 154 =cut
 155
 156 1;
 157
 158 __DATA__
 159
 160 =begin pod_to_ignore
 161
 162 __schemaclass__
 163 package [% schema_class %];
 164
 165 use strict;
 166 use base qw/DBIx::Class::Schema::Loader/;
 167
 168 __PACKAGE__->loader_options(
 169     relationships => 1,
 170     # debug => 1,
 171 );
 172
 173 =head1 NAME
 174
 175 [% schema_class %] - DBIx::Class::Schema::Loader class
 176
 177 =head1 SYNOPSIS
 178
 179 See L<[% app %]>
 180
 181 =head1 DESCRIPTION
 182
 183 Generated by L<Catalyst::Model::DBIC::Schema> for use in L<[% class %]>
 184
 185 =head1 AUTHOR
 186
 187 [% author %]
 188
 189 =head1 LICENSE
 190
 191 This library is free software, you can redistribute it and/or modify
 192 it under the same terms as Perl itself.
 193
 194 =cut
 195
 196 1;
 197
 198 __compclass__
 199 package [% class %];
 200
 201 use strict;
 202 use base 'Catalyst::Model::DBIC::Schema';
 203
 204 __PACKAGE__->config(
 205     schema_class => '[% schema_class %]',
 206     [% IF setup_connect_info %]connect_info => [
 207         [% FOREACH arg = connect_info %][% arg %],
 208         [% END %]
 209     ],[% END %]
 210 );
 211
 212 =head1 NAME
 213
 214 [% class %] - Catalyst DBIC Schema Model
 215 =head1 SYNOPSIS
 216
 217 See L<[% app %]>
 218
 219 =head1 DESCRIPTION
 220
 221 L<Catalyst::Model::DBIC::Schema> Model using schema L<[% schema_class %]>
 222
 223 =head1 AUTHOR
 224
 225 [% author %]
 226
 227 =head1 LICENSE
 228
 229 This library is free software, you can redistribute it and/or modify
 230 it under the same terms as Perl itself.
 231
 232 =cut
 233
 234 1;