lib/Catalyst/Controller/WrapCGI.pm

   1 package Catalyst::Controller::WrapCGI;
   2
   3 use Moose;
   4 use mro 'c3';
   5
   6 extends 'Catalyst::Controller';
   7
   8 use HTTP::Request::AsCGI;
   9 use HTTP::Request;
  10 use URI;
  11 use Catalyst::Exception ();
  12
  13 =head1 NAME
  14
  15 Catalyst::Controller::WrapCGI - Run CGIs in Catalyst
  16
  17 =head1 VERSION
  18
  19 Version 0.0029
  20
  21 =cut
  22
  23 our $VERSION = '0.0029';
  24
  25 =head1 SYNOPSIS
  26
  27     package MyApp::Controller::Foo;
  28
  29     use parent qw/Catalyst::Controller::WrapCGI/;
  30     use CGI ();
  31
  32     sub hello : Path('cgi-bin/hello.cgi') {
  33         my ($self, $c) = @_;
  34
  35         $self->cgi_to_response($c, sub {
  36             my $q = CGI->new;
  37             print $q->header, $q->start_html('Hello'),
  38                 $q->h1('Catalyst Rocks!'),
  39                 $q->end_html;
  40         });
  41     }
  42
  43 In your .conf, configure which environment variables to pass:
  44
  45     <Controller::Foo>
  46         <CGI>
  47             username_field username # used for REMOTE_USER env var
  48             pass_env PERL5LIB
  49             pass_env PATH
  50             pass_env /^MYAPP_/
  51             kill_env MOD_PERL
  52         </CGI>
  53     </Controller::Foo>
  54
  55 =head1 DESCRIPTION
  56
  57 Allows you to run Perl code in a CGI environment derived from your L<Catalyst>
  58 context.
  59
  60 B<*WARNING*>: do not export L<CGI> functions into a Controller, it will break
  61 with L<Catalyst> 5.8 onward.
  62
  63 If you just want to run CGIs from files, see L<Catalyst::Controller::CGIBin>.
  64
  65 =head1 CONFIGURATION
  66
  67 C<< $your_controller->{CGI}{pass_env} >> should be an array of environment variables
  68 or regular expressions to pass through to your CGIs. Entries surrounded by C</>
  69 characters are considered regular expressions.
  70
  71 C<< $your_controller->{CGI}{kill_env} >> should be an array of environment
  72 variables or regular expressions to remove from the environment before passing
  73 it to your CGIs.  Entries surrounded by C</> characters are considered regular
  74 expressions.
  75
  76 Default is to pass the whole of C<%ENV>, except for C<MOD_PERL> (that is, the
  77 default C<kill_env> is C<[ 'MOD_PERL' ]>.
  78
  79 C<< $your_controller->{CGI}{username_field} >> should be the field for your user's name, which will be
  80 read from C<< $c->user->obj >>. Defaults to 'username'.
  81
  82 See L</SYNOPSIS> for an example.
  83
  84 =cut
  85
  86 # Hack-around because Catalyst::Engine::HTTP goes and changes
  87 # them to be the remote socket, and FCGI.pm does even dumber things.
  88
  89 open my $REAL_STDIN, "<&=".fileno(*STDIN);
  90 open my $REAL_STDOUT, ">>&=".fileno(*STDOUT);
  91
  92 =head1 METHODS
  93
  94 =head2 $self->cgi_to_response($c, $coderef)
  95
  96 Does the magic of running $coderef in a CGI environment, and populating the
  97 appropriate parts of your Catalyst context with the results.
  98
  99 Calls wrap_cgi (below.)
 100
 101 =cut
 102
 103 sub cgi_to_response {
 104   my ($self, $c, $script) = @_;
 105   my $res = $self->wrap_cgi($c, $script);
 106
 107   # if the CGI doesn't set the response code but sets location they were
 108   # probably trying to redirect so set 302 for them
 109
 110   my $location = $res->headers->header('Location');
 111
 112   if (defined $location && length $location && $res->code == 200) {
 113     $c->res->status(302);
 114   } else {
 115     $c->res->status($res->code);
 116   }
 117   $c->res->body($res->content);
 118   $c->res->headers($res->headers);
 119 }
 120
 121 =head2 $self->wrap_cgi($c, $coderef)
 122
 123 Runs $coderef in a CGI environment using L<HTTP::Request::AsCGI>, returns an
 124 L<HTTP::Response>.
 125
 126 The CGI environment is set up based on $c.
 127
 128 The environment variables to pass on are taken from the configuration for your
 129 Controller, see L</SYNOPSIS> for an example. If you don't supply a list of
 130 environment variables to pass, the whole of %ENV is used.
 131
 132 Used by cgi_to_response (above), which is probably what you want to use as well.
 133
 134 =cut
 135
 136 sub _filtered_env {
 137   my ($self, $env) = @_;
 138   my @ok;
 139
 140   my $pass_env = $self->{CGI}{pass_env};
 141   $pass_env = []            if not defined $pass_env;
 142   $pass_env = [ $pass_env ] unless ref $pass_env;
 143
 144   my $kill_env = $self->{CGI}{kill_env};
 145   $kill_env = [ 'MOD_PERL' ] unless defined $kill_env;
 146   $kill_env = [ $kill_env ]  unless ref $kill_env;
 147
 148   if (@$pass_env) {
 149     for (@$pass_env) {
 150       if (m!^/(.*)/\z!) {
 151         my $re = qr/$1/;
 152         push @ok, grep /$re/, keys %$env;
 153       } else {
 154         push @ok, $_;
 155       }
 156     }
 157   } else {
 158     @ok = keys %$env;
 159   }
 160
 161   for my $k (@$kill_env) {
 162     if ($k =~ m!^/(.*)/\z!) {
 163       my $re = qr/$1/;
 164       @ok = grep { ! /$re/ } @ok;
 165     } else {
 166       @ok = grep { $_ ne $k } @ok;
 167     }
 168   }
 169   return { map {; $_ => $env->{$_} } @ok };
 170 }
 171
 172 sub wrap_cgi {
 173   my ($self, $c, $call) = @_;
 174   my $req = HTTP::Request->new(
 175     map { $c->req->$_ } qw/method uri headers/
 176   );
 177   my $body = $c->req->body;
 178   my $body_content = '';
 179
 180   $req->content_type($c->req->content_type); # set this now so we can override
 181
 182   if ($body) { # Slurp from body filehandle
 183     local $/; $body_content = <$body>;
 184   } else {
 185     my $body_params = $c->req->body_parameters;
 186     if (%$body_params) {
 187       my $encoder = URI->new;
 188       $encoder->query_form(%$body_params);
 189       $body_content = $encoder->query;
 190       $req->content_type('application/x-www-form-urlencoded');
 191     }
 192   }
 193
 194   my $filtered_env = $self->_filtered_env(\%ENV);
 195
 196   $req->content($body_content);
 197   $req->content_length(length($body_content));
 198
 199   my $username_field = $self->{CGI}{username_field} || 'username';
 200
 201   my $username = (($c->can('user_exists') && $c->user_exists)
 202                ? eval { $c->user->obj->$username_field }
 203                 : '');
 204   my $env = HTTP::Request::AsCGI->new(
 205               $req,
 206               ($username ? (REMOTE_USER => $username) : ()),
 207               %$filtered_env,
 208             );
 209
 210   {
 211     local *STDIN = $REAL_STDIN;   # restore the real ones so the filenos
 212     local *STDOUT = $REAL_STDOUT; # are 0 and 1 for the env setup
 213
 214     my $old = select($REAL_STDOUT); # in case somebody just calls 'print'
 215
 216     my $saved_error;
 217
 218     $env->setup;
 219     eval { $call->() };
 220     $saved_error = $@;
 221     $env->restore;
 222
 223     select($old);
 224
 225     Catalyst::Exception->throw(
 226         message => "CGI invocation failed: $saved_error"
 227     ) if $saved_error;
 228   }
 229
 230   return $env->response;
 231 }
 232
 233 =head1 ACKNOWLEDGEMENTS
 234
 235 Original development sponsored by L<http://www.altinity.com/>
 236
 237 =head1 SEE ALSO
 238
 239 L<Catalyst::Controller::CGIBin>, L<CatalystX::GlobalContext>,
 240 L<Catalyst::Controller>, L<CGI>, L<Catalyst>
 241
 242 =head1 AUTHOR
 243
 244 Matt S. Trout, C<< <mst at shadowcat.co.uk> >>
 245
 246 =head1 BUGS
 247
 248 Please report any bugs or feature requests to C<bug-catalyst-controller-wrapcgi
 249 at rt.cpan.org>, or through the web interface at
 250 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Catalyst-Controller-WrapCGI>.
 251 I will be notified, and then you'll automatically be notified of progress on
 252 your bug as I make changes.
 253
 254 =head1 SUPPORT
 255
 256 More information at:
 257
 258 =over 4
 259
 260 =item * RT: CPAN's request tracker
 261
 262 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Catalyst-Controller-WrapCGI>
 263
 264 =item * AnnoCPAN: Annotated CPAN documentation
 265
 266 L<http://annocpan.org/dist/Catalyst-Controller-WrapCGI>
 267
 268 =item * CPAN Ratings
 269
 270 L<http://cpanratings.perl.org/d/Catalyst-Controller-WrapCGI>
 271
 272 =item * Search CPAN
 273
 274 L<http://search.cpan.org/dist/Catalyst-Controller-WrapCGI>
 275
 276 =back
 277
 278 =head1 COPYRIGHT & LICENSE
 279
 280 Copyright (c) 2008 Matt S. Trout
 281
 282 This program is free software; you can redistribute it and/or modify it
 283 under the same terms as Perl itself.
 284
 285 =cut
 286
 287 1; # End of Catalyst::Controller::WrapCGI
 288
 289 # vim: expandtab shiftwidth=2 ts=2 tw=80: