lib/Catalyst/Helper/Model/DBIC/Schema.pm

   1 package Catalyst::Helper::Model::DBIC::Schema;
   2
   3 use namespace::autoclean;
   4 use Moose;
   5 no warnings 'uninitialized';
   6
   7 our $VERSION = '0.50';
   8 $VERSION = eval $VERSION;
   9
  10 use Carp;
  11 use Tie::IxHash ();
  12 use Data::Dumper ();
  13 use List::Util 'first';
  14 use MooseX::Types::Moose qw/Str HashRef Bool ArrayRef/;
  15 use Catalyst::Model::DBIC::Schema::Types 'CreateOption';
  16 use List::MoreUtils 'firstidx';
  17 use Scalar::Util 'looks_like_number';
  18 use File::Find 'finddepth';
  19 use Try::Tiny;
  20 use Cwd 'getcwd';
  21
  22 =head1 NAME
  23
  24 Catalyst::Helper::Model::DBIC::Schema - Helper for DBIC Schema Models
  25
  26 =head1 SYNOPSIS
  27
  28   script/create.pl model CatalystModelName DBIC::Schema MyApp::SchemaClass \
  29     [ create=dynamic | create=static ] [ traits=trait1,trait2... ] \
  30     [ Schema::Loader opts ] [ dsn user pass ] \
  31     [ other connect_info args ]
  32
  33 =head1 DESCRIPTION
  34
  35 Helper for the DBIC Schema Models.
  36
  37 =head2 Arguments:
  38
  39 C<CatalystModelName> is the short name for the Catalyst Model class
  40 being generated (i.e. callable with C<$c-E<gt>model('CatalystModelName')>).
  41
  42 C<MyApp::SchemaClass> is the fully qualified classname of your Schema,
  43 which might or might not yet exist.  Note that you should have a good
  44 reason to create this under a new global namespace, otherwise use an
  45 existing top level namespace for your schema class.
  46
  47 C<create=dynamic> instructs this Helper to generate the named Schema
  48 class for you, basing it on L<DBIx::Class::Schema::Loader> (which
  49 means the table information will always be dynamically loaded at
  50 runtime from the database).
  51
  52 C<create=static> instructs this Helper to generate the named Schema
  53 class for you, using L<DBIx::Class::Schema::Loader> in "one shot"
  54 mode to create a standard, manually-defined L<DBIx::Class::Schema>
  55 setup, based on what the Loader sees in your database at this moment.
  56 A Schema/Model pair generated this way will not require
  57 L<DBIx::Class::Schema::Loader> at runtime, and will not automatically
  58 adapt itself to changes in your database structure.  You can edit
  59 the generated classes by hand to refine them.
  60
  61 C<traits> is the list of traits to apply to the model, see
  62 L<Catalyst::Model::DBIC::Schema> for details.
  63
  64 C<Schema::Loader opts> are documented in L<DBIx::Class::Schema::Loader::Base>
  65 and some examples are given in L</TYPICAL EXAMPLES> below.
  66
  67 C<connect_info> arguments are the same as what L<DBIx::Class::Schema/connect>
  68 expects, and are storage_type-specific. They are documented in
  69 L<DBIx::Class::Storage::DBI/connect_info>. For DBI-based storage, these
  70 arguments are the dsn, username, password, and connect options, respectively.
  71 These are optional for existing Schemas, but required if you use either of the
  72 C<create=> options.
  73
  74 username and password can be omitted for C<SQLite> dsns.
  75
  76 Use of either of the C<create=> options requires L<DBIx::Class::Schema::Loader>.
  77
  78 =head1 TYPICAL EXAMPLES
  79
  80 Use DBIx::Class::Schema::Loader to create a static DBIx::Class::Schema,
  81 and a Model which references it:
  82
  83   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  84     MyApp::SchemaClass create=static dbi:mysql:foodb myuname mypass
  85
  86 Same, with extra connect_info args
  87 user and pass can be omitted for sqlite, since they are always empty
  88
  89   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  90     MyApp::SchemaClass create=static dbi:SQLite:foo.db \
  91     AutoCommit=1 cursor_class=DBIx::Class::Cursor::Cached \
  92     on_connect_do='["select 1", "select 2"]' quote_names=1
  93
  94 B<ON WINDOWS COMMAND LINES QUOTING RULES ARE DIFFERENT>
  95
  96 In C<cmd.exe> the above example would be:
  97
  98   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  99     MyApp::SchemaClass create=static dbi:SQLite:foo.db \
 100     AutoCommit=1 cursor_class=DBIx::Class::Cursor::Cached \
 101     on_connect_do="[\"select 1\", \"select 2\"]" quote_names=1
 102
 103 Same, but with extra Schema::Loader args (separate multiple values by commas):
 104
 105   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 106     MyApp::SchemaClass create=static db_schema=foodb components=Foo,Bar \
 107     exclude='^(wibble|wobble)$' moniker_map='{ foo => "FOO" }' \
 108     dbi:Pg:dbname=foodb myuname mypass
 109
 110 Coderefs are also supported:
 111
 112   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 113     MyApp::SchemaClass create=static \
 114     inflect_singular='sub { $_[0] =~ /\A(.+?)(_id)?\z/; $1 }' \
 115     moniker_map='sub { join(q{}, map ucfirst, split(/[\W_]+/, lc $_[0])); }' \
 116     dbi:mysql:foodb myuname mypass
 117
 118 See L<DBIx::Class::Schema::Loader::Base> for a list of options
 119
 120 Create a dynamic DBIx::Class::Schema::Loader-based Schema,
 121 and a Model which references it (B<DEPRECATED>):
 122
 123   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 124     MyApp::SchemaClass create=dynamic dbi:mysql:foodb myuname mypass
 125
 126 Reference an existing Schema of any kind, and provide some connection information for ->config:
 127
 128   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 129     MyApp::SchemaClass dbi:mysql:foodb myuname mypass
 130
 131 Same, but don't supply connect information yet (you'll need to do this
 132 in your app config, or [not recommended] in the schema itself).
 133
 134   script/myapp_create.pl model ModelName DBIC::Schema My::SchemaClass
 135
 136 =cut
 137
 138 has helper => (is => 'ro', isa => 'Catalyst::Helper', required => 1);
 139 has create => (is => 'rw', isa => CreateOption);
 140 has args => (is => 'ro', isa => ArrayRef);
 141 has traits => (is => 'rw', isa => ArrayRef);
 142 has schema_class => (is => 'ro', isa => Str, required => 1);
 143 has loader_args => (is => 'rw', isa => HashRef);
 144 has connect_info => (is => 'rw', isa => HashRef);
 145 has old_schema => (is => 'rw', isa => Bool, lazy_build => 1);
 146 has is_moose_schema => (is => 'rw', isa => Bool, lazy_build => 1);
 147 has result_namespace => (is => 'rw', isa => Str, lazy_build => 1);
 148 has components => (is => 'rw', isa => ArrayRef);
 149
 150 =head1 METHODS
 151
 152 =head2 mk_compclass
 153
 154 This is called by L<Catalyst::Helper> with the commandline args to generate the
 155 files.
 156
 157 =cut
 158
 159 sub mk_compclass {
 160     my ($package, $helper, $schema_class, @args) = @_;
 161
 162     my $self = $package->new(
 163         helper => $helper,
 164         schema_class => $schema_class,
 165         args => \@args
 166     );
 167
 168     $self->run;
 169 }
 170
 171 sub BUILD {
 172     my $self   = shift;
 173     my $helper = $self->helper;
 174     my @args   = @{ $self->args || [] };
 175
 176     $helper->{schema_class} = $self->schema_class;
 177
 178     @args = $self->_cleanup_args(\@args);
 179
 180     my ($traits_idx, $traits);
 181     if (($traits_idx = firstidx { ($traits) = /^traits=(\S*)\z/ } @args) != -1) {
 182         my @traits = split /,/ => $traits;
 183
 184         $self->traits(\@traits);
 185
 186         $helper->{traits} = '['
 187             .(join ',' => map { qq{'$_'} } @traits)
 188             .']';
 189
 190         splice @args, $traits_idx, 1, ();
 191     }
 192
 193     if ($args[0] && $args[0] =~ /^create=(\S*)\z/) {
 194         $self->create($1);
 195         shift @args;
 196
 197         if (@args) {
 198             $self->_parse_loader_args(\@args);
 199
 200             $helper->{loader_args} = $self->_build_helper_loader_args;
 201         }
 202     }
 203
 204     my $dbi_dsn_part;
 205     if (first { ($dbi_dsn_part) = /^(dbi):/i } @args) {
 206         die
 207 qq{DSN must start with 'dbi:' not '$dbi_dsn_part' (case matters!)}
 208             if $dbi_dsn_part ne 'dbi';
 209
 210         $helper->{setup_connect_info} = 1;
 211
 212         $helper->{connect_info} =
 213             $self->_build_helper_connect_info(\@args);
 214
 215         $self->_parse_connect_info(\@args);
 216     }
 217
 218     $helper->{generator} = ref $self;
 219     $helper->{generator_version} = $VERSION;
 220 }
 221
 222 =head2 run
 223
 224 Can be called on an instance to generate the files.
 225
 226 =cut
 227
 228 sub run {
 229     my $self = shift;
 230
 231     if ($self->create eq 'dynamic') {
 232         $self->_print_dynamic_deprecation_warning;
 233         $self->_gen_dynamic_schema;
 234     } elsif ($self->create eq 'static') {
 235         $self->_gen_static_schema;
 236     }
 237
 238     $self->_gen_model;
 239 }
 240
 241 sub _parse_loader_args {
 242     my ($self, $args) = @_;
 243
 244     my %loader_args = $self->_read_loader_args($args);
 245
 246     while (my ($key, $val) = each %loader_args) {
 247         next if $key =~ /^(?:components|constraint|exclude)\z/;
 248
 249         $loader_args{$key} = $self->_eval($val);
 250         die "syntax error for loader args key '$key' with value '$val': $@"
 251             if $@;
 252     }
 253
 254     my @components = $self->_build_loader_components(
 255         delete $loader_args{components},
 256         $loader_args{use_namespaces},
 257     );
 258
 259     $self->components(\@components);
 260
 261     for my $re_opt (qw/constraint exclude/) {
 262         $loader_args{$re_opt} = qr/$loader_args{$re_opt}/
 263         if exists $loader_args{$re_opt};
 264     }
 265
 266     tie my %result, 'Tie::IxHash';
 267
 268     %result = (
 269         relationships => 1,
 270         use_moose => $self->is_moose_schema ? 1 : 0,
 271         col_collision_map => 'column_%s',
 272         (!$self->old_schema ? (
 273                 use_namespaces => 1
 274             ) : ()),
 275         (@components ? (
 276                 components => \@components
 277             ) : ()),
 278         (%loader_args ? %loader_args : ()),
 279     );
 280
 281     $self->loader_args(\%result);
 282
 283     wantarray ? %result : \%result;
 284 }
 285
 286 sub _read_loader_args {
 287     my ($self, $args) = @_;
 288
 289     my %loader_args;
 290
 291     while (@$args && $args->[0] !~ /^dbi:/i) {
 292         my ($key, $val) = split /=/, shift(@$args), 2;
 293
 294         if ($self->_is_struct($val)) {
 295             $loader_args{$key} = $val;
 296         } elsif ((my @vals = split /,/ => $val) > 1) {
 297             $loader_args{$key} = \@vals;
 298         } else {
 299             $loader_args{$key} = $val;
 300         }
 301     }
 302
 303     wantarray ? %loader_args : \%loader_args;
 304 }
 305
 306 sub _build_helper_loader_args {
 307     my $self = shift;
 308
 309     my $args = $self->loader_args;
 310
 311     tie my %loader_args, 'Tie::IxHash';
 312
 313     while (my ($arg, $val) = each %$args) {
 314         if (ref $val) {
 315             $loader_args{$arg} = $self->_data_struct_to_string($val);
 316         } else {
 317             $loader_args{$arg} = qq{'$val'};
 318         }
 319     }
 320
 321     \%loader_args
 322 }
 323
 324 sub _build_loader_components {
 325     my ($self, $components, $use_namespaces) = @_;
 326
 327     my @components = $self->old_schema && (not $use_namespaces) ? ()
 328         : ('InflateColumn::DateTime');
 329
 330     if ($components) {
 331         $components = [ $components ] if !ref $components;
 332         push @components, @$components;
 333     }
 334
 335     wantarray ? @components : \@components;
 336 }
 337
 338 sub _build_helper_connect_info {
 339     my ($self, $connect_info) = @_;
 340
 341     my @connect_info = @$connect_info;
 342
 343     my ($dsn, $user, $password) = $self->_get_dsn_user_pass(\@connect_info);
 344
 345     tie my %helper_connect_info, 'Tie::IxHash';
 346
 347     %helper_connect_info = (
 348         dsn => qq{'$dsn'},
 349         user => qq{'$user'},
 350         password => qq{'$password'}
 351     );
 352
 353     for (@connect_info) {
 354         if (/^\s*{.*}\s*\z/) {
 355             my $hash = $self->_eval($_);
 356             die "Syntax errorr in connect_info hash: $_: $@" if $@;
 357             my %hash = %$hash;
 358
 359             for my $key (keys %hash) {
 360                 my $val = $hash{$key};
 361
 362                 if (ref $val) {
 363                     $val = $self->_data_struct_to_string($val);
 364                 } else {
 365                     $val = $self->_quote($val);
 366                 }
 367
 368                 $helper_connect_info{$key} = $val;
 369             }
 370
 371             next;
 372         }
 373
 374         my ($key, $val) = split /=/, $_, 2;
 375
 376         if ($key eq 'quote_char') {
 377             $helper_connect_info{$key} = length($val) == 1 ?
 378                 $self->_quote($val) :
 379                 $self->_data_struct_to_string([split //, $val]);
 380         } else {
 381             $helper_connect_info{$key} = $self->_quote_unless_struct($val);
 382         }
 383     }
 384
 385     \%helper_connect_info
 386 }
 387
 388 sub _build_old_schema {
 389     my $self = shift;
 390
 391     return $self->result_namespace eq '' ? 1 : 0;
 392 }
 393
 394 sub _build_is_moose_schema {
 395     my $self = shift;
 396
 397     my @schema_parts = split '::', $self->schema_class;
 398
 399     my $result_dir = File::Spec->catfile(
 400         $self->helper->{base}, 'lib', @schema_parts, $self->result_namespace
 401     );
 402
 403     # assume yes for new schemas
 404     return 1 if not -d $result_dir;
 405
 406     my $uses_moose = 1;
 407
 408     my $cwd = getcwd;
 409
 410     try {
 411         finddepth(sub {
 412             return if $File::Find::name !~ /\.pm\z/;
 413
 414             open my $fh, '<', $File::Find::name
 415                 or die "Could not open $File::Find::name: $!";
 416
 417             my $code = do { local $/; <$fh> };
 418             close $fh;
 419
 420             $uses_moose = 0 if $code !~ /\nuse Moose;\n/;
 421
 422             die;
 423         }, $result_dir);
 424     };
 425
 426     chdir $cwd;
 427
 428     return $uses_moose;
 429 }
 430
 431 sub _build_result_namespace {
 432     my $self = shift;
 433
 434     my @schema_parts = split '::', $self->schema_class;
 435     my $schema_pm =
 436         File::Spec->catfile($self->helper->{base}, 'lib', @schema_parts) . '.pm';
 437
 438     if (not -f $schema_pm) {
 439         eval { Class::MOP::load_class('DBIx::Class::Schema::Loader') };
 440
 441         return 'Result' if $@;
 442
 443         return (try { DBIx::Class::Schema::Loader->VERSION('0.05') }) ? 'Result' : '';
 444     }
 445
 446     open my $fh, '<', $schema_pm or die "Could not open $schema_pm: $!";
 447     my $code = do { local $/; <$fh> };
 448     close $fh;
 449
 450     my ($result_namespace) = $code =~ /result_namespace => '([^']+)'/;
 451
 452     return $result_namespace if $result_namespace;
 453
 454     return '' if $code =~ /->load_classes/;
 455
 456     return 'Result';
 457 }
 458
 459 sub _data_struct_to_string {
 460     my ($self, $data) = @_;
 461
 462     local $Data::Dumper::Terse = 1;
 463     local $Data::Dumper::Quotekeys = 0;
 464     local $Data::Dumper::Indent = 0;
 465     local $Data::Dumper::Useqq = 1;
 466
 467     return Data::Dumper->Dump([$data]);
 468 }
 469
 470 sub _get_dsn_user_pass {
 471     my ($self, $connect_info) = @_;
 472
 473     my $dsn = shift @$connect_info;
 474     my ($user, $password);
 475
 476     if ($dsn =~ /sqlite/i) {
 477         ($user, $password) = ('', '');
 478         shift @$connect_info while @$connect_info and $connect_info->[0] eq '';
 479     } else {
 480         ($user, $password) = splice @$connect_info, 0, 2;
 481     }
 482
 483     ($dsn, $user, $password)
 484 }
 485
 486 sub _parse_connect_info {
 487     my ($self, $connect_info) = @_;
 488
 489     my @connect_info = @$connect_info;
 490
 491     my ($dsn, $user, $password) = $self->_get_dsn_user_pass(\@connect_info);
 492
 493     tie my %connect_info, 'Tie::IxHash';
 494     @connect_info{qw/dsn user password/} = ($dsn, $user, $password);
 495
 496     for (@connect_info) {
 497         if (/^\s*{.*}\s*\z/) {
 498             my $hash = $self->_eval($_);
 499             die "Syntax errorr in connect_info hash: $_: $@" if $@;
 500
 501             %connect_info = (%connect_info, %$hash);
 502
 503             next;
 504         }
 505
 506         my ($key, $val) = split /=/, $_, 2;
 507
 508         if ($key eq 'quote_char') {
 509             $connect_info{$key} = length($val) == 1 ? $val : [split //, $val];
 510         } elsif ($key =~ /^(?:name_sep|limit_dialect)\z/) {
 511             $connect_info{$key} = $val;
 512         } else {
 513             $connect_info{$key} = $self->_eval($val);
 514         }
 515
 516         die "syntax error for connect_info key '$key' with value '$val': $@"
 517             if $@;
 518     }
 519
 520     $self->connect_info(\%connect_info);
 521
 522     \%connect_info
 523 }
 524
 525 sub _is_struct {
 526     my ($self, $val) = @_;
 527
 528     return $val =~ /^\s*(?:sub|[[{])/;
 529 }
 530
 531 sub _quote {
 532     my ($self, $val) = @_;
 533
 534     return 'q{'.$val.'}';
 535 }
 536
 537 sub _quote_unless_struct {
 538     my ($self, $val) = @_;
 539
 540     $val = $self->_quote($val) if not $self->_is_struct($val);
 541
 542     return $val;
 543 }
 544
 545 sub _eval {
 546     my ($self, $code) = @_;
 547
 548     return $code if looks_like_number $code;
 549
 550     return $code if not $self->_is_struct($code);
 551
 552     return eval "{no strict; $code}";
 553 }
 554
 555 sub _gen_dynamic_schema {
 556     my $self = shift;
 557
 558     my $helper = $self->helper;
 559
 560     my @schema_parts = split(/\:\:/, $self->schema_class);
 561     my $schema_file_part = pop @schema_parts;
 562
 563     my $schema_dir  = File::Spec->catfile(
 564         $helper->{base}, 'lib', @schema_parts
 565     );
 566     my $schema_file = File::Spec->catfile(
 567         $schema_dir, $schema_file_part . '.pm'
 568     );
 569
 570     $helper->mk_dir($schema_dir);
 571     $helper->render_file('schemaclass', $schema_file);
 572 }
 573
 574 sub _gen_static_schema {
 575     my $self = shift;
 576
 577     die "cannot load schema without connect info" unless $self->connect_info;
 578
 579     my $helper = $self->helper;
 580
 581     my $schema_dir = File::Spec->catfile($helper->{base}, 'lib');
 582
 583     try {
 584         Class::MOP::load_class('DBIx::Class::Schema::Loader')
 585     }
 586     catch {
 587         die "Cannot load DBIx::Class::Schema::Loader: $_";
 588     };
 589
 590     DBIx::Class::Schema::Loader->import(
 591         "dump_to_dir:$schema_dir", 'make_schema_at'
 592     );
 593
 594     make_schema_at(
 595         $self->schema_class,
 596         $self->loader_args,
 597         [$self->connect_info]
 598     );
 599
 600     require lib;
 601     lib->import($schema_dir);
 602
 603     Class::MOP::load_class($self->schema_class);
 604
 605     my @sources = $self->schema_class->sources;
 606
 607     if (not @sources) {
 608         warn <<'EOF';
 609 WARNING: No tables found, did you forget to specify db_schema?
 610 EOF
 611     }
 612 }
 613
 614 sub _gen_model {
 615     my $self = shift;
 616     my $helper = $self->helper;
 617
 618     $helper->render_file('compclass', $helper->{file} );
 619 }
 620
 621 sub _print_dynamic_deprecation_warning {
 622     warn <<EOF;
 623 ************************************ WARNING **********************************
 624 * create=dynamic is DEPRECATED, please use create=static instead.             *
 625 *******************************************************************************
 626 EOF
 627     print "Continue? [y/n]: ";
 628     chomp(my $response = <STDIN>);
 629     exit 0 if $response =~ /^n(o)?\z/;
 630 }
 631
 632 sub _cleanup_args {
 633     my ($self, $args) = @_;
 634
 635 # remove blanks, ie. someoned doing foo \  bar
 636     my @res = grep !/^\s+\z/, @$args;
 637
 638 # remove leading whitespace, ie. foo \ bar
 639     s/^\s*// for @res;
 640
 641     @res
 642 }
 643
 644 =head1 SEE ALSO
 645
 646 General Catalyst Stuff:
 647
 648 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 649 L<Catalyst::Response>, L<Catalyst::Helper>, L<Catalyst>,
 650
 651 Stuff related to DBIC and this Model style:
 652
 653 L<DBIx::Class>, L<DBIx::Class::Schema>,
 654 L<DBIx::Class::Schema::Loader>, L<Catalyst::Model::DBIC::Schema>
 655
 656 =head1 AUTHOR
 657
 658 See L<Catalyst::Model::DBIC::Schema/AUTHOR> and
 659 L<Catalyst::Model::DBIC::Schema/CONTRIBUTORS>.
 660
 661 =head1 COPYRIGHT
 662
 663 See L<Catalyst::Model::DBIC::Schema/COPYRIGHT>.
 664
 665 =head1 LICENSE
 666
 667 This library is free software, you can redistribute it and/or modify
 668 it under the same terms as Perl itself.
 669
 670 =cut
 671
 672 1;
 673
 674 __DATA__
 675
 676 =begin pod_to_ignore
 677
 678 __schemaclass__
 679 package [% schema_class %];
 680
 681 use strict;
 682 use base qw/DBIx::Class::Schema::Loader/;
 683
 684 __PACKAGE__->loader_options(
 685     [%- FOREACH key = loader_args.keys %]
 686     [% key %] => [% loader_args.${key} %],
 687     [%- END -%]
 688
 689 );
 690
 691 =head1 NAME
 692
 693 [% schema_class %] - L<DBIx::Class::Schema::Loader> class
 694
 695 =head1 SYNOPSIS
 696
 697 See L<[% app %]>
 698
 699 =head1 DESCRIPTION
 700
 701 Dynamic L<DBIx::Class::Schema::Loader> schema for use in L<[% class %]>
 702
 703 =head1 GENERATED BY
 704
 705 [% generator %] - [% generator_version %]
 706
 707 =head1 AUTHOR
 708
 709 [% author.replace(',+$', '') %]
 710
 711 =head1 LICENSE
 712
 713 This library is free software, you can redistribute it and/or modify
 714 it under the same terms as Perl itself.
 715
 716 =cut
 717
 718 1;
 719
 720 __compclass__
 721 package [% class %];
 722
 723 use strict;
 724 use base 'Catalyst::Model::DBIC::Schema';
 725
 726 __PACKAGE__->config(
 727     schema_class => '[% schema_class %]',
 728     [% IF traits %]traits => [% traits %],[% END %]
 729     [% IF setup_connect_info %]connect_info => {
 730         [%- FOREACH key = connect_info.keys %]
 731         [% key %] => [% connect_info.${key} %],
 732         [%- END -%]
 733
 734     }[% END %]
 735 );
 736
 737 =head1 NAME
 738
 739 [% class %] - Catalyst DBIC Schema Model
 740
 741 =head1 SYNOPSIS
 742
 743 See L<[% app %]>
 744
 745 =head1 DESCRIPTION
 746
 747 L<Catalyst::Model::DBIC::Schema> Model using schema L<[% schema_class %]>
 748
 749 =head1 GENERATED BY
 750
 751 [% generator %] - [% generator_version %]
 752
 753 =head1 AUTHOR
 754
 755 [% author.replace(',+$', '') %]
 756
 757 =head1 LICENSE
 758
 759 This library is free software, you can redistribute it and/or modify
 760 it under the same terms as Perl itself.
 761
 762 =cut
 763
 764 1;
 765 __END__
 766 # vim:sts=4 sw=4: