lib/Catalyst/Manual/Tutorial/Authorization.pod

   1 =head1 NAME
   2
   3 Catalyst::Manual::Tutorial::Authorization - Catalyst Tutorial - Part 6: Authorization
   4
   5
   6 =head1 OVERVIEW
   7
   8 This is B<Part 6 of 10> for the Catalyst tutorial.
   9
  10 L<Tutorial Overview|Catalyst::Manual::Tutorial>
  11
  12 =over 4
  13
  14 =item 1
  15
  16 L<Introduction|Catalyst::Manual::Tutorial::Intro>
  17
  18 =item 2
  19
  20 L<Catalyst Basics|Catalyst::Manual::Tutorial::CatalystBasics>
  21
  22 =item 3
  23
  24 L<More Catalyst Basics|Catalyst::Manual::Tutorial::MoreCatalystBasics>
  25
  26 =item 4
  27
  28 L<Basic CRUD|Catalyst::Manual::Tutorial::BasicCRUD>
  29
  30 =item 5
  31
  32 L<Authentication|Catalyst::Manual::Tutorial::Authentication>
  33
  34 =item 6
  35
  36 B<Authorization>
  37
  38 =item 7
  39
  40 L<Debugging|Catalyst::Manual::Tutorial::Debugging>
  41
  42 =item 8
  43
  44 L<Testing|Catalyst::Manual::Tutorial::Testing>
  45
  46 =item 9
  47
  48 L<Advanced CRUD|Catalyst::Manual::Tutorial::AdvancedCRUD>
  49
  50 =item 10
  51
  52 L<Appendices|Catalyst::Manual::Tutorial::Appendices>
  53
  54 =back
  55
  56
  57 =head1 DESCRIPTION
  58
  59 This part of the tutorial adds role-based authorization to the existing
  60 authentication implemented in Part 5.  It provides simple examples of
  61 how to use roles in both TT templates and controller actions.  The first
  62 half looks at manually configured authorization.  The second half looks
  63 at how the ACL authorization plugin can simplify your code.
  64
  65 You can checkout the source code for this example from the catalyst
  66 subversion repository as per the instructions in
  67 L<Catalyst::Manual::Tutorial::Intro>
  68
  69 =head1 BASIC AUTHORIZATION
  70
  71 In this section you learn how to manually configure authorization.
  72
  73 =head2 Update Plugins to Include Support for Authorization
  74
  75 Edit C<lib/MyApp.pm> and add C<Authorization::Roles> to the list:
  76
  77     __PACKAGE__->setup(qw/
  78             -Debug
  79             ConfigLoader
  80             Static::Simple
  81
  82             StackTrace
  83
  84             Authentication
  85             Authorization::Roles
  86
  87             Session
  88             Session::Store::FastMmap
  89             Session::State::Cookie
  90             /);
  91
  92
  93 =head2 Add Config Information for Authorization
  94
  95 Edit C<myapp.conf> and update it to match the following (the
  96 C<role_relation> and C<role_field> definitions are new):
  97
  98     name MyApp
  99     <authentication>
 100         default_realm dbic
 101         <realms>
 102             <dbic>
 103                 <credential>
 104                     # Note this first definition would be the same as setting
 105                     # __PACKAGE__->config->{authentication}->{realms}->{dbic}
 106                     #     ->{credential} = 'Password' in lib/MyApp.pm
 107                     #
 108                     # Specify that we are going to do password-based auth
 109                     class Password
 110                     # This is the name of the field in the users table with the
 111                     # password stored in it
 112                     password_field password
 113                     # Switch to more secure hashed passwords
 114                     password_type  hashed
 115                     # Use the SHA-1 hashing algorithm
 116                     password_hash_type SHA-1
 117                 </credential>
 118                 <store>
 119                     # Use DBIC to retrieve username, password & role information
 120                     class DBIx::Class
 121                     # This is the model object created by Catalyst::Model::DBIC
 122                     # from your schema (you created 'MyApp::Schema::User' but as
 123                     # the Catalyst startup debug messages show, it was loaded as
 124                     # 'MyApp::Model::DB::Users').
 125                     # NOTE: Omit 'MyApp::Model' here just as you would when using
 126                     # '$c->model("DB::Users)'
 127                     user_class DB::Users
 128                     # This is the name of the field in your 'users' table that
 129                     # contains the user's name
 130                     id_field username
 131                     # This is the name of a many_to_many relation in the users
 132                     # object that points to the roles for that user
 133                     role_relation  roles
 134                     # This is the name of field in the roles table that contains
 135                     # the role information
 136                     role_field role
 137                 </store>
 138             </dbic>
 139         </realms>
 140     </authentication>
 141
 142
 143 =head2 Add Role-Specific Logic to the "Book List" Template
 144
 145 Open C<root/src/books/list.tt2> in your editor and add the following
 146 lines to the bottom of the file:
 147
 148     <p>Hello [% c.user.username %], you have the following roles:</p>
 149
 150     <ul>
 151       [% # Dump list of roles -%]
 152       [% FOR role = c.user.roles %]<li>[% role %]</li>[% END %]
 153     </ul>
 154
 155     <p>
 156     [% # Add some simple role-specific logic to template %]
 157     [% # Use $c->check_user_roles() to check authz -%]
 158     [% IF c.check_user_roles('user') %]
 159       [% # Give normal users a link for 'logout' %]
 160       <a href="[% c.uri_for('/logout') %]">Logout</a>
 161     [% END %]
 162
 163     [% # Can also use $c->user->check_roles() to check authz -%]
 164     [% IF c.check_user_roles('admin') %]
 165       [% # Give admin users a link for 'create' %]
 166       <a href="[% c.uri_for('form_create') %]">Create</a>
 167     [% END %]
 168     </p>
 169
 170 This code displays a different combination of links depending on the
 171 roles assigned to the user.
 172
 173 =head2 Limit C<Books::add> to C<admin> Users
 174
 175 C<IF> statements in TT templates simply control the output that is sent
 176 to the user's browser; it provides no real enforcement (if users know or
 177 guess the appropriate URLs, they are still perfectly free to hit any
 178 action within your application).  We need to enhance the controller
 179 logic to wrap restricted actions with role-validation logic.
 180
 181 For example, we might want to restrict the "formless create" action to
 182 admin-level users by editing C<lib/MyApp/Controller/Books.pm> and
 183 updating C<url_create> to match the following code:
 184
 185     =head2 url_create
 186
 187     Create a book with the supplied title and rating,
 188     with manual authorization
 189
 190     =cut
 191
 192     sub url_create : Local {
 193         # In addition to self & context, get the title, rating & author_id args
 194         # from the URL.  Note that Catalyst automatically puts extra information
 195         # after the "/<controller_name>/<action_name/" into @_
 196         my ($self, $c, $title, $rating, $author_id) = @_;
 197
 198         # Check the user's roles
 199         if ($c->check_user_roles('admin')) {
 200             # Call create() on the book model object. Pass the table
 201             # columns/field values we want to set as hash values
 202             my $book = $c->model('DB::Books')->create({
 203                     title   => $title,
 204                     rating  => $rating
 205                 });
 206
 207             # Add a record to the join table for this book, mapping to
 208             # appropriate author
 209             $book->add_to_book_authors({author_id => $author_id});
 210             # Note: Above is a shortcut for this:
 211             # $book->create_related('book_authors', {author_id => $author_id});
 212
 213             # Assign the Book object to the stash for display in the view
 214             $c->stash->{book} = $book;
 215
 216             # This is a hack to disable XSUB processing in Data::Dumper
 217             # (it's used in the view).  This is a work-around for a bug in
 218             # the interaction of some versions or Perl, Data::Dumper & DBIC.
 219             # You won't need this if you aren't using Data::Dumper (or if
 220             # you are running DBIC 0.06001 or greater), but adding it doesn't
 221             # hurt anything either.
 222             $Data::Dumper::Useperl = 1;
 223
 224             # Set the TT template to use
 225             $c->stash->{template} = 'books/create_done.tt2';
 226         } else {
 227             # Provide very simple feedback to the user
 228             $c->response->body('Unauthorized!');
 229         }
 230     }
 231
 232
 233 To add authorization, we simply wrap the main code of this method in an
 234 C<if> statement that calls C<check_user_roles>.  If the user does not
 235 have the appropriate permissions, they receive an "Unauthorized!"
 236 message.  Note that we intentionally chose to display the message this
 237 way to demonstrate that TT templates will not be used if the response
 238 body has already been set.  In reality you would probably want to use a
 239 technique that maintains the visual continuity of your template layout
 240 (for example, using the "status" or "error" message feature added in
 241 Part 3).
 242
 243 B<TIP>: If you want to keep your existing C<url_create> method, you can
 244 create a new copy and comment out the original by making it look like a
 245 Pod comment.  For example, put something like C<=begin> before C<sub add
 246 : Local {> and C<=end> after the closing C<}>.
 247
 248 =head2 Try Out Authentication And Authorization
 249
 250 Press C<Ctrl-C> to kill the previous server instance (if it's still
 251 running) and restart it:
 252
 253     $ script/myapp_server.pl
 254
 255 Now trying going to L<http://localhost:3000/books/list> and you should
 256 be taken to the login page (you might have to C<Shift+Reload> your
 257 browser and/or click the "Logout" link on the book list page).  Try
 258 logging in with both C<test01> and C<test02> (both use a password
 259 of C<mypass>) and notice how the roles information updates at the
 260 bottom of the "Book List" page. Also try the C<Logout> link on the
 261 book list page.
 262
 263 Now the "url_create" URL will work if you are already logged in as user
 264 C<test01>, but receive an authorization failure if you are logged in as
 265 C<test02>.  Try:
 266
 267     http://localhost:3000/books/url_create/test/1/6
 268
 269 while logged in as each user.  Use one of the 'Logout' links (or go to
 270 L<http://localhost:3000/logout> in your browser directly) when you are
 271 done.
 272
 273
 274 =head1 ENABLE ACL-BASED AUTHORIZATION
 275
 276 This section takes a brief look at how the
 277 L<Catalyst::Plugin::Authorization::ACL|Catalyst::Plugin::Authorization::ACL>
 278 plugin can automate much of the work required to perform role-based
 279 authorization in a Catalyst application.
 280
 281 =head2 Add the C<Catalyst::Plugin::Authorization::ACL> Plugin
 282
 283 Open C<lib/MyApp.pm> in your editor and add the following plugin to the
 284 C<use Catalyst> statement:
 285
 286     Authorization::ACL
 287
 288 Note that the remaining C<use Catalyst> plugins from earlier sections
 289 are not shown here, but they should still be included.
 290
 291 =head2 Add ACL Rules to the Application Class
 292
 293 Open C<lib/MyApp.pm> in your editor and add the following B<BELOW> the
 294 C<__PACKAGE__-E<gt>setup;> statement:
 295
 296     # Authorization::ACL Rules
 297     __PACKAGE__->deny_access_unless(
 298             "/books/form_create",
 299             [qw/admin/],
 300         );
 301     __PACKAGE__->deny_access_unless(
 302             "/books/form_create_do",
 303             [qw/admin/],
 304         );
 305     __PACKAGE__->deny_access_unless(
 306             "/books/delete",
 307             [qw/user admin/],
 308         );
 309
 310 Each of the three statements above comprises an ACL plugin "rule".  The
 311 first two rules only allow admin-level users to create new books using
 312 the form (both the form itself and the data submission logic are
 313 protected).  The third statement allows both users and admins to delete
 314 books.  The C</books/url_create> action will continue to be protected by
 315 the "manually configured" authorization created earlier in this part of
 316 the tutorial.
 317
 318 The ACL plugin permits you to apply allow/deny logic in a variety of
 319 ways.  The following provides a basic overview of the capabilities:
 320
 321 =over 4
 322
 323 =item *
 324
 325 The ACL plugin only operates on the Catalyst "private namespace".  You
 326 are using the private namespace when you use C<Local> actions.  C<Path>,
 327 C<Regex>, and C<Global> allow you to specify actions where the path and
 328 the namespace differ -- the ACL plugin will not work in these cases.
 329
 330 =item *
 331
 332 Each rule is expressed in a separate
 333 C<__PACKAGE__-E<gt>deny_access_unless()> or
 334 C<__PACKAGE__-E<gt>allow_access_if()> line (there are several other
 335 methods that can be used for more complex policies, see the C<METHODS>
 336 portion of the
 337 L<Catalyst::Plugin::Authorization::ACL|Catalyst::Plugin::Authorization::ACL>
 338 documentation for more details).
 339
 340 =item *
 341
 342 Each rule can contain multiple roles but only a single path.
 343
 344 =item *
 345
 346 The rules are tried in order (with the "most specific" rules tested
 347 first), and processing stops at the first "match" where an allow or deny
 348 is specified.  Rules "fall through" if there is not a "match" (where a
 349 "match" means the user has the specified role).  If a "match" is found,
 350 then processing stops there and the appropriate allow/deny action is
 351 taken.
 352
 353 =item *
 354
 355 If none of the rules match, then access is allowed.
 356
 357 =item *
 358
 359 The rules currently need to be specified in the application class
 360 C<lib\MyApp.pm> B<after> the C<__PACKAGE__-E<gt>setup;> line.
 361
 362 =back
 363
 364 =head2 Add a Method to Handle Access Violations
 365
 366 By default,
 367 L<Catalyst::Plugin::Authorization::ACL|Catalyst::Plugin::Authorization::ACL>
 368 throws an exception when authorization fails.  This will take the user
 369 to the Catalyst debug screen, or a "Please come back later" message if
 370 you are not using the C<-Debug> flag. This step uses the
 371 C<access_denied> method in order to provide more appropriate feedback to
 372 the user.
 373
 374 Open C<lib/MyApp/Controller/Books.pm> in your editor and add the
 375 following method:
 376
 377     =head2 access_denied
 378
 379     Handle Catalyst::Plugin::Authorization::ACL access denied exceptions
 380
 381     =cut
 382
 383     sub access_denied : Private {
 384         my ($self, $c) = @_;
 385
 386         # Set the error message
 387         $c->stash->{error_msg} = 'Unauthorized!';
 388
 389         # Display the list
 390         $c->forward('list');
 391     }
 392
 393 Then run the Catalyst development server script:
 394
 395     $ script/myapp_server.pl
 396
 397 Log in as C<test02>.  Once at the book list, click the "Create" link
 398 to try the C<form_create> action.  You should receive a red
 399 "Unauthorized!"  error message at the top of the list.  (Note that in
 400 the example code the "Create" link code in C<root/src/books/list.tt2>
 401 is inside an C<IF> statement that only displays the list to
 402 admin-level users.)  If you log in as C<test01> you should be able to
 403 view the C<form_create> form and add a new book.
 404
 405 When you are done, use one of the 'Logout' links (or go to the
 406 L<http://localhost:3000/logout> URL directly) when you are done.
 407
 408
 409 =head1 AUTHOR
 410
 411 Kennedy Clark, C<hkclark@gmail.com>
 412
 413 Please report any errors, issues or suggestions to the author.  The
 414 most recent version of the Catalyst Tutorial can be found at
 415 L<http://dev.catalyst.perl.org/repos/Catalyst/trunk/Catalyst-Manual/lib/Catalyst/Manual/Tutorial/>.
 416
 417 Copyright 2006-2008, Kennedy Clark, under Creative Commons License
 418 (L<http://creativecommons.org/licenses/by-nc-sa/2.5/>).
 419