lib/Catalyst/Manual/Tutorial/06_Authorization.pod

   1 =head1 NAME
   2
   3 Catalyst::Manual::Tutorial::06_Authorization - Catalyst Tutorial - Chapter 6: Authorization
   4
   5
   6 =head1 OVERVIEW
   7
   8 This is B<Chapter 6 of 10> for the Catalyst tutorial.
   9
  10 L<Tutorial Overview|Catalyst::Manual::Tutorial>
  11
  12 =over 4
  13
  14 =item 1
  15
  16 L<Introduction|Catalyst::Manual::Tutorial::01_Intro>
  17
  18 =item 2
  19
  20 L<Catalyst Basics|Catalyst::Manual::Tutorial::02_CatalystBasics>
  21
  22 =item 3
  23
  24 L<More Catalyst Basics|Catalyst::Manual::Tutorial::03_MoreCatalystBasics>
  25
  26 =item 4
  27
  28 L<Basic CRUD|Catalyst::Manual::Tutorial::04_BasicCRUD>
  29
  30 =item 5
  31
  32 L<Authentication|Catalyst::Manual::Tutorial::05_Authentication>
  33
  34 =item 6
  35
  36 B<06_Authorization>
  37
  38 =item 7
  39
  40 L<Debugging|Catalyst::Manual::Tutorial::07_Debugging>
  41
  42 =item 8
  43
  44 L<Testing|Catalyst::Manual::Tutorial::08_Testing>
  45
  46 =item 9
  47
  48 L<Advanced CRUD|Catalyst::Manual::Tutorial::09_AdvancedCRUD>
  49
  50 =item 10
  51
  52 L<Appendices|Catalyst::Manual::Tutorial::10_Appendices>
  53
  54 =back
  55
  56
  57 =head1 DESCRIPTION
  58
  59 This chapter of the tutorial adds role-based authorization to the
  60 existing authentication implemented in Chapter 5.  It provides simple
  61 examples of how to use roles in both TT templates and controller
  62 actions.  The first half looks at basic authorization concepts. The
  63 second half looks at how moving your authorization code to your model
  64 can simplify your code and make things easier to maintain.
  65
  66 You can checkout the source code for this example from the catalyst
  67 subversion repository as per the instructions in
  68 L<Catalyst::Manual::Tutorial::01_Intro|Catalyst::Manual::Tutorial::01_Intro>.
  69
  70
  71 =head1 BASIC AUTHORIZATION
  72
  73 In this section you learn the basics of how authorization works under
  74 Catalyst.
  75
  76
  77 =head2 Update Plugins to Include Support for Authorization
  78
  79 Edit C<lib/MyApp.pm> and add C<Authorization::Roles> to the list:
  80
  81     # Load plugins
  82     use Catalyst qw/
  83                     -Debug
  84                     ConfigLoader
  85                     Static::Simple
  86
  87                     StackTrace
  88
  89                     Authentication
  90                     Authorization::Roles
  91
  92                     Session
  93                     Session::Store::FastMmap
  94                     Session::State::Cookie
  95                     /;
  96
  97 B<Note:> As discussed in MoreCatalystBasics, different versions of
  98 C<Catalyst::Devel> have used a variety of methods to load the plugins.
  99 You can put the plugins in the C<use Catalyst> statement if you
 100 prefer.
 101
 102 Once again (remain sharp, by now you should be getting the hang of things)
 103 include this additional plugin as a new dependency in the Makefile.PL file
 104 like this:
 105
 106     requires (
 107         ...
 108         'Catalyst::Plugin::Authorization::Roles' => '0',
 109     );
 110
 111
 112 =head2 Add Role-Specific Logic to the "Book List" Template
 113
 114 Open C<root/src/books/list.tt2> in your editor and add the following
 115 lines to the bottom of the file:
 116
 117     ...
 118     <p>Hello [% c.user.username %], you have the following roles:</p>
 119
 120     <ul>
 121       [% # Dump list of roles -%]
 122       [% FOR role = c.user.roles %]<li>[% role %]</li>[% END %]
 123     </ul>
 124
 125     <p>
 126     [% # Add some simple role-specific logic to template %]
 127     [% # Use $c->check_user_roles() to check authz -%]
 128     [% IF c.check_user_roles('user') %]
 129       [% # Give normal users a link for 'logout' %]
 130       <a href="[% c.uri_for('/logout') %]">User Logout</a>
 131     [% END %]
 132
 133     [% # Can also use $c->user->check_roles() to check authz -%]
 134     [% IF c.check_user_roles('admin') %]
 135       [% # Give admin users a link for 'create' %]
 136       <a href="[% c.uri_for(c.controller.action_for('form_create')) %]">Admin Create</a>
 137     [% END %]
 138     </p>
 139
 140 This code displays a different combination of links depending on the
 141 roles assigned to the user.
 142
 143
 144 =head2 Limit Books::add to 'admin' Users
 145
 146 C<IF> statements in TT templates simply control the output that is sent
 147 to the user's browser; it provides no real enforcement (if users know or
 148 guess the appropriate URLs, they are still perfectly free to hit any
 149 action within your application).  We need to enhance the controller
 150 logic to wrap restricted actions with role-validation logic.
 151
 152 For example, we might want to restrict the "formless create" action to
 153 admin-level users by editing C<lib/MyApp/Controller/Books.pm> and
 154 updating C<url_create> to match the following code:
 155
 156     =head2 url_create
 157
 158     Create a book with the supplied title and rating,
 159     with manual authorization
 160
 161     =cut
 162
 163     sub url_create :Chained('base') :PathPart('url_create') :Args(3) {
 164         # In addition to self & context, get the title, rating & author_id args
 165         # from the URL.  Note that Catalyst automatically puts extra information
 166         # after the "/<controller_name>/<action_name/" into @_
 167         my ($self, $c, $title, $rating, $author_id) = @_;
 168
 169         # Check the user's roles
 170         if ($c->check_user_roles('admin')) {
 171             # Call create() on the book model object. Pass the table
 172             # columns/field values we want to set as hash values
 173             my $book = $c->model('DB::Book')->create({
 174                     title   => $title,
 175                     rating  => $rating
 176                 });
 177
 178             # Add a record to the join table for this book, mapping to
 179             # appropriate author
 180             $book->add_to_book_authors({author_id => $author_id});
 181             # Note: Above is a shortcut for this:
 182             # $book->create_related('book_authors', {author_id => $author_id});
 183
 184             # Assign the Book object to the stash for display in the view
 185             $c->stash->{book} = $book;
 186
 187             # Set the TT template to use
 188             $c->stash->{template} = 'books/create_done.tt2';
 189         } else {
 190             # Provide very simple feedback to the user.
 191             $c->response->body('Unauthorized!');
 192         }
 193     }
 194
 195
 196 To add authorization, we simply wrap the main code of this method in an
 197 C<if> statement that calls C<check_user_roles>.  If the user does not
 198 have the appropriate permissions, they receive an "Unauthorized!"
 199 message.  Note that we intentionally chose to display the message this
 200 way to demonstrate that TT templates will not be used if the response
 201 body has already been set.  In reality you would probably want to use a
 202 technique that maintains the visual continuity of your template layout
 203 (for example, using the "status" or "error" message feature added in
 204 Chapter 3 or C<detach> to an action that shows an "unauthorized" page).
 205
 206 B<TIP>: If you want to keep your existing C<url_create> method, you can
 207 create a new copy and comment out the original by making it look like a
 208 Pod comment.  For example, put something like C<=begin> before
 209 C<sub add : Local {> and C<=end> after the closing C<}>.
 210
 211
 212 =head2 Try Out Authentication And Authorization
 213
 214 Press C<Ctrl-C> to kill the previous server instance (if it's still
 215 running) and restart it:
 216
 217     $ script/myapp_server.pl
 218
 219 Now trying going to L<http://localhost:3000/books/list> and you should
 220 be taken to the login page (you might have to C<Shift+Reload> or
 221 C<Ctrl+Reload> your browser and/or click the "User Logout" link on the book
 222 list page).  Try logging in with both C<test01> and C<test02> (both
 223 use a password of C<mypass>) and notice how the roles information
 224 updates at the bottom of the "Book List" page. Also try the "User Logout"
 225 link on the book list page.
 226
 227 Now the "url_create" URL will work if you are already logged in as user
 228 C<test01>, but receive an authorization failure if you are logged in as
 229 C<test02>.  Try:
 230
 231     http://localhost:3000/books/url_create/test/1/6
 232
 233 while logged in as each user.  Use one of the "logout" links (or go to
 234 L<http://localhost:3000/logout> in your browser directly) when you are
 235 done.
 236
 237
 238 =head1 ENABLE MODEL-BASED AUTHORIZATION
 239
 240 Hopefully it's fairly obvious that adding detailed permission checking
 241 logic to our controllers and view templates isn't a very clean or
 242 scalable way to build role-based permissions into out application.  As
 243 with many other aspects of MVC web development, the goal is to have
 244 your controllers and views be an "thin" as possible, with all of the
 245 "fancy business logic" built into your model.
 246
 247 For example, let's add a method to our C<Books.pm> Result Class to
 248 check if a user is allowed to delete a book.  Open
 249 C<lib/MyApp/Schema/Result/Book.pm> and add the following method
 250 (be sure to add it below the "C<DO NOT MODIFY ...>" line):
 251
 252     =head2 delete_allowed_by
 253
 254     Can the specified user delete the current book?
 255
 256     =cut
 257
 258     sub delete_allowed_by {
 259         my ($self, $user) = @_;
 260
 261         # Only allow delete if user has 'admin' role
 262         return $user->has_role('admin');
 263     }
 264
 265 Here we call a C<has_role> method on our user object, so we should add
 266 this method to our Result Class.  Open
 267 C<lib/MyApp/Schema/Result/User.pm> and add the following method below
 268 the "C<DO NOT MODIFY ...>" line:
 269
 270     =head 2 has_role
 271
 272     Check if a user has the specified role
 273
 274     =cut
 275
 276     use Perl6::Junction qw/any/;
 277     sub has_role {
 278         my ($self, $role) = @_;
 279
 280         # Does this user posses the required role?
 281         return any(map { $_->role } $self->roles) eq $role;
 282     }
 283
 284 Now we need to add some enforcement inside our controller.  Open
 285 C<lib/MyApp/Controller/Books.pm> and update the C<delete> method to
 286 match the following code:
 287
 288     =head2 delete
 289
 290     Delete a book
 291
 292     =cut
 293
 294     sub delete :Chained('object') :PathPart('delete') :Args(0) {
 295         my ($self, $c) = @_;
 296
 297         # Check permissions
 298         $c->detach('/error_noperms')
 299             unless $c->stash->{object}->delete_allowed_by($c->user->get_object);
 300
 301         # Use the book object saved by 'object' and delete it along
 302         # with related 'book_authors' entries
 303         $c->stash->{object}->delete;
 304
 305         # Use 'flash' to save information across requests until it's read
 306         $c->flash->{status_msg} = "Book deleted";
 307
 308         # Redirect the user back to the list page
 309         $c->response->redirect($c->uri_for($self->action_for('list')));
 310     }
 311
 312 Here, we C<detach> to an error page if the user is lacking the
 313 appropriate permissions.  For this to work, we need to make
 314 arrangements for the '/error_noperms' action to work.  Open
 315 C<lib/MyApp/Controller/Root.pm> and add this method:
 316
 317     =head2 error_noperms
 318
 319     Permissions error screen
 320
 321     =cut
 322
 323     sub error_noperms :Chained('/') :PathPart('error_noperms') :Args(0) {
 324         my ($self, $c) = @_;
 325
 326         $c->stash->{template} = 'error_noperms.tt2';
 327     }
 328
 329 And also add the template file by putting the following text into
 330 C<root/src/error_noperms.tt2>:
 331
 332     <span class="error">Permission Denied</span>
 333
 334 Then run the Catalyst development server script:
 335
 336     $ script/myapp_server.pl
 337
 338 Log in as C<test01> and create several new books using the C<url_create>
 339 feature:
 340
 341     http://localhost:3000/books/url_create/Test/1/4
 342
 343 Then, while still logged in as C<test01>, click the "Delete" link next
 344 to one of these books.  The book should be removed and you should see
 345 the usual green "Book deleted" message.  Next, click the "User Logout"
 346 link and log back in as C<test02>.  Now try deleting one of the books.
 347 You should be taken to the red "Permission Denied" message on our
 348 error page.
 349
 350 Use one of the 'Logout' links (or go to the
 351 L<http://localhost:3000/logout> URL directly) when you are done.
 352
 353
 354 =head1 AUTHOR
 355
 356 Kennedy Clark, C<hkclark@gmail.com>
 357
 358 Please report any errors, issues or suggestions to the author.  The
 359 most recent version of the Catalyst Tutorial can be found at
 360 L<http://dev.catalyst.perl.org/repos/Catalyst/Catalyst-Manual/5.80/trunk/lib/Catalyst/Manual/Tutorial/>.
 361
 362 Copyright 2006-2008, Kennedy Clark, under Creative Commons License
 363 (L<http://creativecommons.org/licenses/by-sa/3.0/us/>).
 364