lib/Catalyst/Helper/Model/DBIC/Schema.pm

   1 package Catalyst::Helper::Model::DBIC::Schema;
   2
   3 use namespace::autoclean;
   4 use Moose;
   5 no warnings 'uninitialized';
   6
   7 our $VERSION = '0.33';
   8 $VERSION = eval $VERSION;
   9
  10 use Carp;
  11 use Tie::IxHash ();
  12 use Data::Dumper ();
  13 use List::Util 'first';
  14 use MooseX::Types::Moose qw/Str HashRef Bool ArrayRef/;
  15 use Catalyst::Model::DBIC::Schema::Types 'CreateOption';
  16 use List::MoreUtils 'firstidx';
  17 use Scalar::Util 'looks_like_number';
  18
  19 =head1 NAME
  20
  21 Catalyst::Helper::Model::DBIC::Schema - Helper for DBIC Schema Models
  22
  23 =head1 SYNOPSIS
  24
  25   script/create.pl model CatalystModelName DBIC::Schema MyApp::SchemaClass \
  26     [ create=dynamic | create=static ] [ traits=trait1,trait2... ] \
  27     [ Schema::Loader opts ] [ dsn user pass ] \
  28     [ other connect_info args ]
  29
  30 =head1 DESCRIPTION
  31
  32 Helper for the DBIC Schema Models.
  33
  34 =head2 Arguments:
  35
  36 C<CatalystModelName> is the short name for the Catalyst Model class
  37 being generated (i.e. callable with C<$c-E<gt>model('CatalystModelName')>).
  38
  39 C<MyApp::SchemaClass> is the fully qualified classname of your Schema,
  40 which might or might not yet exist.  Note that you should have a good
  41 reason to create this under a new global namespace, otherwise use an
  42 existing top level namespace for your schema class.
  43
  44 C<create=dynamic> instructs this Helper to generate the named Schema
  45 class for you, basing it on L<DBIx::Class::Schema::Loader> (which
  46 means the table information will always be dynamically loaded at
  47 runtime from the database).
  48
  49 C<create=static> instructs this Helper to generate the named Schema
  50 class for you, using L<DBIx::Class::Schema::Loader> in "one shot"
  51 mode to create a standard, manually-defined L<DBIx::Class::Schema>
  52 setup, based on what the Loader sees in your database at this moment.
  53 A Schema/Model pair generated this way will not require
  54 L<DBIx::Class::Schema::Loader> at runtime, and will not automatically
  55 adapt itself to changes in your database structure.  You can edit
  56 the generated classes by hand to refine them.
  57
  58 C<traits> is the list of traits to apply to the model, see
  59 L<Catalyst::Model::DBIC::Schema> for details.
  60
  61 C<Schema::Loader opts> are described in L</TYPICAL EXAMPLES> below.
  62
  63 C<connect_info> arguments are the same as what
  64 DBIx::Class::Schema::connect expects, and are storage_type-specific.
  65 For DBI-based storage, these arguments are the dsn, username,
  66 password, and connect options, respectively.  These are optional for
  67 existing Schemas, but required if you use either of the C<create=>
  68 options.
  69
  70 username and password can be omitted for C<SQLite> dsns.
  71
  72 Use of either of the C<create=> options requires L<DBIx::Class::Schema::Loader>.
  73
  74 =head1 TYPICAL EXAMPLES
  75
  76 Use DBIx::Class::Schema::Loader to create a static DBIx::Class::Schema,
  77 and a Model which references it:
  78
  79   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  80     MyApp::SchemaClass create=static dbi:mysql:foodb myuname mypass
  81
  82 Same, with extra connect_info args
  83 user and pass can be omitted for sqlite, since they are always empty
  84
  85   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  86     MyApp::SchemaClass create=static dbi:SQLite:foo.db \
  87     AutoCommit=1 cursor_class=DBIx::Class::Cursor::Cached \
  88     on_connect_do='["select 1", "select 2"]' quote_char='"'
  89
  90 If using a 2 character quote_char:
  91
  92   script/myapp_create.pl ... quote_char='[]'
  93
  94 B<ON WINDOWS COMMAND LINES QUOTING RULES ARE DIFFERENT>
  95
  96 In C<cmd.exe> the above example would be:
  97
  98   script/myapp_create.pl model CatalystModelName DBIC::Schema \
  99     MyApp::SchemaClass create=static dbi:SQLite:foo.db \
 100     AutoCommit=1 cursor_class=DBIx::Class::Cursor::Cached \
 101     on_connect_do="[\"select 1\", \"select 2\"]" quote_char="\""
 102
 103 Same, but with extra Schema::Loader args (separate multiple values by commas):
 104
 105   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 106     MyApp::SchemaClass create=static db_schema=foodb components=Foo,Bar \
 107     exclude='^(wibble|wobble)$' moniker_map='{ foo => "FOO" }' \
 108     dbi:Pg:dbname=foodb myuname mypass
 109
 110 Coderefs are also supported:
 111
 112   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 113     MyApp::SchemaClass create=static \
 114     inflect_singular='sub { $_[0] =~ /\A(.+?)(_id)?\z/; $1 }' \
 115     moniker_map='sub { join(q{}, map ucfirst, split(/[\W_]+/, lc $_[0])); }' \
 116     dbi:mysql:foodb myuname mypass
 117
 118 See L<DBIx::Class::Schema::Loader::Base> for a list of options
 119
 120 Create a dynamic DBIx::Class::Schema::Loader-based Schema,
 121 and a Model which references it (B<DEPRECATED>):
 122
 123   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 124     MyApp::SchemaClass create=dynamic dbi:mysql:foodb myuname mypass
 125
 126 Reference an existing Schema of any kind, and provide some connection information for ->config:
 127
 128   script/myapp_create.pl model CatalystModelName DBIC::Schema \
 129     MyApp::SchemaClass dbi:mysql:foodb myuname mypass
 130
 131 Same, but don't supply connect information yet (you'll need to do this
 132 in your app config, or [not recommended] in the schema itself).
 133
 134   script/myapp_create.pl model ModelName DBIC::Schema My::SchemaClass
 135
 136 =cut
 137
 138 has helper => (is => 'ro', isa => 'Catalyst::Helper', required => 1);
 139 has create => (is => 'rw', isa => CreateOption);
 140 has args => (is => 'ro', isa => ArrayRef);
 141 has traits => (is => 'rw', isa => ArrayRef);
 142 has schema_class => (is => 'ro', isa => Str, required => 1);
 143 has loader_args => (is => 'rw', isa => HashRef);
 144 has connect_info => (is => 'rw', isa => HashRef);
 145 has old_schema => (is => 'rw', isa => Bool, lazy_build => 1);
 146 has components => (is => 'rw', isa => ArrayRef);
 147
 148 =head1 METHODS
 149
 150 =head2 mk_compclass
 151
 152 This is called by L<Catalyst::Helper> with the commandline args to generate the
 153 files.
 154
 155 =cut
 156
 157 sub mk_compclass {
 158     my ($package, $helper, $schema_class, @args) = @_;
 159
 160     my $self = $package->new(
 161         helper => $helper,
 162         schema_class => $schema_class,
 163         args => \@args
 164     );
 165
 166     $self->run;
 167 }
 168
 169 sub BUILD {
 170     my $self   = shift;
 171     my $helper = $self->helper;
 172     my @args   = @{ $self->args || [] };
 173
 174     $helper->{schema_class} = $self->schema_class;
 175
 176     @args = $self->_cleanup_args(\@args);
 177
 178     my ($traits_idx, $traits);
 179     if (($traits_idx = firstidx { ($traits) = /^traits=(\S*)\z/ } @args) != -1) {
 180         my @traits = split /,/ => $traits;
 181
 182         $self->traits(\@traits);
 183
 184         $helper->{traits} = '['
 185             .(join ',' => map { qq{'$_'} } @traits)
 186             .']';
 187
 188         splice @args, $traits_idx, 1, ();
 189     }
 190
 191     if ($args[0] && $args[0] =~ /^create=(\S*)\z/) {
 192         $self->create($1);
 193         shift @args;
 194
 195         if (@args) {
 196             $self->_parse_loader_args(\@args);
 197
 198             $helper->{loader_args} = $self->_build_helper_loader_args;
 199         }
 200     }
 201
 202     my $dbi_dsn_part;
 203     if (first { ($dbi_dsn_part) = /^(dbi):/i } @args) {
 204         die
 205 qq{DSN must start with 'dbi:' not '$dbi_dsn_part' (case matters!)}
 206             if $dbi_dsn_part ne 'dbi';
 207
 208         $helper->{setup_connect_info} = 1;
 209
 210         $helper->{connect_info} =
 211             $self->_build_helper_connect_info(\@args);
 212
 213         $self->_parse_connect_info(\@args);
 214     }
 215
 216     $helper->{generator} = ref $self;
 217     $helper->{generator_version} = $VERSION;
 218 }
 219
 220 =head2 run
 221
 222 Can be called on an instance to generate the files.
 223
 224 =cut
 225
 226 sub run {
 227     my $self = shift;
 228
 229     if ($self->create eq 'dynamic') {
 230         $self->_print_dynamic_deprecation_warning;
 231         $self->_gen_dynamic_schema;
 232     } elsif ($self->create eq 'static') {
 233         $self->_gen_static_schema;
 234     }
 235
 236     $self->_gen_model;
 237 }
 238
 239 sub _parse_loader_args {
 240     my ($self, $args) = @_;
 241
 242     my %loader_args = $self->_read_loader_args($args);
 243
 244     while (my ($key, $val) = each %loader_args) {
 245         next if $key =~ /^(?:components|constraint|exclude)\z/;
 246
 247         $loader_args{$key} = $self->_eval($val);
 248         die "syntax error for loader args key '$key' with value '$val': $@"
 249             if $@;
 250     }
 251
 252     my @components =
 253     $self->_build_loader_components(delete $loader_args{components});
 254
 255     $self->components(\@components);
 256
 257     for my $re_opt (qw/constraint exclude/) {
 258         $loader_args{$re_opt} = qr/$loader_args{$re_opt}/
 259         if exists $loader_args{$re_opt};
 260     }
 261
 262     tie my %result, 'Tie::IxHash';
 263
 264     %result = (
 265         relationships => 1,
 266         (%loader_args ? %loader_args : ()),
 267         (!$self->old_schema ? (
 268                 use_namespaces => 1
 269             ) : ()),
 270         (@components ? (
 271                 components => \@components
 272             ) : ())
 273     );
 274
 275     $self->loader_args(\%result);
 276
 277     wantarray ? %result : \%result;
 278 }
 279
 280 sub _read_loader_args {
 281     my ($self, $args) = @_;
 282
 283     my %loader_args;
 284
 285     while (@$args && $args->[0] !~ /^dbi:/i) {
 286         my ($key, $val) = split /=/, shift(@$args), 2;
 287
 288         if ($self->_is_struct($val)) {
 289             $loader_args{$key} = $val;
 290         } elsif ((my @vals = split /,/ => $val) > 1) {
 291             $loader_args{$key} = \@vals;
 292         } else {
 293             $loader_args{$key} = $val;
 294         }
 295     }
 296
 297     wantarray ? %loader_args : \%loader_args;
 298 }
 299
 300 sub _build_helper_loader_args {
 301     my $self = shift;
 302
 303     my $args = $self->loader_args;
 304
 305     tie my %loader_args, 'Tie::IxHash';
 306
 307     while (my ($arg, $val) = each %$args) {
 308         if (ref $val) {
 309             $loader_args{$arg} = $self->_data_struct_to_string($val);
 310         } else {
 311             $loader_args{$arg} = qq{'$val'};
 312         }
 313     }
 314
 315     \%loader_args
 316 }
 317
 318 sub _build_loader_components {
 319     my ($self, $components) = @_;
 320
 321     my @components = $self->old_schema ? () : ('InflateColumn::DateTime');
 322
 323     if ($components) {
 324         $components = [ $components ] if !ref $components;
 325         push @components, @$components;
 326     }
 327
 328     wantarray ? @components : \@components;
 329 }
 330
 331 sub _build_helper_connect_info {
 332     my ($self, $connect_info) = @_;
 333
 334     my @connect_info = @$connect_info;
 335
 336     my ($dsn, $user, $password) = $self->_get_dsn_user_pass(\@connect_info);
 337
 338     tie my %helper_connect_info, 'Tie::IxHash';
 339
 340     %helper_connect_info = (
 341         dsn => qq{'$dsn'},
 342         user => qq{'$user'},
 343         password => qq{'$password'}
 344     );
 345
 346     for (@connect_info) {
 347         if (/^\s*{.*}\s*\z/) {
 348             my $hash = $self->_eval($_);
 349             die "Syntax errorr in connect_info hash: $_: $@" if $@;
 350             my %hash = %$hash;
 351
 352             for my $key (keys %hash) {
 353                 my $val = $hash{$key};
 354
 355                 if (ref $val) {
 356                     $val = $self->_data_struct_to_string($val);
 357                 } else {
 358                     $val = $self->_quote($val);
 359                 }
 360
 361                 $helper_connect_info{$key} = $val;
 362             }
 363
 364             next;
 365         }
 366
 367         my ($key, $val) = split /=/, $_, 2;
 368
 369         if ($key eq 'quote_char') {
 370             $helper_connect_info{$key} = length($val) == 1 ?
 371                 $self->_quote($val) :
 372                 $self->_data_struct_to_string([split //, $val]);
 373         } else {
 374             $helper_connect_info{$key} = $self->_quote_unless_struct($val);
 375         }
 376     }
 377
 378     \%helper_connect_info
 379 }
 380
 381 sub _build_old_schema {
 382     my $self = shift;
 383
 384     my @schema_pm   = split '::', $self->schema_class;
 385     $schema_pm[-1] .= '.pm';
 386     my $schema_file =
 387     File::Spec->catfile($self->helper->{base}, 'lib', @schema_pm);
 388
 389     if (-f $schema_file) {
 390         my $schema_code = do { local (@ARGV, $/) = $schema_file; <> };
 391         return 1 if $schema_code =~ /->load_classes/;
 392     }
 393
 394     0;
 395 }
 396
 397 sub _data_struct_to_string {
 398     my ($self, $data) = @_;
 399
 400     local $Data::Dumper::Terse = 1;
 401     local $Data::Dumper::Quotekeys = 0;
 402     local $Data::Dumper::Indent = 0;
 403     local $Data::Dumper::Useqq = 1;
 404
 405     return Data::Dumper->Dump([$data]);
 406 }
 407
 408 sub _get_dsn_user_pass {
 409     my ($self, $connect_info) = @_;
 410
 411     my $dsn = shift @$connect_info;
 412     my ($user, $password);
 413
 414     if ($dsn =~ /sqlite/i) {
 415         ($user, $password) = ('', '');
 416         shift @$connect_info while @$connect_info and $connect_info->[0] eq '';
 417     } else {
 418         ($user, $password) = splice @$connect_info, 0, 2;
 419     }
 420
 421     ($dsn, $user, $password)
 422 }
 423
 424 sub _parse_connect_info {
 425     my ($self, $connect_info) = @_;
 426
 427     my @connect_info = @$connect_info;
 428
 429     my ($dsn, $user, $password) = $self->_get_dsn_user_pass(\@connect_info);
 430
 431     tie my %connect_info, 'Tie::IxHash';
 432     @connect_info{qw/dsn user password/} = ($dsn, $user, $password);
 433
 434     for (@connect_info) {
 435         if (/^\s*{.*}\s*\z/) {
 436             my $hash = $self->_eval($_);
 437             die "Syntax errorr in connect_info hash: $_: $@" if $@;
 438
 439             %connect_info = (%connect_info, %$hash);
 440
 441             next;
 442         }
 443
 444         my ($key, $val) = split /=/, $_, 2;
 445
 446         if ($key eq 'quote_char') {
 447             $connect_info{$key} = length($val) == 1 ? $val : [split //, $val];
 448         } elsif ($key =~ /^(?:name_sep|limit_dialect)\z/) {
 449             $connect_info{$key} = $val;
 450         } else {
 451             $connect_info{$key} = $self->_eval($val);
 452         }
 453
 454         die "syntax error for connect_info key '$key' with value '$val': $@"
 455             if $@;
 456     }
 457
 458     $self->connect_info(\%connect_info);
 459
 460     \%connect_info
 461 }
 462
 463 sub _is_struct {
 464     my ($self, $val) = @_;
 465
 466     return $val =~ /^\s*(?:sub|[[{])/;
 467 }
 468
 469 sub _quote {
 470     my ($self, $val) = @_;
 471
 472     return 'q{'.$val.'}';
 473 }
 474
 475 sub _quote_unless_struct {
 476     my ($self, $val) = @_;
 477
 478     $val = $self->_quote($val) if not $self->_is_struct($val);
 479
 480     return $val;
 481 }
 482
 483 sub _eval {
 484     my ($self, $code) = @_;
 485
 486     return $code if looks_like_number $code;
 487
 488     return $code if $code =~ m{^[\w;:/]*\z};
 489
 490     return eval "{no strict; $code}";
 491 }
 492
 493 sub _gen_dynamic_schema {
 494     my $self = shift;
 495
 496     my $helper = $self->helper;
 497
 498     my @schema_parts = split(/\:\:/, $self->schema_class);
 499     my $schema_file_part = pop @schema_parts;
 500
 501     my $schema_dir  = File::Spec->catfile(
 502         $helper->{base}, 'lib', @schema_parts
 503     );
 504     my $schema_file = File::Spec->catfile(
 505         $schema_dir, $schema_file_part . '.pm'
 506     );
 507
 508     $helper->mk_dir($schema_dir);
 509     $helper->render_file('schemaclass', $schema_file);
 510 }
 511
 512 sub _gen_static_schema {
 513     my $self = shift;
 514
 515     die "cannot load schema without connect info" unless $self->connect_info;
 516
 517     my $helper = $self->helper;
 518
 519     my $schema_dir = File::Spec->catfile($helper->{base}, 'lib');
 520
 521     eval { Class::MOP::load_class('DBIx::Class::Schema::Loader') };
 522     die "Cannot load DBIx::Class::Schema::Loader: $@" if $@;
 523
 524     DBIx::Class::Schema::Loader->import(
 525         "dump_to_dir:$schema_dir", 'make_schema_at'
 526     );
 527
 528     make_schema_at(
 529         $self->schema_class,
 530         $self->loader_args,
 531         [$self->connect_info]
 532     );
 533 }
 534
 535 sub _gen_model {
 536     my $self = shift;
 537     my $helper = $self->helper;
 538
 539     $helper->render_file('compclass', $helper->{file} );
 540 }
 541
 542 sub _print_dynamic_deprecation_warning {
 543     warn <<EOF;
 544 ************************************ WARNING **********************************
 545 * create=dynamic is DEPRECATED, please use create=static instead.             *
 546 *******************************************************************************
 547 EOF
 548     print "Continue? [y/n]: ";
 549     chomp(my $response = <STDIN>);
 550     exit 0 if $response =~ /^n(o)?\z/;
 551 }
 552
 553 sub _cleanup_args {
 554     my ($self, $args) = @_;
 555
 556 # remove blanks, ie. someoned doing foo \  bar
 557     my @res = grep !/^\s+\z/, @$args;
 558
 559 # remove leading whitespace, ie. foo \ bar
 560     s/^\s*// for @res;
 561
 562     @res
 563 }
 564
 565 =head1 SEE ALSO
 566
 567 General Catalyst Stuff:
 568
 569 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 570 L<Catalyst::Response>, L<Catalyst::Helper>, L<Catalyst>,
 571
 572 Stuff related to DBIC and this Model style:
 573
 574 L<DBIx::Class>, L<DBIx::Class::Schema>,
 575 L<DBIx::Class::Schema::Loader>, L<Catalyst::Model::DBIC::Schema>
 576
 577 =head1 AUTHOR
 578
 579 See L<Catalyst::Model::DBIC::Schema/AUTHOR> and
 580 L<Catalyst::Model::DBIC::Schema/CONTRIBUTORS>.
 581
 582 =head1 COPYRIGHT
 583
 584 See L<Catalyst::Model::DBIC::Schema/COPYRIGHT>.
 585
 586 =head1 LICENSE
 587
 588 This library is free software, you can redistribute it and/or modify
 589 it under the same terms as Perl itself.
 590
 591 =cut
 592
 593 1;
 594
 595 __DATA__
 596
 597 =begin pod_to_ignore
 598
 599 __schemaclass__
 600 package [% schema_class %];
 601
 602 use strict;
 603 use base qw/DBIx::Class::Schema::Loader/;
 604
 605 __PACKAGE__->loader_options(
 606     [%- FOREACH key = loader_args.keys %]
 607     [% key %] => [% loader_args.${key} %],
 608     [%- END -%]
 609
 610 );
 611
 612 =head1 NAME
 613
 614 [% schema_class %] - L<DBIx::Class::Schema::Loader> class
 615
 616 =head1 SYNOPSIS
 617
 618 See L<[% app %]>
 619
 620 =head1 DESCRIPTION
 621
 622 Dynamic L<DBIx::Class::Schema::Loader> schema for use in L<[% class %]>
 623
 624 =head1 GENERATED BY
 625
 626 [% generator %] - [% generator_version %]
 627
 628 =head1 AUTHOR
 629
 630 [% author.replace(',+$', '') %]
 631
 632 =head1 LICENSE
 633
 634 This library is free software, you can redistribute it and/or modify
 635 it under the same terms as Perl itself.
 636
 637 =cut
 638
 639 1;
 640
 641 __compclass__
 642 package [% class %];
 643
 644 use strict;
 645 use base 'Catalyst::Model::DBIC::Schema';
 646
 647 __PACKAGE__->config(
 648     schema_class => '[% schema_class %]',
 649     [% IF traits %]traits => [% traits %],[% END %]
 650     [% IF setup_connect_info %]connect_info => {
 651         [%- FOREACH key = connect_info.keys %]
 652         [% key %] => [% connect_info.${key} %],
 653         [%- END -%]
 654
 655     }[% END %]
 656 );
 657
 658 =head1 NAME
 659
 660 [% class %] - Catalyst DBIC Schema Model
 661
 662 =head1 SYNOPSIS
 663
 664 See L<[% app %]>
 665
 666 =head1 DESCRIPTION
 667
 668 L<Catalyst::Model::DBIC::Schema> Model using schema L<[% schema_class %]>
 669
 670 =head1 GENERATED BY
 671
 672 [% generator %] - [% generator_version %]
 673
 674 =head1 AUTHOR
 675
 676 [% author.replace(',+$', '') %]
 677
 678 =head1 LICENSE
 679
 680 This library is free software, you can redistribute it and/or modify
 681 it under the same terms as Perl itself.
 682
 683 =cut
 684
 685 1;
 686 __END__
 687 # vim:sts=4 sw=4: