3 Catalyst::Manual::Tutorial::05_Authentication - Catalyst Tutorial - Chapter 5: Authentication
8 This is B<Chapter 5 of 10> for the Catalyst tutorial.
10 L<Tutorial Overview|Catalyst::Manual::Tutorial>
16 L<Introduction|Catalyst::Manual::Tutorial::01_Intro>
20 L<Catalyst Basics|Catalyst::Manual::Tutorial::02_CatalystBasics>
24 L<More Catalyst Basics|Catalyst::Manual::Tutorial::03_MoreCatalystBasics>
28 L<Basic CRUD|Catalyst::Manual::Tutorial::04_BasicCRUD>
36 L<Authorization|Catalyst::Manual::Tutorial::06_Authorization>
40 L<Debugging|Catalyst::Manual::Tutorial::07_Debugging>
44 L<Testing|Catalyst::Manual::Tutorial::08_Testing>
48 L<Advanced CRUD|Catalyst::Manual::Tutorial::09_AdvancedCRUD>
52 L<Appendices|Catalyst::Manual::Tutorial::10_Appendices>
59 Now that we finally have a simple yet functional application, we can
60 focus on providing authentication (with authorization coming next in
63 This chapter of the tutorial is divided into two main sections: 1) basic,
64 cleartext authentication and 2) hash-based authentication.
66 You can checkout the source code for this example from the catalyst
67 subversion repository as per the instructions in
68 L<Catalyst::Manual::Tutorial::01_Intro|Catalyst::Manual::Tutorial::01_Intro>.
71 =head1 BASIC AUTHENTICATION
73 This section explores how to add authentication logic to a Catalyst
77 =head2 Add Users and Roles to the Database
79 First, we add both user and role information to the database (we will
80 add the role information here although it will not be used until the
81 authorization section, Chapter 6). Create a new SQL script file by opening
82 C<myapp02.sql> in your editor and insert:
85 -- Add user and role tables, along with a many-to-many join table
88 id INTEGER PRIMARY KEY,
97 id INTEGER PRIMARY KEY,
100 CREATE TABLE user_role (
103 PRIMARY KEY (user_id, role_id)
106 -- Load up some initial test data
108 INSERT INTO user VALUES (1, 'test01', 'mypass', 't01@na.com', 'Joe', 'Blow', 1);
109 INSERT INTO user VALUES (2, 'test02', 'mypass', 't02@na.com', 'Jane', 'Doe', 1);
110 INSERT INTO user VALUES (3, 'test03', 'mypass', 't03@na.com', 'No', 'Go', 0);
111 INSERT INTO role VALUES (1, 'user');
112 INSERT INTO role VALUES (2, 'admin');
113 INSERT INTO user_role VALUES (1, 1);
114 INSERT INTO user_role VALUES (1, 2);
115 INSERT INTO user_role VALUES (2, 1);
116 INSERT INTO user_role VALUES (3, 1);
118 Then load this into the C<myapp.db> database with the following command:
120 $ sqlite3 myapp.db < myapp02.sql
123 =head2 Add User and Role Information to DBIC Schema
125 Although we could manually edit the DBIC schema information to include
126 the new tables added in the previous step, let's use the C<create=static>
127 option on the DBIC model helper to do most of the work for us:
129 $ script/myapp_create.pl model DB DBIC::Schema MyApp::Schema \
130 create=static components=TimeStamp dbi:SQLite:myapp.db
131 exists "/root/dev/MyApp/script/../lib/MyApp/Model"
132 exists "/root/dev/MyApp/script/../t"
133 Dumping manual schema for MyApp::Schema to directory /root/dev/MyApp/script/../lib ...
134 Schema dump completed.
135 exists "/root/dev/MyApp/script/../lib/MyApp/Model/DB.pm"
137 $ ls lib/MyApp/Schema/Result
138 Author.pm BookAuthor.pm Book.pm Role.pm User.pm UserRole.pm
140 Notice how the helper has added three new table-specific result source
141 files to the C<lib/MyApp/Schema/Result> directory. And, more
142 importantly, even if there were changes to the existing result source
143 files, those changes would have only been written above the C<# DO NOT
144 MODIFY THIS OR ANYTHING ABOVE!> comment and your hand-edited
145 enhancements would have been preserved.
147 Speaking of "hand-editted enhancements," we should now add
148 relationship information to the three new result source files. Edit
149 each of these files and add the following information between the C<#
150 DO NOT MODIFY THIS OR ANYTHING ABOVE!> comment and the closing C<1;>:
152 C<lib/MyApp/Schema/Result/User.pm>:
160 # 1) Name of relationship, DBIC will create accessor with this name
161 # 2) Name of the model class referenced by this relationship
162 # 3) Column name in *foreign* table (aka, foreign key in peer table)
163 __PACKAGE__->has_many(map_user_roles => 'MyApp::Schema::Result::UserRole', 'user_id');
167 # 1) Name of relationship, DBIC will create accessor with this name
168 # 2) Name of has_many() relationship this many_to_many() is shortcut for
169 # 3) Name of belongs_to() relationship in model class of has_many() above
170 # You must already have the has_many() defined to use a many_to_many().
171 __PACKAGE__->many_to_many(roles => 'map_user_roles', 'role');
174 C<lib/MyApp/Schema/Result/Role.pm>:
182 # 1) Name of relationship, DBIC will create accessor with this name
183 # 2) Name of the model class referenced by this relationship
184 # 3) Column name in *foreign* table (aka, foreign key in peer table)
185 __PACKAGE__->has_many(map_user_roles => 'MyApp::Schema::Result::UserRole', 'role_id');
188 C<lib/MyApp/Schema/Result/UserRole.pm>:
196 # 1) Name of relationship, DBIC will create accessor with this name
197 # 2) Name of the model class referenced by this relationship
198 # 3) Column name in *this* table
199 __PACKAGE__->belongs_to(user => 'MyApp::Schema::Result::User', 'user_id');
203 # 1) Name of relationship, DBIC will create accessor with this name
204 # 2) Name of the model class referenced by this relationship
205 # 3) Column name in *this* table
206 __PACKAGE__->belongs_to(role => 'MyApp::Schema::Result::Role', 'role_id');
208 The code for these three sets of updates is obviously very similar to
209 the edits we made to the C<Book>, C<Author>, and C<BookAuthor>
210 classes created in Chapter 3.
212 Note that we do not need to make any change to the
213 C<lib/MyApp/Schema.pm> schema file. It simply tells DBIC to load all
214 of the Result Class and ResultSet Class files it finds in below the
215 C<lib/MyApp/Schema> directory, so it will automatically pick up our
216 new table information.
219 =head2 Sanity-Check Reload of Development Server
221 We aren't ready to try out the authentication just yet; we only want
222 to do a quick check to be sure our model loads correctly. Press
223 C<Ctrl-C> to kill the previous server instance (if it's still running)
226 $ script/myapp_server.pl
228 Look for the three new model objects in the startup debug output:
231 .-------------------------------------------------------------------+----------.
233 +-------------------------------------------------------------------+----------+
234 | MyApp::Controller::Books | instance |
235 | MyApp::Controller::Root | instance |
236 | MyApp::Model::DB | instance |
237 | MyApp::Model::DB::Author | class |
238 | MyApp::Model::DB::Book | class |
239 | MyApp::Model::DB::BookAuthor | class |
240 | MyApp::Model::DB::Role | class |
241 | MyApp::Model::DB::User | class |
242 | MyApp::Model::DB::UserRole | class |
243 | MyApp::View::TT | instance |
244 '-------------------------------------------------------------------+----------'
247 Again, notice that your "Result Class" classes have been "re-loaded"
248 by Catalyst under C<MyApp::Model>.
251 =head2 Include Authentication and Session Plugins
253 Edit C<lib/MyApp.pm> and update it as follows (everything below
254 C<StackTrace> is new):
267 Session::Store::FastMmap
268 Session::State::Cookie
271 B<Note:> As discussed in MoreCatalystBasics, different versions of
272 C<Catalyst::Devel> have used a variety of methods to load the plugins,
273 but we are going to use the current Catalyst 5.8X practice of putting
274 them on the C<use Catalyst> line.
276 The C<Authentication> plugin supports Authentication while the
277 C<Session> plugins are required to maintain state across multiple HTTP
280 Note that the only required Authentication class is the main one. This
281 is a change that occurred in version 0.09999_01 of the
282 C<Authentication> plugin. You B<do not need> to specify a particular
283 Authentication::Store or Authentication::Credential plugin. Instead,
284 indicate the Store and Credential you want to use in your application
285 configuration (see below).
287 Make sure you include the additional plugins as new dependencies in
288 the Makefile.PL file something like this:
291 'Catalyst::Plugin::Authentication' => '0',
292 'Catalyst::Plugin::Session' => '0',
293 'Catalyst::Plugin::Session::Store::FastMmap' => '0',
294 'Catalyst::Plugin::Session::State::Cookie' => '0',
297 Note that there are several options for
298 L<Session::Store|Catalyst::Plugin::Session::Store>
299 (L<Session::Store::FastMmap|Catalyst::Plugin::Session::Store::FastMmap>
300 is generally a good choice if you are on Unix; try
301 L<Session::Store::File|Catalyst::Plugin::Session::Store::File> if you
302 are on Win32) -- consult
303 L<Session::Store|Catalyst::Plugin::Session::Store> and its subclasses
304 for additional information and options (for example to use a database-
305 backed session store).
308 =head2 Configure Authentication
310 There are a variety of ways to provide configuration information to
311 L<Catalyst::Plugin::Authentication|Catalyst::Plugin::Authentication>.
313 L<Catalyst::Authentication::Realm::SimpleDB|Catalyst::Authentication::Realm::SimpleDB>
314 because it automatically sets a reasonable set of defaults for us. Open
315 C<lib/MyApp.pm> and place the following text above the call to
316 C<__PACKAGE__-E<gt>setup();>:
318 # Configure SimpleDB Authentication
319 __PACKAGE__->config->{'Plugin::Authentication'} = {
322 user_model => 'DB::User',
323 password_type => 'clear',
327 We could have placed this configuration in C<myapp.conf>, but placing
328 it in C<lib/MyApp.pm> is probably a better place since it's not likely
329 something that users of your application will want to change during
330 deployment (or you could use a mixture: leave C<class> and
331 C<user_model> defined in C<lib/MyApp.pm> as we show above, but place
332 C<password_type> in C<myapp.conf> to allow the type of password to be
333 easily modified during deployment). We will stick with putting
334 all of the authentication-related configuration in C<lib/MyApp.pm>
335 for the tutorial, but if you wish to use C<myapp.conf>, just convert
336 to the following code:
338 <Plugin::Authentication>
345 </Plugin::Authentication>
347 B<TIP:> Here is a short script that will dump the contents of
348 C<MyApp->config> to L<Config::General|Config::General> format in
351 $ perl -Ilib -e 'use MyApp; use Config::General;
352 Config::General->new->save_file("myapp.conf", MyApp->config);'
354 B<NOTE:> Because we are using SimpleDB along with a database layout
355 that complies with its default assumptions, we don't need to specify
356 the names of the columns where our username and password information
357 is stored (hence, the "Simple" part of "SimpleDB"). That being said,
358 SimpleDB lets you specify that type of information if you need to.
360 C<Catalyst::Authentication::Realm::SimpleDB|Catalyst::Authentication::Realm::SimpleDB>
364 =head2 Add Login and Logout Controllers
366 Use the Catalyst create script to create two stub controller files:
368 $ script/myapp_create.pl controller Login
369 $ script/myapp_create.pl controller Logout
371 You could easily use a single controller here. For example, you could
372 have a C<User> controller with both C<login> and C<logout> actions.
373 Remember, Catalyst is designed to be very flexible, and leaves such
374 matters up to you, the designer and programmer.
376 Then open C<lib/MyApp/Controller/Login.pm>, locate the
377 C<sub index :Path :Args(0)> method (or C<sub index : Private> if you
378 are using an older version of Catalyst) that was automatically
379 inserted by the helpers when we created the Login controller above,
380 and update the definition of C<sub index> to match:
388 sub index :Path :Args(0) {
391 # Get the username and password from form
392 my $username = $c->request->params->{username} || "";
393 my $password = $c->request->params->{password} || "";
395 # If the username and password values were found in form
396 if (defined($username) && defined($password)) {
397 # Attempt to log the user in
398 if ($c->authenticate({ username => $username,
399 password => $password } )) {
400 # If successful, then let them use the application
401 $c->response->redirect($c->uri_for(
402 $c->controller('Books')->action_for('list')));
405 # Set an error message
406 $c->stash->{error_msg} = "Bad username or password.";
410 # If either of above don't work out, send to the login page
411 $c->stash->{template} = 'login.tt2';
414 Be sure to remove the C<$c-E<gt>response-E<gt>body('Matched MyApp::Controller::Login in Login.');>
415 line of the C<sub index>.
417 This controller fetches the C<username> and C<password> values from the
418 login form and attempts to authenticate the user. If successful, it
419 redirects the user to the book list page. If the login fails, the user
420 will stay at the login page and receive an error message. If the
421 C<username> and C<password> values are not present in the form, the
422 user will be taken to the empty login form.
424 Note that we could have used something like "C<sub default :Path>",
425 however, it is generally recommended (partly for historical reasons,
426 and partly for code clarity) only to use C<default> in
427 C<MyApp::Controller::Root>, and then mainly to generate the 404 not
428 found page for the application.
430 Instead, we are using "C<sub somename :Path :Args(0) {...}>" here to
431 specifically match the URL C</login>. C<Path> actions (aka, "literal
432 actions") create URI matches relative to the namespace of the
433 controller where they are defined. Although C<Path> supports
434 arguments that allow relative and absolute paths to be defined, here
435 we use an empty C<Path> definition to match on just the name of the
436 controller itself. The method name, C<index>, is arbitrary. We make
437 the match even more specific with the C<:Args(0)> action modifier --
438 this forces the match on I<only> C</login>, not
439 C</login/somethingelse>.
441 Next, update the corresponding method in
442 C<lib/MyApp/Controller/Logout.pm> to match:
450 sub index :Path :Args(0) {
453 # Clear the user's state
456 # Send the user to the starting point
457 $c->response->redirect($c->uri_for('/'));
460 As with the login controller, be sure to delete the
461 C<$c-E<gt>response-E<gt>body('Matched MyApp::Controller::Logout in Logout.');>
462 line of the C<sub index>.
465 =head2 Add a Login Form TT Template Page
467 Create a login form by opening C<root/src/login.tt2> and inserting:
469 [% META title = 'Login' %]
472 <form method="post" action="[% c.uri_for('/login') %]">
476 <td><input type="text" name="username" size="40" /></td>
480 <td><input type="password" name="password" size="40" /></td>
483 <td colspan="2"><input type="submit" name="submit" value="Submit" /></td>
489 =head2 Add Valid User Check
491 We need something that provides enforcement for the authentication
492 mechanism -- a I<global> mechanism that prevents users who have not
493 passed authentication from reaching any pages except the login page.
494 This is generally done via an C<auto> action/method in
495 C<lib/MyApp/Controller/Root.pm>.
497 Edit the existing C<lib/MyApp/Controller/Root.pm> class file and insert
498 the following method:
502 Check if there is a user and, if not, forward to login page
506 # Note that 'auto' runs after 'begin' but before your actions and that
507 # 'auto's "chain" (all from application path to most specific class are run)
508 # See the 'Actions' section of 'Catalyst::Manual::Intro' for more info.
512 # Allow unauthenticated users to reach the login page. This
513 # allows unauthenticated users to reach any action in the Login
514 # controller. To lock it down to a single action, we could use:
515 # if ($c->action eq $c->controller('Login')->action_for('index'))
516 # to only allow unauthenticated access to the 'index' action we
518 if ($c->controller eq $c->controller('Login')) {
522 # If a user doesn't exist, force login
523 if (!$c->user_exists) {
524 # Dump a log message to the development server debug output
525 $c->log->debug('***Root::auto User not found, forwarding to /login');
526 # Redirect the user to the login page
527 $c->response->redirect($c->uri_for('/login'));
528 # Return 0 to cancel 'post-auto' processing and prevent use of application
532 # User found, so return 1 to continue with processing after this 'auto'
537 L<Catalyst::Manual::Tutorial::03_MoreCatalystBasics/CREATE A CATALYST CONTROLLER>,
538 every C<auto> method from the application/root controller down to the
539 most specific controller will be called. By placing the
540 authentication enforcement code inside the C<auto> method of
541 C<lib/MyApp/Controller/Root.pm> (or C<lib/MyApp.pm>), it will be
542 called for I<every> request that is received by the entire
546 =head2 Displaying Content Only to Authenticated Users
548 Let's say you want to provide some information on the login page that
549 changes depending on whether the user has authenticated yet. To do
550 this, open C<root/src/login.tt2> in your editor and add the following
551 lines to the bottom of the file:
556 # This code illustrates how certain parts of the TT
557 # template will only be shown to users who have logged in
559 [% IF c.user_exists %]
560 Please Note: You are already logged in as '[% c.user.username %]'.
561 You can <a href="[% c.uri_for('/logout') %]">logout</a> here.
563 You need to log in to use this application.
566 Note that this whole block is a comment because the "#" appears
567 immediate after the "[%" (with no spaces in between). Although it
568 can be a handy way to temporarily "comment out" a whole block of
569 TT code, it's probably a little too subtle for use in "normal"
574 Although most of the code is comments, the middle few lines provide a
575 "you are already logged in" reminder if the user returns to the login
576 page after they have already authenticated. For users who have not yet
577 authenticated, a "You need to log in..." message is displayed (note the
578 use of an IF-THEN-ELSE construct in TT).
581 =head2 Try Out Authentication
583 Press C<Ctrl-C> to kill the previous server instance (if it's still
584 running) and restart it:
586 $ script/myapp_server.pl
588 B<IMPORTANT NOTE:> If you are having issues with authentication on
589 Internet Explorer, be sure to check the system clocks on both your
590 server and client machines. Internet Explorer is very picky about
591 timestamps for cookies. You can quickly sync a Debian system by
592 installing the "ntpdate" package:
594 sudo aptitude -y install ntpdate
596 And then run the following command:
600 Or, depending on your firewall configuration:
602 sudo ntpdate-debian -u
604 Note: NTP can be a little more finicky about firewalls because it uses
605 UDP vs. the more common TCP that you see with most Internet protocols.
606 Worse case, you might have to manually set the time on your development
607 box instead of using NTP.
609 Now trying going to L<http://localhost:3000/books/list> and you should
610 be redirected to the login page, hitting Shift+Reload or Ctrl+Reload
611 if necessary (the "You are already logged in" message should I<not>
612 appear -- if it does, click the C<logout> button and try again). Note
613 the C<***Root::auto User not found...> debug message in the
614 development server output. Enter username C<test01> and password
615 C<mypass>, and you should be taken to the Book List page.
617 Open C<root/src/books/list.tt2> and add the following lines to the
618 bottom (below the closing </table> tag):
621 <a href="[% c.uri_for('/login') %]">Login</a>
622 <a href="[% c.uri_for(c.controller.action_for('form_create')) %]">Create</a>
625 Reload your browser and you should now see a "Login" and "Create" links
626 at the bottom of the page (as mentioned earlier, you can update template
627 files without reloading the development server). Click the first link
628 to return to the login page. This time you I<should> see the "You are
629 already logged in" message.
631 Finally, click the C<You can logout here> link on the C</login> page.
632 You should stay at the login page, but the message should change to "You
633 need to log in to use this application."
636 =head1 USING PASSWORD HASHES
638 In this section we increase the security of our system by converting
639 from cleartext passwords to SHA-1 password hashes that include a
640 random "salt" value to make them extremely difficult to crack with
641 dictionary and "rainbow table" attacks.
643 B<Note:> This section is optional. You can skip it and the rest of the
644 tutorial will function normally.
646 Be aware that even with the techniques shown in this section, the browser
647 still transmits the passwords in cleartext to your application. We are
648 just avoiding the I<storage> of cleartext passwords in the database by
649 using a salted SHA-1 hash. If you are concerned about cleartext passwords
650 between the browser and your application, consider using SSL/TLS, made
651 easy with the Catalyst plugin Catalyst::Plugin:RequireSSL.
654 =head2 Re-Run the DBIC::Schema Model Helper to Include DBIx::Class::EncodedColumn
656 Next, we can re-run the model helper to have it include
657 L<DBIx::Class::EncodedColumn|DBIx::Class::EncodedColumn> in all of the
658 Result Classes it generates for us. Simply use the same command we
659 saw in Chapters 3 and 4, but add C<,EncodedColumn> to the C<components>
662 $ script/myapp_create.pl model DB DBIC::Schema MyApp::Schema \
663 create=static components=TimeStamp,EncodedColumn dbi:SQLite:myapp.db
665 If you then open one of the Result Classes, you will see that it
666 includes EncodedColumn in the C<load_components> line. Take a look at
667 C<lib/MyApp/Schema/Result/User.pm> since that's the main class where we
668 want to use hashed and salted passwords:
670 __PACKAGE__->load_components("InflateColumn::DateTime", "TimeStamp", "EncodedColumn", "Core");
673 =head2 Modify the "password" Column to Use EncodedColumn
675 Open the file C<lib/MyApp/Schema/Result/User.pm> and enter the following
676 text below the "# DO NOT MODIFY THIS OR ANYTHING ABOVE!" line but above
679 # Have the 'password' column use a SHA-1 hash and 10-character salt
680 # with hex encoding; Generate the 'check_password" method
681 __PACKAGE__->add_columns(
686 encode_class => 'Digest',
687 encode_args => {salt_length => 10},
688 encode_check_method => 'check_password',
692 This redefines the automatically generated definition for the password
693 fields at the top of the Result Class file to now use EncodedColumn
694 logic (C<encoded_column> is set to 1). C<encode_class> can be set to
695 either C<Digest> to use
696 L<DBIx::Class::EncodedColumn::Digest|DBIx::Class::EncodedColumn::Digest>,
697 or C<Crypt::Eksblowfish::Bcrypt> for
698 L<DBIx::Class::EncodedColumn::Crypt::Eksblowfish::Bcrypt|DBIx::Class::EncodedColumn::Crypt::Eksblowfish::Bcrypt>.
699 C<encode_args> is then used to customize the type of Digest you
700 selected. Here we only specified the size of the salt to use, but
701 we could have also modified the hashing algorithm ('SHA-256' is
702 the default) and the format to use ('base64' is the default, but
703 'hex' and 'binary' are other options). To use these, you could
704 change the C<encode_args> to something like:
706 encode_args => {algorithm => 'SHA-1',
711 =head2 Load Hashed Passwords in the Database
713 Next, let's create a quick script to load some hashed and salted passwords
714 into the C<password> column of our C<users> table. Open the file
715 C<set_hashed_passwords.pl> in your editor and enter the following text:
724 my $schema = MyApp::Schema->connect('dbi:SQLite:myapp.db');
726 my @users = $schema->resultset('User')->all;
728 foreach my $user (@users) {
729 $user->password('mypass');
733 EncodedColumn lets us simple call C<$user->check_password($password)>
734 to see if the user has supplied the correct password, or, as we show
735 above, call C<$user->update($new_password)> to update the hashed
736 password stored for this user.
738 Then run the following command:
740 $ DBIC_TRACE=1 perl -Ilib set_hashed_passwords.pl
742 We had to use the C<-Ilib> arguement to tell perl to look under the
743 C<lib> directory for our C<MyApp::Schema> model.
745 The DBIC_TRACE output should show that the update worked:
747 $ DBIC_TRACE=1 perl -Ilib set_hashed_passwords.pl
748 SELECT me.id, me.username, me.password, me.email_address,
749 me.first_name, me.last_name, me.active FROM user me:
750 UPDATE user SET password = ? WHERE ( id = ? ):
751 'oXiyAcGOjowz7ISUhpIm1IrS8AxSZ9r4jNjpX9VnVeQmN6GRtRKTz', '1'
752 UPDATE user SET password = ? WHERE ( id = ? ):
753 'PmyEPrkB8EGwvaF/DvJm7LIfxoZARjv8ygFIR7pc1gEA1OfwHGNzs', '2'
754 UPDATE user SET password = ? WHERE ( id = ? ):
755 'h7CS1Fm9UCs4hjcbu2im0HumaHCJUq4Uriac+SQgdUMUfFSoOrz3c', '3'
757 But we can further confirm our actions by dumping the users table:
759 $ sqlite3 myapp.db "select * from user"
760 1|test01|38d3974fa9e9263099f7bc2574284b2f55473a9bM=fwpX2NR8|t01@na.com|Joe|Blow|1
761 2|test02|6ed8586587e53e0d7509b1cfed5df08feadc68cbMJlnPyPt0I|t02@na.com|Jane|Doe|1
762 3|test03|af929a151340c6aed4d54d7e2651795d1ad2e2f7UW8dHoGv9z|t03@na.com|No|Go|0
764 As you can see, the passwords are much harder to steal from the
765 database (not only are the hashes stored, but every hash is different
766 even though the passwords are the same because of the added "salt"
767 value). Also note that this demonstrates how to use a DBIx::Class
768 model outside of your web application -- a very useful feature in many
772 =head2 Enable Hashed and Salted Passwords
774 Edit C<lib/MyApp.pm> and update it to match the following text (the
775 only change is to the C<password_type> field):
777 # Configure SimpleDB Authentication
778 __PACKAGE__->config->{'Plugin::Authentication'} = {
781 user_model => 'DB::User',
782 password_type => 'self_check',
786 The use of C<self_check> will cause
787 Catalyst::Plugin::Authentication::Store::DBIC to call the
788 C<check_password> method we enabled on our C<password> columns.
791 =head2 Try Out the Hashed Passwords
793 Press C<Ctrl-C> to kill the previous server instance (if it's still
794 running) and restart it:
796 $ script/myapp_server.pl
798 You should now be able to go to L<http://localhost:3000/books/list> and
799 login as before. When done, click the "logout" link on the login page
800 (or point your browser at L<http://localhost:3000/logout>).
803 =head1 USING THE SESSION FOR FLASH
805 As discussed in the previous chapter of the tutorial, C<flash> allows
806 you to set variables in a way that is very similar to C<stash>, but it
807 will remain set across multiple requests. Once the value is read, it
808 is cleared (unless reset). Although C<flash> has nothing to do with
809 authentication, it does leverage the same session plugins. Now that
810 those plugins are enabled, let's go back and update the "delete and
811 redirect with query parameters" code seen at the end of the L<Basic
812 CRUD|Catalyst::Manual::Tutorial::04_BasicCRUD> chapter of the tutorial to
813 take advantage of C<flash>.
815 First, open C<lib/MyApp/Controller/Books.pm> and modify C<sub delete>
816 to match the following (everything after the model search line of code
825 sub delete :Chained('object') :PathPart('delete') :Args(0) {
828 # Use the book object saved by 'object' and delete it along
829 # with related 'book_authors' entries
830 $c->stash->{object}->delete;
832 # Use 'flash' to save information across requests until it's read
833 $c->flash->{status_msg} = "Book deleted";
835 # Redirect the user back to the list page
836 $c->response->redirect($c->uri_for($self->action_for('list')));
839 Next, open C<root/src/wrapper.tt2> and update the TT code to pull from
840 flash vs. the C<status_msg> query parameter:
844 [%# Status and error messages %]
845 <span class="message">[% status_msg || c.flash.status_msg %]</span>
846 <span class="error">[% error_msg %]</span>
847 [%# This is where TT will stick all of your template's contents. -%]
849 </div><!-- end content -->
852 Although the sample above only shows the C<content> div, leave the
853 rest of the file intact -- the only change we made to replace
854 "|| c.request.params.status_msg" with "c.flash.status_msg" in the
855 C<< <span class="message"> >> line.
860 Restart the development server, log in, and then point your browser to
861 L<http://localhost:3000/books/url_create/Test/1/4> to create an extra
862 several books. Click the "Return to list" link and delete one of the
863 "Test" books you just added. The C<flash> mechanism should retain our
864 "Book deleted" status message across the redirect.
866 B<NOTE:> While C<flash> will save information across multiple requests,
867 I<it does get cleared the first time it is read>. In general, this is
868 exactly what you want -- the C<flash> message will get displayed on
869 the next screen where it's appropriate, but it won't "keep showing up"
870 after that first time (unless you reset it). Please refer to
871 L<Catalyst::Plugin::Session|Catalyst::Plugin::Session> for additional
875 =head2 Switch To Flash-To-Stash
877 Although the a use of flash above works well, the
878 C<status_msg || c.flash.status_msg> statement is a little ugly. A nice
879 alternative is to use the C<flash_to_stash> feature that automatically
880 copies the content of flash to stash. This makes your controller
881 and template code work regardless of where it was directly access, a
882 forward, or a redirect. To enable C<flash_to_stash>, you can either
883 set the value in C<lib/MyApp.pm> by changing the default
884 C<__PACKAGE__-E<gt>config> setting to something like:
888 session => {flash_to_stash => 1},
891 B<or> add the following to C<myapp.conf>:
897 The C<__PACKAGE__-E<gt>config> option is probably preferable here
898 since it's not something you will want to change at runtime without it
899 possibly breaking some of your code.
901 Then edit C<root/src/wrapper.tt2> and change the C<status_msg> line
902 to match the following:
904 <span class="message">[% status_msg %]</span>
906 Restart the development server and go to
907 L<http://localhost:3000/books/list> in your browser. Delete another
908 of the "Test" books you added in the previous step. Flash should still
909 maintain the status message across the redirect even though you are no
910 longer explicitly accessing C<c.flash>.
915 Kennedy Clark, C<hkclark@gmail.com>
917 Please report any errors, issues or suggestions to the author. The
918 most recent version of the Catalyst Tutorial can be found at
919 L<http://dev.catalyst.perl.org/repos/Catalyst/Catalyst-Manual/5.80/trunk/lib/Catalyst/Manual/Tutorial/>.
921 Copyright 2006-2008, Kennedy Clark, under Creative Commons License
922 (L<http://creativecommons.org/licenses/by-sa/3.0/us/>).