t/generated_app.t

   1 use strict;
   2 use warnings;
   3 use lib ();
   4 use Cwd qw( abs_path );
   5 use File::Temp qw/ tempdir /;
   6 use File::Spec;
   7 use FindBin qw/$Bin/;
   8 use Catalyst::Devel;
   9 use Catalyst::Helper;
  10 use Test::More;
  11 use Config;
  12
  13 eval "use IPC::Run3";
  14 plan skip_all => 'These tests require IPC::Run3' if $@;
  15
  16 my $share_dir = abs_path('share');
  17 plan skip_all => "No share dir at $share_dir!"
  18     unless -d $share_dir;
  19
  20 $ENV{CATALYST_DEVEL_SHAREDIR} = $share_dir;
  21
  22 my $dir = tempdir(CLEANUP => 1);
  23 my $devnull = File::Spec->devnull;
  24
  25 diag "Generated app is in $dir";
  26
  27 chdir $dir or die "Cannot chdir to $dir: $!";
  28
  29 {
  30     open my $fh, '>', $devnull or die "Cannot write to $devnull: $!";
  31
  32     local *STDOUT = $fh;
  33
  34     my $helper = Catalyst::Helper->new(
  35         {
  36             name => 'TestApp',
  37         }
  38     );
  39
  40     $helper->mk_app('TestApp');
  41 }
  42
  43 my $app_dir = File::Spec->catdir($dir, 'TestApp');
  44 chdir($app_dir) or die "Cannot chdir to $app_dir: $!";
  45 lib->import(File::Spec->catdir($dir, 'TestApp', 'lib'));
  46
  47 my @files = qw|
  48     Makefile.PL
  49     testapp.conf
  50     testapp.psgi
  51     lib/TestApp.pm
  52     lib/TestApp/Controller/Root.pm
  53     README
  54     Changes
  55     t/01app.t
  56     t/02pod.t
  57     t/03podcoverage.t
  58     root/static/images/catalyst_logo.png
  59     root/static/images/btn_120x50_built.png
  60     root/static/images/btn_120x50_built_shadow.png
  61     root/static/images/btn_120x50_powered.png
  62     root/static/images/btn_120x50_powered_shadow.png
  63     root/static/images/btn_88x31_built.png
  64     root/static/images/btn_88x31_built_shadow.png
  65     root/static/images/btn_88x31_powered.png
  66     root/static/images/btn_88x31_powered_shadow.png
  67     root/favicon.ico
  68     Makefile.PL
  69     script/testapp_cgi.pl
  70     script/testapp_fastcgi.pl
  71     script/testapp_server.pl
  72     script/testapp_test.pl
  73     script/testapp_create.pl
  74 |;
  75
  76 foreach my $fn (map { File::Spec->catdir(@$_) } map { [ split /\// ] } @files) {
  77     test_fn($fn);
  78 }
  79 create_ok($_, 'My' . $_) for qw/Model View Controller/;
  80
  81 command_ok( [ $^X, 'Makefile.PL' ] );
  82 ok -e "Makefile", "Makefile generated";
  83 #NOTE: do not assume that 'make' is always 'make' as e.g. Win32/strawberry perl uses 'dmake'
  84 command_ok( [ ($Config{make} || 'make') ] );
  85
  86 run_generated_component_tests();
  87
  88 my $server_script_file = File::Spec->catdir(qw/script testapp_server.pl/);
  89 my $server_script = do {
  90     open(my $fh, '<', $server_script_file) or fail $!;
  91     local $/;
  92     <$fh>;
  93 };
  94
  95 ok $server_script;
  96 ok $server_script =~ qr/CATALYST_SCRIPT_GEN}\s+=\s+(\d+)/,
  97     'SCRIPT_GEN found in generated output';
  98 is $1, $Catalyst::Devel::CATALYST_SCRIPT_GEN, 'Script gen correct';
  99
 100 {
 101     open(my $fh, '>', $server_script_file) or fail $!;
 102     print $fh "MOO\n";
 103 }
 104 my $helper = Catalyst::Helper->new(
 105     {
 106         '.newfiles' => 0,
 107         'makefile'  => 0,
 108         'scripts'   => 1,
 109         name => '.',
 110     }
 111 );
 112 $helper->mk_app( '.' ) or fail;
 113
 114 my $server_script_new = do {
 115     open(my $fh, '<', $server_script_file) or fail $!;
 116     local $/;
 117     <$fh>;
 118 };
 119
 120 is $server_script, $server_script_new;
 121
 122 chdir('/');
 123 done_testing;
 124
 125 sub command_ok {
 126     my $cmd = shift;
 127     my $desc = shift;
 128
 129     my $stdout;
 130     my $stderr;
 131     run3( $cmd, \undef, \$stdout, \$stderr );
 132
 133     $desc ||= "Exit status ok for '@{$cmd}'";
 134     unless ( is $? >> 8, 0, $desc ) {
 135         diag "STDOUT:\n$stdout" if defined $stdout;
 136         diag "STDERR:\n$stderr" if defined $stderr;
 137     }
 138 }
 139
 140 sub runperl {
 141     my $comment = pop @_;
 142     command_ok( [ $^X, '-I', File::Spec->catdir($Bin, '..', 'lib'), @_ ], $comment );
 143 }
 144
 145 my @generated_component_tests;
 146
 147 sub test_fn {
 148     my $fn = shift;
 149     ok -r $fn, "Have $fn in generated app";
 150     if ($fn =~ /script/) {
 151         SKIP: {
 152             skip 'Executable file flag test does not make sense on Win32', 1 if ($^O eq 'MSWin32');
 153             ok -x $fn, "$fn is executable";
 154        }
 155     }
 156     if ($fn =~ /\.p[ml]$/) {
 157         runperl( '-c', $fn, "$fn compiles" );
 158     }
 159     # Save these till later as Catalyst::Test will only be loaded once :-/
 160     push @generated_component_tests, $fn
 161         if $fn =~ /\.t$/;
 162 }
 163
 164 sub run_generated_component_tests {
 165     local $ENV{TEST_POD} = 1;
 166     local $ENV{CATALYST_DEBUG} = 0;
 167     foreach my $fn (@generated_component_tests) {
 168         subtest "Generated app test: $fn", sub {
 169             do $fn;
 170         };
 171     }
 172 }
 173
 174 sub create_ok {
 175     my ($type, $name) = @_;
 176     runperl( File::Spec->catdir('script', 'testapp_create.pl'), $type, $name,
 177         "'script/testapp_create.pl $type $name' ok");
 178     test_fn(File::Spec->catdir('t', sprintf("%s_%s.t", lc $type, $name)));
 179 }