lib/Catalyst/Controller/MessageDriven.pm

   1 package Catalyst::Controller::MessageDriven;
   2 use Moose;
   3 use Data::Serializer;
   4
   5 BEGIN { extends 'Catalyst::Controller' }
   6
   7 =head1 NAME
   8
   9 Catalyst::Controller::MessageDriven
  10
  11 =head1 SYNOPSIS
  12
  13   package MyApp::Controller::Queue;
  14   use Moose;
  15   BEGIN { extends 'Catalyst::Controller::MessageDriven' }
  16
  17   sub some_action : Local {
  18       my ($self, $c, $message) = @_;
  19
  20       # Handle message
  21
  22       # Reply with a minimal response message
  23       my $response = { type => 'testaction_response' };
  24       $c->stash->{response} = $response;
  25   }
  26
  27 =head1 DESCRIPTION
  28
  29 A Catalyst controller base class for use with Catalyst::Engine::Stomp,
  30 which handles YAML-serialized messages. A top-level "type" key in the
  31 YAML determines the action dispatched to.
  32
  33 =cut
  34
  35 __PACKAGE__->config( serializer => 'YAML' );
  36
  37 sub begin : Private {
  38         my ($self, $c) = @_;
  39
  40         # Deserialize the request message
  41         my $message;
  42         my $serializer = $self->config->{serializer};
  43         my $s = Data::Serializer->new( serializer => $serializer );
  44         eval {
  45                 my $body = $c->request->body;
  46                 open my $IN, "$body" or die "can't open temp file $body";
  47                 $message = $s->raw_deserialize(do { local $/; <$IN> });
  48         };
  49         if ($@) {
  50                 # can't reply - reply_to is embedded in the message
  51                 $c->error("exception in deserialize: $@");
  52         }
  53         else {
  54                 $c->stash->{request} = $message;
  55         }
  56 }
  57
  58 sub end : Private {
  59         my ($self, $c) = @_;
  60
  61         # Engine will send our reply based on the value of this header.
  62         $c->response->headers->header( 'X-Reply-Address' => $c->stash->{request}->{reply_to} );
  63
  64         # The wire response
  65         my $output;
  66
  67         # Load a serializer
  68         my $serializer = $self->config->{serializer};
  69         my $s = Data::Serializer->new( serializer => $serializer );
  70
  71         # Custom error handler - steal errors from catalyst and dump them into
  72         # the stash, to get them serialized out as the reply.
  73         if (scalar @{$c->error}) {
  74                 my $error = join "\n", @{$c->error};
  75                 $c->stash->{response} = { status => 'ERROR', error => $error };
  76                 $output = $s->serialize( $c->stash->{response} );
  77                 $c->clear_errors;
  78                 $c->response->status(400);
  79         }
  80
  81         # Serialize the response
  82         eval {
  83                 $output = $s->raw_serialize( $c->stash->{response} );
  84         };
  85         if ($@) {
  86                 my $error = "exception in serialize: $@";
  87                 $c->stash->{response} = { status => 'ERROR', error => $error };
  88                 $output = $s->serialize( $c->stash->{response} );
  89                 $c->response->status(400);
  90         }
  91
  92         $c->response->output( $output );
  93 }
  94
  95 sub default : Private {
  96         my ($self, $c) = @_;
  97
  98         # Forward the request to the appropriate action, based on the
  99         # message type.
 100         my $action = $c->stash->{request}->{type};
 101         if (defined $action) {
 102                 $c->forward($action, [$c->stash->{request}]);
 103         }
 104         else {
 105                 $c->error('no message type specified');
 106         }
 107 }
 108
 109 __PACKAGE__->meta->make_immutable;
 110
 111 1;