lib/Catalyst/Controller/WrapCGI.pm

   1 package Catalyst::Controller::WrapCGI;
   2
   3 use strict;
   4 use warnings;
   5 use parent 'Catalyst::Controller';
   6
   7 use HTTP::Request::AsCGI;
   8 use HTTP::Request;
   9 use URI;
  10 use Catalyst::Exception ();
  11
  12 =head1 NAME
  13
  14 Catalyst::Controller::WrapCGI - Run CGIs in Catalyst
  15
  16 =head1 VERSION
  17
  18 Version 0.0023
  19
  20 =cut
  21
  22 our $VERSION = '0.0023';
  23
  24 =head1 SYNOPSIS
  25
  26     package MyApp::Controller::Foo;
  27
  28     use parent qw/Catalyst::Controller::WrapCGI/;
  29
  30     sub hello : Path('cgi-bin/hello.cgi') {
  31         my ($self, $c) = @_;
  32
  33         $self->cgi_to_response($c, sub {
  34             use CGI ':standard';
  35
  36             print header, start_html('Hello'),
  37                 h1('Catalyst Rocks!'),
  38                 end_html;
  39         });
  40     }
  41
  42 In your .conf, configure which environment variables to pass:
  43
  44     <Controller::Foo>
  45         <CGI>
  46             username_field username # used for REMOTE_USER env var
  47             pass_env PERL5LIB
  48             pass_env PATH
  49             pass_env /^MYAPP_/
  50         </CGI>
  51     </Controller::Foo>
  52
  53 =head1 DESCRIPTION
  54
  55 Allows you to run Perl code in a CGI environment derived from your L<Catalyst>
  56 context.
  57
  58 If you just want to run CGIs from files, see L<Catalyst::Controller::CGIBin>.
  59
  60 =head1 CONFIGURATION
  61
  62 C<$your_controller->{CGI}{pass_env}> should be an array of environment variables
  63 or regular expressions to pass through to your CGIs. Entries surrounded by C</>
  64 characters are considered regular expressions.
  65
  66 Default is to pass the whole of C<%ENV>.
  67
  68 C<{CGI}{username_field}> should be the field for your user's name, which will be
  69 read from C<$c->user->obj>. Defaults to 'username'.
  70
  71 See L</SYNOPSIS> for an example.
  72
  73 =cut
  74
  75 # Hack-around because Catalyst::Engine::HTTP goes and changes
  76 # them to be the remote socket, and FCGI.pm does even dumber things.
  77
  78 open my $REAL_STDIN, "<&=".fileno(*STDIN);
  79 open my $REAL_STDOUT, ">>&=".fileno(*STDOUT);
  80
  81 =head1 METHODS
  82
  83 =head2 $self->cgi_to_response($c, $coderef)
  84
  85 Does the magic of running $coderef in a CGI environment, and populating the
  86 appropriate parts of your Catalyst context with the results.
  87
  88 Calls wrap_cgi (below.)
  89
  90 =cut
  91
  92 sub cgi_to_response {
  93   my ($self, $c, $script) = @_;
  94   my $res = $self->wrap_cgi($c, $script);
  95
  96   # if the CGI doesn't set the response code but sets location they were
  97   # probably trying to redirect so set 302 for them
  98
  99   my $location = $res->headers->header('Location');
 100
 101   if (defined $location && length $location && $res->code == 200) {
 102     $c->res->status(302);
 103   } else {
 104     $c->res->status($res->code);
 105   }
 106   $c->res->body($res->content);
 107   $c->res->headers($res->headers);
 108 }
 109
 110 =head2 $self->wrap_cgi($c, $coderef)
 111
 112 Runs $coderef in a CGI environment using L<HTTP::Request::AsCGI>, returns an
 113 L<HTTP::Response>.
 114
 115 The CGI environment is set up based on $c.
 116
 117 The environment variables to pass on are taken from the configuration for your
 118 Controller, see L</SYNOPSIS> for an example. If you don't supply a list of
 119 environment variables to pass, the whole of %ENV is used.
 120
 121 Used by cgi_to_response (above), which is probably what you want to use as well.
 122
 123 =cut
 124
 125 sub wrap_cgi {
 126   my ($self, $c, $call) = @_;
 127   my $req = HTTP::Request->new(
 128     map { $c->req->$_ } qw/method uri headers/
 129   );
 130   my $body = $c->req->body;
 131   my $body_content = '';
 132
 133   $req->content_type($c->req->content_type); # set this now so we can override
 134
 135   if ($body) { # Slurp from body filehandle
 136     local $/; $body_content = <$body>;
 137   } else {
 138     my $body_params = $c->req->body_parameters;
 139     if (%$body_params) {
 140       my $encoder = URI->new;
 141       $encoder->query_form(%$body_params);
 142       $body_content = $encoder->query;
 143       $req->content_type('application/x-www-form-urlencoded');
 144     }
 145   }
 146
 147   my @env;
 148
 149   my $pass_env = $self->{CGI}{pass_env};
 150   $pass_env = []            if not defined $pass_env;
 151   $pass_env = [ $pass_env ] unless ref $pass_env;
 152
 153   for (@$pass_env) {
 154     if (m!^/(.*)/\z!) {
 155       my $re = qr/$1/;
 156       push @env, grep /$re/, keys %ENV;
 157     } else {
 158       push @env, $_;
 159     }
 160   }
 161
 162   @env = keys %ENV unless @env;
 163
 164   $req->content($body_content);
 165   $req->content_length(length($body_content));
 166
 167   my $username_field = $self->{CGI}{username_field} || 'username';
 168
 169   my $username = (($c->can('user_exists') && $c->user_exists)
 170                ? eval { $c->user->obj->$username_field }
 171                 : '');
 172   my $env = HTTP::Request::AsCGI->new(
 173               $req,
 174               ($username ? (REMOTE_USER => $username) : ()),
 175               map { ($_, $ENV{$_}) } @env
 176             );
 177
 178   {
 179     local *STDIN = $REAL_STDIN;   # restore the real ones so the filenos
 180     local *STDOUT = $REAL_STDOUT; # are 0 and 1 for the env setup
 181
 182     my $old = select($REAL_STDOUT); # in case somebody just calls 'print'
 183
 184     my $saved_error;
 185
 186     $env->setup;
 187     eval { $call->() };
 188     $saved_error = $@;
 189     $env->restore;
 190
 191     select($old);
 192
 193     Catalyst::Exception->throw(
 194         message => "CGI invocation failed: $saved_error"
 195     ) if $saved_error;
 196   }
 197
 198   return $env->response;
 199 }
 200
 201 =head1 ACKNOWLEDGEMENTS
 202
 203 Original development sponsored by L<http://www.altinity.com/>
 204
 205 =head1 SEE ALSO
 206
 207 L<Catalyst::Controller::CGIBin>, L<CatalystX::GlobalContext>,
 208 L<Catalyst::Controller>, L<CGI>, L<Catalyst>
 209
 210 =head1 AUTHOR
 211
 212 Matt S. Trout, C<< <mst at shadowcat.co.uk> >>
 213
 214 =head1 BUGS
 215
 216 Please report any bugs or feature requests to C<bug-catalyst-controller-wrapcgi
 217 at rt.cpan.org>, or through the web interface at
 218 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Catalyst-Controller-WrapCGI>.
 219 I will be notified, and then you'll automatically be notified of progress on
 220 your bug as I make changes.
 221
 222 =head1 SUPPORT
 223
 224 More information at:
 225
 226 =over 4
 227
 228 =item * RT: CPAN's request tracker
 229
 230 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Catalyst-Controller-WrapCGI>
 231
 232 =item * AnnoCPAN: Annotated CPAN documentation
 233
 234 L<http://annocpan.org/dist/Catalyst-Controller-WrapCGI>
 235
 236 =item * CPAN Ratings
 237
 238 L<http://cpanratings.perl.org/d/Catalyst-Controller-WrapCGI>
 239
 240 =item * Search CPAN
 241
 242 L<http://search.cpan.org/dist/Catalyst-Controller-WrapCGI>
 243
 244 =back
 245
 246 =head1 COPYRIGHT & LICENSE
 247
 248 Copyright (c) 2008 Matt S. Trout
 249
 250 This program is free software; you can redistribute it and/or modify it
 251 under the same terms as Perl itself.
 252
 253 =cut
 254
 255 1; # End of Catalyst::Controller::WrapCGI
 256
 257 # vim: expandtab shiftwidth=2 ts=2 tw=80: