lib/Catalyst/Helper/Model/DBIC/Schema.pm

   1 package Catalyst::Helper::Model::DBIC::Schema;
   2
   3 use namespace::autoclean;
   4 use Moose;
   5 no warnings 'uninitialized';
   6
   7 our $VERSION = '0.52';
   8 $VERSION = eval $VERSION;
   9
  10 use Carp;
  11 use Tie::IxHash ();
  12 use Data::Dumper ();
  13 use List::Util 'first';
  14 use MooseX::Types::Moose qw/Str HashRef Bool ArrayRef/;
  15 use Catalyst::Model::DBIC::Schema::Types 'CreateOption';
  16 use List::MoreUtils 'firstidx';
  17 use Scalar::Util 'looks_like_number';
  18 use File::Find 'finddepth';
  19 use Try::Tiny;
  20 use Cwd 'getcwd';
  21
  22 =head1 NAME
  23
  24 Catalyst::Helper::Model::DBIC::Schema - Helper for DBIC Schema Models
  25
  26 =head1 SYNOPSIS
  27
  28   script/create.pl model CatalystModelName DBIC::Schema MyApp::SchemaClass \
  29     [ create=dynamic | create=static ] [ traits=trait1,trait2... ] \
  30     [ Schema::Loader opts ] [ dsn user pass ] \
  31     [ other connect_info args ]
  32
  33 =head1 DESCRIPTION
  34
  35 Helper for the DBIC Schema Models.
  36
  37 =head2 Arguments:
  38
  39 C<CatalystModelName> is the short name for the Catalyst Model class
  40 being generated (i.e. callable with C<$c-E<gt>model('CatalystModelName')>).
  41
  42 C<MyApp::SchemaClass> is the fully qualified classname of your Schema,
  43 which might or might not yet exist.  Note that you should have a good
  44 reason to create this under a new global namespace, otherwise use an
  45 existing top level namespace for your schema class.
  46
  47 C<create=dynamic> instructs this Helper to generate the named Schema
  48 class for you, basing it on L<DBIx::Class::Schema::Loader> (which
  49 means the table information will always be dynamically loaded at
  50 runtime from the database).
  51
  52 C<create=static> instructs this Helper to generate the named Schema
  53 class for you, using L<DBIx::Class::Schema::Loader> in "one shot"
  54 mode to create a standard, manually-defined L<DBIx::Class::Schema>
  55 setup, based on what the Loader sees in your database at this moment.
  56 A Schema/Model pair generated this way will not require
  57 L<DBIx::Class::Schema::Loader> at runtime, and will not automatically
  58 adapt itself to changes in your database structure.  You can edit
  59 the generated classes by hand to refine them.
  60
  61 C<traits> is the list of traits to apply to the model, see
  62 L<Catalyst::Model::DBIC::Schema> for details.
  63
  64 C<Schema::Loader opts> are documented in L<DBIx::Class::Schema::Loader::Base>
  65 and some examples are given in L</TYPICAL EXAMPLES> below.
  66
  67 C<connect_info> arguments are the same as what L<DBIx::Class::Schema/connect>
  68 expects, and are storage_type-specific. They are documented in
  69 L<DBIx::Class::Storage::DBI/connect_info>. For DBI-based storage, these
  70 arguments are the dsn, username, password, and connect options, respectively.
  71 These are optional for existing Schemas, but required if you use either of the
  72 C<create=> options.
  73
  74 username and password can be omitted for C<SQLite> dsns.
  75
  76 Use of either of the C<create=> options requires L<DBIx::Class::Schema::Loader>.
  77
  78 =head1 TYPICAL EXAMPLES
  79
  80 Use DBIx::Class::Schema::Loader to create a static DBIx::Class::Schema,
  81 and a Model which references it:
  82
  83   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  84     MyApp::SchemaClass create=static dbi:mysql:foodb myuname mypass
  85
  86 Same, with extra connect_info args
  87 user and pass can be omitted for sqlite, since they are always empty
  88
  89   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  90     MyApp::SchemaClass create=static dbi:SQLite:foo.db \
  91     AutoCommit=1 cursor_class=DBIx::Class::Cursor::Cached \
  92     on_connect_do='["select 1", "select 2"]' quote_names=1
  93
  94 B<ON WINDOWS COMMAND LINES QUOTING RULES ARE DIFFERENT>
  95
  96 In C<cmd.exe> the above example would be:
  97
  98   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  99     MyApp::SchemaClass create=static dbi:SQLite:foo.db \
 100     AutoCommit=1 cursor_class=DBIx::Class::Cursor::Cached \
 101     on_connect_do="[\"select 1\", \"select 2\"]" quote_names=1
 102
 103 Same, but with extra Schema::Loader args (separate multiple values by commas):
 104
 105   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 106     MyApp::SchemaClass create=static db_schema=foodb components=Foo,Bar \
 107     exclude='^(wibble|wobble)$' moniker_map='{ foo => "FOO" }' \
 108     dbi:Pg:dbname=foodb myuname mypass
 109
 110 Coderefs are also supported:
 111
 112   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 113     MyApp::SchemaClass create=static \
 114     inflect_singular='sub { $_[0] =~ /\A(.+?)(_id)?\z/; $1 }' \
 115     moniker_map='sub { join(q{}, map ucfirst, split(/[\W_]+/, lc $_[0])); }' \
 116     dbi:mysql:foodb myuname mypass
 117
 118 See L<DBIx::Class::Schema::Loader::Base> for a list of options
 119
 120 Create a dynamic DBIx::Class::Schema::Loader-based Schema,
 121 and a Model which references it (B<DEPRECATED>):
 122
 123   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 124     MyApp::SchemaClass create=dynamic dbi:mysql:foodb myuname mypass
 125
 126 Reference an existing Schema of any kind, and provide some connection information for ->config:
 127
 128   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 129     MyApp::SchemaClass dbi:mysql:foodb myuname mypass
 130
 131 Same, but don't supply connect information yet (you'll need to do this
 132 in your app config, or [not recommended] in the schema itself).
 133
 134   script/myapp_create.pl model ModelName DBIC::Schema My::SchemaClass
 135
 136 =cut
 137
 138 has helper => (is => 'ro', isa => 'Catalyst::Helper', required => 1);
 139 has create => (is => 'rw', isa => CreateOption);
 140 has args => (is => 'ro', isa => ArrayRef);
 141 has traits => (is => 'rw', isa => ArrayRef);
 142 has schema_class => (is => 'ro', isa => Str, required => 1);
 143 has loader_args => (is => 'rw', isa => HashRef);
 144 has connect_info => (is => 'rw', isa => HashRef);
 145 has old_schema => (is => 'rw', isa => Bool, lazy_build => 1);
 146 has is_moose_schema => (is => 'rw', isa => Bool, lazy_build => 1);
 147 has result_namespace => (is => 'rw', isa => Str, lazy_build => 1);
 148 has components => (is => 'rw', isa => ArrayRef);
 149
 150 =head1 METHODS
 151
 152 =head2 mk_compclass
 153
 154 This is called by L<Catalyst::Helper> with the commandline args to generate the
 155 files.
 156
 157 =cut
 158
 159 sub mk_compclass {
 160     my ($package, $helper, $schema_class, @args) = @_;
 161
 162     my $self = $package->new(
 163         helper => $helper,
 164         schema_class => $schema_class,
 165         args => \@args
 166     );
 167
 168     $self->run;
 169 }
 170
 171 sub BUILD {
 172     my $self   = shift;
 173     my $helper = $self->helper;
 174     my @args   = @{ $self->args || [] };
 175
 176     $helper->{schema_class} = $self->schema_class;
 177
 178     @args = $self->_cleanup_args(\@args);
 179
 180     my ($traits_idx, $traits);
 181     if (($traits_idx = firstidx { ($traits) = /^traits=(\S*)\z/ } @args) != -1) {
 182         my @traits = split /,/ => $traits;
 183
 184         $self->traits(\@traits);
 185
 186         $helper->{traits} = '['
 187             .(join ',' => map { qq{'$_'} } @traits)
 188             .']';
 189
 190         splice @args, $traits_idx, 1, ();
 191     }
 192
 193     if ($args[0] && $args[0] =~ /^create=(\S*)\z/) {
 194         $self->create($1);
 195         shift @args;
 196
 197         if (@args) {
 198             $self->_parse_loader_args(\@args);
 199
 200             $helper->{loader_args} = $self->_build_helper_loader_args;
 201         }
 202     }
 203
 204     my $dbi_dsn_part;
 205     if (first { ($dbi_dsn_part) = /^(dbi):/i } @args) {
 206         die
 207 qq{DSN must start with 'dbi:' not '$dbi_dsn_part' (case matters!)}
 208             if $dbi_dsn_part ne 'dbi';
 209
 210         $helper->{setup_connect_info} = 1;
 211
 212         $helper->{connect_info} =
 213             $self->_build_helper_connect_info(\@args);
 214
 215         $self->_parse_connect_info(\@args);
 216     }
 217
 218     $helper->{generator} = ref $self;
 219     $helper->{generator_version} = $VERSION;
 220 }
 221
 222 =head2 run
 223
 224 Can be called on an instance to generate the files.
 225
 226 =cut
 227
 228 sub run {
 229     my $self = shift;
 230
 231     if ($self->create eq 'dynamic') {
 232         $self->_print_dynamic_deprecation_warning;
 233         $self->_gen_dynamic_schema;
 234     } elsif ($self->create eq 'static') {
 235         $self->_gen_static_schema;
 236     }
 237
 238     $self->_gen_model;
 239 }
 240
 241 sub _parse_loader_args {
 242     my ($self, $args) = @_;
 243
 244     my %loader_args = $self->_read_loader_args($args);
 245
 246     while (my ($key, $val) = each %loader_args) {
 247         next if $key =~ /^(?:components|constraint|exclude)\z/;
 248
 249         $loader_args{$key} = $self->_eval($val);
 250         die "syntax error for loader args key '$key' with value '$val': $@"
 251             if $@;
 252     }
 253
 254     my @components = $self->_build_loader_components(
 255         delete $loader_args{components},
 256         $loader_args{use_namespaces},
 257     );
 258
 259     $self->components(\@components);
 260
 261     for my $re_opt (qw/constraint exclude/) {
 262         $loader_args{$re_opt} = qr/$loader_args{$re_opt}/
 263         if exists $loader_args{$re_opt};
 264     }
 265
 266     tie my %result, 'Tie::IxHash';
 267
 268     %result = (
 269         relationships => 1,
 270         use_moose => $self->is_moose_schema ? 1 : 0,
 271         col_collision_map => 'column_%s',
 272         (!$self->old_schema ? (
 273                 use_namespaces => 1
 274             ) : ()),
 275         (@components ? (
 276                 components => \@components
 277             ) : ()),
 278         (%loader_args ? %loader_args : ()),
 279     );
 280
 281     $self->loader_args(\%result);
 282
 283     wantarray ? %result : \%result;
 284 }
 285
 286 sub _read_loader_args {
 287     my ($self, $args) = @_;
 288
 289     my %loader_args;
 290
 291     while (@$args && $args->[0] !~ /^dbi:/i) {
 292         my ($key, $val) = split /=/, shift(@$args), 2;
 293
 294         if ($self->_is_struct($val)) {
 295             $loader_args{$key} = $val;
 296         } elsif ((my @vals = split /,/ => $val) > 1) {
 297             $loader_args{$key} = \@vals;
 298         } else {
 299             $loader_args{$key} = $val;
 300         }
 301     }
 302
 303     # Use args after connect_info as loader args as well, because people always
 304     # get the order confused.
 305     my $i = 1;
 306     if ($args->[0] =~ /sqlite/i) {
 307         $i++ if $args->[$i] eq '';
 308         $i++ if $args->[$i] eq '';
 309     }
 310     else {
 311         $i += 2;
 312     }
 313
 314     while (defined $args->[$i]) {
 315         $i++ while $self->_is_struct($args->[$i]);
 316
 317         last if not defined $args->[$i];
 318
 319         my ($key, $val) = split /=/, $args->[$i++], 2;
 320
 321         if ($self->_is_struct($val)) {
 322             $loader_args{$key} = $val;
 323         } elsif ((my @vals = split /,/ => $val) > 1) {
 324             $loader_args{$key} = \@vals;
 325         } else {
 326             $loader_args{$key} = $val;
 327         }
 328     }
 329
 330     wantarray ? %loader_args : \%loader_args;
 331 }
 332
 333 sub _build_helper_loader_args {
 334     my $self = shift;
 335
 336     my $args = $self->loader_args;
 337
 338     tie my %loader_args, 'Tie::IxHash';
 339
 340     while (my ($arg, $val) = each %$args) {
 341         if (ref $val) {
 342             $loader_args{$arg} = $self->_data_struct_to_string($val);
 343         } else {
 344             $loader_args{$arg} = qq{'$val'};
 345         }
 346     }
 347
 348     \%loader_args
 349 }
 350
 351 sub _build_loader_components {
 352     my ($self, $components, $use_namespaces) = @_;
 353
 354     my @components = $self->old_schema && (not $use_namespaces) ? ()
 355         : ('InflateColumn::DateTime');
 356
 357     if ($components) {
 358         $components = [ $components ] if !ref $components;
 359         push @components, @$components;
 360     }
 361
 362     wantarray ? @components : \@components;
 363 }
 364
 365 sub _build_helper_connect_info {
 366     my ($self, $connect_info) = @_;
 367
 368     my @connect_info = @$connect_info;
 369
 370     my ($dsn, $user, $password) = $self->_get_dsn_user_pass(\@connect_info);
 371
 372     tie my %helper_connect_info, 'Tie::IxHash';
 373
 374     %helper_connect_info = (
 375         dsn => qq{'$dsn'},
 376         user => qq{'$user'},
 377         password => qq{'$password'}
 378     );
 379
 380     for (@connect_info) {
 381         if (/^\s*{.*}\s*\z/) {
 382             my $hash = $self->_eval($_);
 383             die "Syntax errorr in connect_info hash: $_: $@" if $@;
 384             my %hash = %$hash;
 385
 386             for my $key (keys %hash) {
 387                 my $val = $hash{$key};
 388
 389                 if (ref $val) {
 390                     $val = $self->_data_struct_to_string($val);
 391                 } else {
 392                     $val = $self->_quote($val);
 393                 }
 394
 395                 $helper_connect_info{$key} = $val;
 396             }
 397
 398             next;
 399         }
 400
 401         my ($key, $val) = split /=/, $_, 2;
 402
 403         if ($key eq 'quote_char') {
 404             $helper_connect_info{$key} = length($val) == 1 ?
 405                 $self->_quote($val) :
 406                 $self->_data_struct_to_string([split //, $val]);
 407         } else {
 408             $helper_connect_info{$key} = $self->_quote_unless_struct($val);
 409         }
 410     }
 411
 412     \%helper_connect_info
 413 }
 414
 415 sub _build_old_schema {
 416     my $self = shift;
 417
 418     return $self->result_namespace eq '' ? 1 : 0;
 419 }
 420
 421 sub _build_is_moose_schema {
 422     my $self = shift;
 423
 424     my @schema_parts = split '::', $self->schema_class;
 425
 426     my $result_dir = File::Spec->catfile(
 427         $self->helper->{base}, 'lib', @schema_parts, $self->result_namespace
 428     );
 429
 430     # assume yes for new schemas
 431     return 1 if not -d $result_dir;
 432
 433     my $uses_moose = 1;
 434
 435     my $cwd = getcwd;
 436
 437     try {
 438         finddepth(sub {
 439             return if $File::Find::name !~ /\.pm\z/;
 440
 441             open my $fh, '<', $File::Find::name
 442                 or die "Could not open $File::Find::name: $!";
 443
 444             my $code = do { local $/; <$fh> };
 445             close $fh;
 446
 447             $uses_moose = 0 if $code !~ /\nuse Moose;\n/;
 448
 449             die;
 450         }, $result_dir);
 451     };
 452
 453     chdir $cwd;
 454
 455     return $uses_moose;
 456 }
 457
 458 sub _build_result_namespace {
 459     my $self = shift;
 460
 461     my @schema_parts = split '::', $self->schema_class;
 462     my $schema_pm =
 463         File::Spec->catfile($self->helper->{base}, 'lib', @schema_parts) . '.pm';
 464
 465     if (not -f $schema_pm) {
 466         eval { Class::MOP::load_class('DBIx::Class::Schema::Loader') };
 467
 468         return 'Result' if $@;
 469
 470         return (try { DBIx::Class::Schema::Loader->VERSION('0.05') }) ? 'Result' : '';
 471     }
 472
 473     open my $fh, '<', $schema_pm or die "Could not open $schema_pm: $!";
 474     my $code = do { local $/; <$fh> };
 475     close $fh;
 476
 477     my ($result_namespace) = $code =~ /result_namespace => '([^']+)'/;
 478
 479     return $result_namespace if $result_namespace;
 480
 481     return '' if $code =~ /->load_classes/;
 482
 483     return 'Result';
 484 }
 485
 486 sub _data_struct_to_string {
 487     my ($self, $data) = @_;
 488
 489     local $Data::Dumper::Terse = 1;
 490     local $Data::Dumper::Quotekeys = 0;
 491     local $Data::Dumper::Indent = 0;
 492     local $Data::Dumper::Useqq = 1;
 493
 494     return Data::Dumper->Dump([$data]);
 495 }
 496
 497 sub _get_dsn_user_pass {
 498     my ($self, $connect_info) = @_;
 499
 500     my $dsn = shift @$connect_info;
 501     my ($user, $password);
 502
 503     if ($dsn =~ /sqlite/i) {
 504         ($user, $password) = ('', '');
 505         shift @$connect_info while @$connect_info and $connect_info->[0] eq '';
 506     } else {
 507         ($user, $password) = splice @$connect_info, 0, 2;
 508     }
 509
 510     ($dsn, $user, $password)
 511 }
 512
 513 sub _parse_connect_info {
 514     my ($self, $connect_info) = @_;
 515
 516     my @connect_info = @$connect_info;
 517
 518     my ($dsn, $user, $password) = $self->_get_dsn_user_pass(\@connect_info);
 519
 520     tie my %connect_info, 'Tie::IxHash';
 521     @connect_info{qw/dsn user password/} = ($dsn, $user, $password);
 522
 523     for (@connect_info) {
 524         if (/^\s*{.*}\s*\z/) {
 525             my $hash = $self->_eval($_);
 526             die "Syntax errorr in connect_info hash: $_: $@" if $@;
 527
 528             %connect_info = (%connect_info, %$hash);
 529
 530             next;
 531         }
 532
 533         my ($key, $val) = split /=/, $_, 2;
 534
 535         if ($key eq 'quote_char') {
 536             $connect_info{$key} = length($val) == 1 ? $val : [split //, $val];
 537         } elsif ($key =~ /^(?:name_sep|limit_dialect)\z/) {
 538             $connect_info{$key} = $val;
 539         } else {
 540             $connect_info{$key} = $self->_eval($val);
 541         }
 542
 543         die "syntax error for connect_info key '$key' with value '$val': $@"
 544             if $@;
 545     }
 546
 547     $self->connect_info(\%connect_info);
 548
 549     \%connect_info
 550 }
 551
 552 sub _is_struct {
 553     my ($self, $val) = @_;
 554
 555     return $val =~ /^\s*(?:sub|[[{])/;
 556 }
 557
 558 sub _quote {
 559     my ($self, $val) = @_;
 560
 561     return 'q{'.$val.'}';
 562 }
 563
 564 sub _quote_unless_struct {
 565     my ($self, $val) = @_;
 566
 567     $val = $self->_quote($val) if not $self->_is_struct($val);
 568
 569     return $val;
 570 }
 571
 572 sub _eval {
 573     my ($self, $code) = @_;
 574
 575     return $code if looks_like_number $code;
 576
 577     return $code if not $self->_is_struct($code);
 578
 579     return eval "{no strict; $code}";
 580 }
 581
 582 sub _gen_dynamic_schema {
 583     my $self = shift;
 584
 585     my $helper = $self->helper;
 586
 587     my @schema_parts = split(/\:\:/, $self->schema_class);
 588     my $schema_file_part = pop @schema_parts;
 589
 590     my $schema_dir  = File::Spec->catfile(
 591         $helper->{base}, 'lib', @schema_parts
 592     );
 593     my $schema_file = File::Spec->catfile(
 594         $schema_dir, $schema_file_part . '.pm'
 595     );
 596
 597     $helper->mk_dir($schema_dir);
 598     $helper->render_file('schemaclass', $schema_file);
 599 }
 600
 601 sub _gen_static_schema {
 602     my $self = shift;
 603
 604     die "cannot load schema without connect info" unless $self->connect_info;
 605
 606     my $helper = $self->helper;
 607
 608     my $schema_dir = File::Spec->catfile($helper->{base}, 'lib');
 609
 610     try {
 611         Class::MOP::load_class('DBIx::Class::Schema::Loader')
 612     }
 613     catch {
 614         die "Cannot load DBIx::Class::Schema::Loader: $_";
 615     };
 616
 617     DBIx::Class::Schema::Loader->import(
 618         "dump_to_dir:$schema_dir", 'make_schema_at'
 619     );
 620
 621     make_schema_at(
 622         $self->schema_class,
 623         $self->loader_args,
 624         [$self->connect_info]
 625     );
 626
 627     require lib;
 628     lib->import($schema_dir);
 629
 630     Class::MOP::load_class($self->schema_class);
 631
 632     my @sources = $self->schema_class->sources;
 633
 634     if (not @sources) {
 635         warn <<'EOF';
 636 WARNING: No tables found, did you forget to specify db_schema?
 637 EOF
 638     }
 639 }
 640
 641 sub _gen_model {
 642     my $self = shift;
 643     my $helper = $self->helper;
 644
 645     $helper->render_file('compclass', $helper->{file} );
 646 }
 647
 648 sub _print_dynamic_deprecation_warning {
 649     warn <<EOF;
 650 ************************************ WARNING **********************************
 651 * create=dynamic is DEPRECATED, please use create=static instead.             *
 652 *******************************************************************************
 653 EOF
 654     print "Continue? [y/n]: ";
 655     chomp(my $response = <STDIN>);
 656     exit 0 if $response =~ /^n(o)?\z/;
 657 }
 658
 659 sub _cleanup_args {
 660     my ($self, $args) = @_;
 661
 662 # remove blanks, ie. someoned doing foo \  bar
 663     my @res = grep !/^\s+\z/, @$args;
 664
 665 # remove leading whitespace, ie. foo \ bar
 666     s/^\s*// for @res;
 667
 668     @res
 669 }
 670
 671 =head1 SEE ALSO
 672
 673 General Catalyst Stuff:
 674
 675 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 676 L<Catalyst::Response>, L<Catalyst::Helper>, L<Catalyst>,
 677
 678 Stuff related to DBIC and this Model style:
 679
 680 L<DBIx::Class>, L<DBIx::Class::Schema>,
 681 L<DBIx::Class::Schema::Loader>, L<Catalyst::Model::DBIC::Schema>
 682
 683 =head1 AUTHOR
 684
 685 See L<Catalyst::Model::DBIC::Schema/AUTHOR> and
 686 L<Catalyst::Model::DBIC::Schema/CONTRIBUTORS>.
 687
 688 =head1 COPYRIGHT
 689
 690 See L<Catalyst::Model::DBIC::Schema/COPYRIGHT>.
 691
 692 =head1 LICENSE
 693
 694 This library is free software, you can redistribute it and/or modify
 695 it under the same terms as Perl itself.
 696
 697 =cut
 698
 699 1;
 700
 701 __DATA__
 702
 703 =begin pod_to_ignore
 704
 705 __schemaclass__
 706 package [% schema_class %];
 707
 708 use strict;
 709 use base qw/DBIx::Class::Schema::Loader/;
 710
 711 __PACKAGE__->loader_options(
 712     [%- FOREACH key = loader_args.keys %]
 713     [% key %] => [% loader_args.${key} %],
 714     [%- END -%]
 715
 716 );
 717
 718 =head1 NAME
 719
 720 [% schema_class %] - L<DBIx::Class::Schema::Loader> class
 721
 722 =head1 SYNOPSIS
 723
 724 See L<[% app %]>
 725
 726 =head1 DESCRIPTION
 727
 728 Dynamic L<DBIx::Class::Schema::Loader> schema for use in L<[% class %]>
 729
 730 =head1 GENERATED BY
 731
 732 [% generator %] - [% generator_version %]
 733
 734 =head1 AUTHOR
 735
 736 [% author.replace(',+$', '') %]
 737
 738 =head1 LICENSE
 739
 740 This library is free software, you can redistribute it and/or modify
 741 it under the same terms as Perl itself.
 742
 743 =cut
 744
 745 1;
 746
 747 __compclass__
 748 package [% class %];
 749
 750 use strict;
 751 use base 'Catalyst::Model::DBIC::Schema';
 752
 753 __PACKAGE__->config(
 754     schema_class => '[% schema_class %]',
 755     [% IF traits %]traits => [% traits %],[% END %]
 756     [% IF setup_connect_info %]connect_info => {
 757         [%- FOREACH key = connect_info.keys %]
 758         [% key %] => [% connect_info.${key} %],
 759         [%- END -%]
 760
 761     }[% END %]
 762 );
 763
 764 =head1 NAME
 765
 766 [% class %] - Catalyst DBIC Schema Model
 767
 768 =head1 SYNOPSIS
 769
 770 See L<[% app %]>
 771
 772 =head1 DESCRIPTION
 773
 774 L<Catalyst::Model::DBIC::Schema> Model using schema L<[% schema_class %]>
 775
 776 =head1 GENERATED BY
 777
 778 [% generator %] - [% generator_version %]
 779
 780 =head1 AUTHOR
 781
 782 [% author.replace(',+$', '') %]
 783
 784 =head1 LICENSE
 785
 786 This library is free software, you can redistribute it and/or modify
 787 it under the same terms as Perl itself.
 788
 789 =cut
 790
 791 1;
 792 __END__
 793 # vim:sts=4 sw=4: