Change so that ActiveMQ is only started if not already running

[catagits/Catalyst-Engine-STOMP.git] / t / Catalyst-Engine-Stomp.t

use Test::More;

# Tests which expect a STOMP server like ActiveMQ to exist on
# localhost:61613, which is what you get if you just get the ActiveMQ
# distro and run its out-of-the-box config.

use Net::Stomp;
use YAML::XS qw/ Dump Load /;
use Data::Dumper;

use Alien::ActiveMQ;
my $ACTIVEMQ_VERSION = '5.2.0';

my ($stomp, $mq);
eval {
    $stomp = Net::Stomp->new( { hostname => 'localhost', port => 61613 } );
};
if ($@) {

    unless (Alien::ActiveMQ->is_version_installed($ACTIVEMQ_VERSION)) {
        plan 'skip_all' => 'No ActiveMQ server installed by Alien::ActiveMQ, try running the "install-activemq" command'; 
        exit;
    }

    $mq = Alien::ActiveMQ->run_server($ACTIVEMQ_VERSION);

    eval {
        $stomp = Net::Stomp->new( { hostname => 'localhost', port => 61613 } );
    };
    if ($@) {
        plan 'skip_all' => 'No ActiveMQ server listening on 61613: ' . $@;
        exit;
    }
}

plan tests => 12;

# First fire off the server
$SIG{CHLD} = 'IGNORE';
unless (fork()) {
	system("$^X -Ilib -Itestapp/lib testapp/script/stomptestapp_stomp.pl --oneshot");
	exit 0;
}
print STDERR "server started, waiting for spinup...";
sleep 20;

# Now be a client to that server
print STDERR "testing\n";
ok($stomp, 'Net::Stomp object');

my $frame = $stomp->connect();
ok($frame, 'connect to MQ server ok');

my $reply_to = sprintf '%s:1', $frame->headers->{session};
ok($frame->headers->{session}, 'got a session');
ok(length $reply_to > 2, 'valid-looking reply_to queue');

ok($stomp->subscribe( { destination => '/temp-queue/reply' } ), 'subscribe to temp queue');

my $message = {
	       payload => { foo => 1, bar => 2 },
	       reply_to => $reply_to,
	       type => 'testaction',
	      };
my $text = Dump($message);
ok($text, 'compose message');

$stomp->send( { destination => '/queue/testcontroller', body => $text } );

my $reply_frame = $stomp->receive_frame();
ok($reply_frame, 'got a reply');
ok($reply_frame->headers->{destination} eq "/remote-temp-queue/$reply_to", 'came to correct temp queue');
ok($reply_frame->body, 'has a body');

my $response = Load($reply_frame->body);
ok($response, 'YAML response ok');
ok($response->{type} eq 'testaction_response', 'correct type');

ok($stomp->disconnect, 'disconnected');