lib/Catalyst/Controller/WrapCGI.pm

   1 package Catalyst::Controller::WrapCGI;
   2
   3 use Moose;
   4 use mro 'c3';
   5
   6 extends 'Catalyst::Controller';
   7
   8 use HTTP::Request::AsCGI ();
   9 use HTTP::Request ();
  10 use URI ();
  11 use Catalyst::Exception ();
  12 use URI::Escape;
  13 use HTTP::Request::Common;
  14
  15 use namespace::clean -except => 'meta';
  16
  17 =head1 NAME
  18
  19 Catalyst::Controller::WrapCGI - Run CGIs in Catalyst
  20
  21 =head1 VERSION
  22
  23 Version 0.0036
  24
  25 =cut
  26
  27 our $VERSION = '0.0036';
  28
  29 =head1 SYNOPSIS
  30
  31     package MyApp::Controller::Foo;
  32
  33     use parent qw/Catalyst::Controller::WrapCGI/;
  34     use CGI ();
  35
  36     sub hello : Path('cgi-bin/hello.cgi') {
  37         my ($self, $c) = @_;
  38
  39         $self->cgi_to_response($c, sub {
  40             my $q = CGI->new;
  41             print $q->header, $q->start_html('Hello'),
  42                 $q->h1('Catalyst Rocks!'),
  43                 $q->end_html;
  44         });
  45     }
  46
  47 In your .conf, configure which environment variables to pass:
  48
  49     <Controller::Foo>
  50         <CGI>
  51             username_field username # used for REMOTE_USER env var
  52             pass_env PERL5LIB
  53             pass_env PATH
  54             pass_env /^MYAPP_/
  55             kill_env MYAPP_BAD
  56         </CGI>
  57     </Controller::Foo>
  58
  59 =head1 DESCRIPTION
  60
  61 Allows you to run Perl code in a CGI environment derived from your L<Catalyst>
  62 context.
  63
  64 B<*WARNING*>: do not export L<CGI> functions into a Controller, it will break
  65 with L<Catalyst> 5.8 onward.
  66
  67 If you just want to run CGIs from files, see L<Catalyst::Controller::CGIBin>.
  68
  69 =head1 CONFIGURATION
  70
  71 =head2 pass_env
  72
  73 C<< $your_controller->{CGI}{pass_env} >> should be an array of environment variables
  74 or regular expressions to pass through to your CGIs. Entries surrounded by C</>
  75 characters are considered regular expressions.
  76
  77 =head2 kill_env
  78
  79 C<< $your_controller->{CGI}{kill_env} >> should be an array of environment
  80 variables or regular expressions to remove from the environment before passing
  81 it to your CGIs.  Entries surrounded by C</> characters are considered regular
  82 expressions.
  83
  84 Default is to pass the whole of C<%ENV>, except for entries listed in
  85 L</FILTERED ENVIRONMENT> below.
  86
  87 =head2 username_field
  88
  89 C<< $your_controller->{CGI}{username_field} >> should be the field for your
  90 user's name, which will be read from C<< $c->user->obj >>. Defaults to
  91 'username'.
  92
  93 See L</SYNOPSIS> for an example.
  94
  95 =cut
  96
  97 # Hack-around because Catalyst::Engine::HTTP goes and changes
  98 # them to be the remote socket, and FCGI.pm does even dumber things.
  99
 100 open my $REAL_STDIN, "<&=".fileno(*STDIN);
 101 open my $REAL_STDOUT, ">>&=".fileno(*STDOUT);
 102
 103 =head1 METHODS
 104
 105 =head2 cgi_to_response
 106
 107 C<<$self->cgi_to_response($c, $coderef)>>
 108
 109 Does the magic of running $coderef in a CGI environment, and populating the
 110 appropriate parts of your Catalyst context with the results.
 111
 112 Calls L</wrap_cgi>.
 113
 114 =cut
 115
 116 sub cgi_to_response {
 117   my ($self, $c, $script) = @_;
 118
 119   my $res = $self->wrap_cgi($c, $script);
 120
 121   # if the CGI doesn't set the response code but sets location they were
 122   # probably trying to redirect so set 302 for them
 123
 124   my $location = $res->headers->header('Location');
 125
 126   if (defined $location && length $location && $res->code == 200) {
 127     $c->res->status(302);
 128   } else {
 129     $c->res->status($res->code);
 130   }
 131   $c->res->body($res->content);
 132   $c->res->headers($res->headers);
 133 }
 134
 135 =head2 wrap_cgi
 136
 137 C<<$self->wrap_cgi($c, $coderef)>>
 138
 139 Runs $coderef in a CGI environment using L<HTTP::Request::AsCGI>, returns an
 140 L<HTTP::Response>.
 141
 142 The CGI environment is set up based on $c.
 143
 144 The environment variables to pass on are taken from the configuration for your
 145 Controller, see L</SYNOPSIS> for an example. If you don't supply a list of
 146 environment variables to pass, the whole of %ENV is used.
 147
 148 Used by L</cgi_to_response>, which is probably what you want to use as well.
 149
 150 =cut
 151
 152 sub wrap_cgi {
 153   my ($self, $c, $call) = @_;
 154   my $req = HTTP::Request->new(
 155     map { $c->req->$_ } qw/method uri headers/
 156   );
 157   my $body = $c->req->body;
 158   my $body_content = '';
 159
 160   $req->content_type($c->req->content_type); # set this now so we can override
 161
 162   if ($body) { # Slurp from body filehandle
 163     local $/; $body_content = <$body>;
 164   } else {
 165     my $body_params = $c->req->body_parameters;
 166
 167     if (my %uploads = %{ $c->req->uploads }) {
 168       my $post = POST 'http://localhost/',
 169         Content_Type => 'form-data',
 170         Content => [
 171           %$body_params,
 172           map {
 173             my $upl = $uploads{$_};
 174             $_ => [
 175               undef,
 176               $upl->filename,
 177               Content => $upl->slurp,
 178               map {
 179                 my $header = $_;
 180                 map { $header => $_ } $upl->headers->header($header)
 181               } $upl->headers->header_field_names
 182             ]
 183           } keys %uploads
 184         ];
 185       $body_content = $post->content;
 186       $req->content_type($post->header('Content-Type'));
 187     } elsif (%$body_params) {
 188       my $encoder = URI->new;
 189       $encoder->query_form(%$body_params);
 190       $body_content = $encoder->query;
 191       $req->content_type('application/x-www-form-urlencoded');
 192     }
 193   }
 194
 195   my $filtered_env = $self->_filtered_env(\%ENV);
 196
 197   $req->content($body_content);
 198   $req->content_length(length($body_content));
 199
 200   my $username_field = $self->{CGI}{username_field} || 'username';
 201
 202   my $username = (($c->can('user_exists') && $c->user_exists)
 203                ? eval { $c->user->obj->$username_field }
 204                 : '');
 205
 206   my $path_info = '/'.join '/' => map {
 207     utf8::is_utf8($_) ? uri_escape_utf8($_) : uri_escape($_)
 208   } @{ $c->req->args };
 209
 210   my $env = HTTP::Request::AsCGI->new(
 211               $req,
 212               ($username ? (REMOTE_USER => $username) : ()),
 213               %$filtered_env,
 214               PATH_INFO => $path_info,
 215 # eww, this is likely broken:
 216               FILEPATH_INFO => '/'.$c->action.$path_info,
 217               SCRIPT_NAME => $c->uri_for($c->action)->path
 218             );
 219
 220   {
 221     local *STDIN = $REAL_STDIN;   # restore the real ones so the filenos
 222     local *STDOUT = $REAL_STDOUT; # are 0 and 1 for the env setup
 223
 224     my $old = select($REAL_STDOUT); # in case somebody just calls 'print'
 225
 226     my $saved_error;
 227
 228     $env->setup;
 229     eval { $call->() };
 230     $saved_error = $@;
 231     $env->restore;
 232
 233     select($old);
 234
 235     Catalyst::Exception->throw(
 236         message => "CGI invocation failed: $saved_error"
 237     ) if $saved_error;
 238   }
 239
 240   return $env->response;
 241 }
 242
 243 =head1 FILTERED ENVIRONMENT
 244
 245 If you don't use the L</pass_env> option to restrict which environment variables
 246 are passed in, the default is to pass the whole of C<%ENV> except the variables
 247 listed below.
 248
 249   MOD_PERL
 250   SERVER_SOFTWARE
 251   SERVER_NAME
 252   GATEWAY_INTERFACE
 253   SERVER_PROTOCOL
 254   SERVER_PORT
 255   REQUEST_METHOD
 256   PATH_INFO
 257   PATH_TRANSLATED
 258   SCRIPT_NAME
 259   QUERY_STRING
 260   REMOTE_HOST
 261   REMOTE_ADDR
 262   AUTH_TYPE
 263   REMOTE_USER
 264   REMOTE_IDENT
 265   CONTENT_TYPE
 266   CONTENT_LENGTH
 267   HTTP_ACCEPT
 268   HTTP_USER_AGENT
 269
 270 C<%ENV> can be further trimmed using L</kill_env>.
 271
 272 =cut
 273
 274 my $DEFAULT_KILL_ENV = [qw/
 275   MOD_PERL SERVER_SOFTWARE SERVER_NAME GATEWAY_INTERFACE SERVER_PROTOCOL
 276   SERVER_PORT REQUEST_METHOD PATH_INFO PATH_TRANSLATED SCRIPT_NAME QUERY_STRING
 277   REMOTE_HOST REMOTE_ADDR AUTH_TYPE REMOTE_USER REMOTE_IDENT CONTENT_TYPE
 278   CONTENT_LENGTH HTTP_ACCEPT HTTP_USER_AGENT
 279 /];
 280
 281 sub _filtered_env {
 282   my ($self, $env) = @_;
 283   my @ok;
 284
 285   my $pass_env = $self->{CGI}{pass_env};
 286   $pass_env = []            if not defined $pass_env;
 287   $pass_env = [ $pass_env ] unless ref $pass_env;
 288
 289   my $kill_env = $self->{CGI}{kill_env};
 290   $kill_env = $DEFAULT_KILL_ENV unless defined $kill_env;
 291   $kill_env = [ $kill_env ]  unless ref $kill_env;
 292
 293   if (@$pass_env) {
 294     for (@$pass_env) {
 295       if (m!^/(.*)/\z!) {
 296         my $re = qr/$1/;
 297         push @ok, grep /$re/, keys %$env;
 298       } else {
 299         push @ok, $_;
 300       }
 301     }
 302   } else {
 303     @ok = keys %$env;
 304   }
 305
 306   for my $k (@$kill_env) {
 307     if ($k =~ m!^/(.*)/\z!) {
 308       my $re = qr/$1/;
 309       @ok = grep { ! /$re/ } @ok;
 310     } else {
 311       @ok = grep { $_ ne $k } @ok;
 312     }
 313   }
 314   return { map {; $_ => $env->{$_} } @ok };
 315 }
 316
 317 __PACKAGE__->meta->make_immutable;
 318
 319 =head1 DIRECT SOCKET/NPH SCRIPTS
 320
 321 This currently won't work:
 322
 323     #!/usr/bin/perl
 324
 325     use CGI ':standard';
 326
 327     $| = 1;
 328
 329     print header;
 330
 331     for (0..1000) {
 332         print $_, br, "\n";
 333         sleep 1;
 334     }
 335
 336 because the coderef is executed synchronously with C<STDOUT> pointing to a temp
 337 file.
 338
 339 =head1 ACKNOWLEDGEMENTS
 340
 341 Original development sponsored by L<http://www.altinity.com/>
 342
 343 =head1 SEE ALSO
 344
 345 L<Catalyst::Controller::CGIBin>, L<CatalystX::GlobalContext>,
 346 L<Catalyst::Controller>, L<CGI>, L<Catalyst>
 347
 348 =head1 AUTHORS
 349
 350 Originally written by:
 351
 352 Matt S. Trout, C<< <mst at shadowcat.co.uk> >>
 353
 354 Contributors:
 355
 356 Rafael Kitover C<< <rkitover at cpan.org> >>
 357
 358 Hans Dieter Pearcey C<< <hdp at cpan.org> >>
 359
 360 =head1 BUGS
 361
 362 Please report any bugs or feature requests to C<bug-catalyst-controller-wrapcgi
 363 at rt.cpan.org>, or through the web interface at
 364 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Catalyst-Controller-WrapCGI>.
 365 I will be notified, and then you'll automatically be notified of progress on
 366 your bug as I make changes.
 367
 368 =head1 SUPPORT
 369
 370 More information at:
 371
 372 =over 4
 373
 374 =item * RT: CPAN's request tracker
 375
 376 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Catalyst-Controller-WrapCGI>
 377
 378 =item * AnnoCPAN: Annotated CPAN documentation
 379
 380 L<http://annocpan.org/dist/Catalyst-Controller-WrapCGI>
 381
 382 =item * CPAN Ratings
 383
 384 L<http://cpanratings.perl.org/d/Catalyst-Controller-WrapCGI>
 385
 386 =item * Search CPAN
 387
 388 L<http://search.cpan.org/dist/Catalyst-Controller-WrapCGI>
 389
 390 =back
 391
 392 =head1 COPYRIGHT & LICENSE
 393
 394 Copyright (c) 2008 Matt S. Trout
 395
 396 This program is free software; you can redistribute it and/or modify it
 397 under the same terms as Perl itself.
 398
 399 =cut
 400
 401 1; # End of Catalyst::Controller::WrapCGI
 402
 403 # vim: expandtab shiftwidth=2 ts=2 tw=80: