lib/Catalyst/Controller/WrapCGI.pm

   1 package Catalyst::Controller::WrapCGI;
   2
   3 use 5.008_001;
   4 use Moose;
   5 use mro 'c3';
   6
   7 extends 'Catalyst::Controller';
   8
   9 use HTTP::Request::AsCGI ();
  10 use HTTP::Request ();
  11 use URI ();
  12 use Catalyst::Exception ();
  13 use URI::Escape;
  14 use HTTP::Request::Common;
  15
  16 use namespace::clean -except => 'meta';
  17
  18 =head1 NAME
  19
  20 Catalyst::Controller::WrapCGI - Run CGIs in Catalyst
  21
  22 =head1 VERSION
  23
  24 Version 0.027
  25
  26 =cut
  27
  28 our $VERSION = '0.027';
  29
  30 =head1 SYNOPSIS
  31
  32     package MyApp::Controller::Foo;
  33
  34     use parent qw/Catalyst::Controller::WrapCGI/;
  35     use CGI ();
  36
  37     sub hello : Path('cgi-bin/hello.cgi') {
  38         my ($self, $c) = @_;
  39
  40         $self->cgi_to_response($c, sub {
  41             my $q = CGI->new;
  42             print $q->header, $q->start_html('Hello'),
  43                 $q->h1('Catalyst Rocks!'),
  44                 $q->end_html;
  45         });
  46     }
  47
  48 In your .conf, configure which environment variables to pass:
  49
  50     <Controller::Foo>
  51         <CGI>
  52             username_field username # used for REMOTE_USER env var
  53             pass_env PERL5LIB
  54             pass_env PATH
  55             pass_env /^MYAPP_/
  56             kill_env MYAPP_BAD
  57         </CGI>
  58     </Controller::Foo>
  59
  60 =head1 DESCRIPTION
  61
  62 Allows you to run Perl code in a CGI environment derived from your L<Catalyst>
  63 context.
  64
  65 B<*WARNING*>: do not export L<CGI> functions into a Controller, it will break
  66 with L<Catalyst> 5.8 onward.
  67
  68 If you just want to run CGIs from files, see L<Catalyst::Controller::CGIBin>.
  69
  70 C<REMOTE_USER> will be set to C<< $c->user->obj->$username_field >> if
  71 available, or to C<< $c->req->remote_user >> otherwise.
  72
  73 =head1 CONFIGURATION
  74
  75 =head2 pass_env
  76
  77 C<< $your_controller->{CGI}{pass_env} >> should be an array of environment variables
  78 or regular expressions to pass through to your CGIs. Entries surrounded by C</>
  79 characters are considered regular expressions.
  80
  81 =head2 kill_env
  82
  83 C<< $your_controller->{CGI}{kill_env} >> should be an array of environment
  84 variables or regular expressions to remove from the environment before passing
  85 it to your CGIs.  Entries surrounded by C</> characters are considered regular
  86 expressions.
  87
  88 Default is to pass the whole of C<%ENV>, except for entries listed in
  89 L</FILTERED ENVIRONMENT> below.
  90
  91 =head2 username_field
  92
  93 C<< $your_controller->{CGI}{username_field} >> should be the field for your
  94 user's name, which will be read from C<< $c->user->obj >>. Defaults to
  95 'username'.
  96
  97 See L</SYNOPSIS> for an example.
  98
  99 =cut
 100
 101 # Hack-around because Catalyst::Engine::HTTP goes and changes
 102 # them to be the remote socket, and FCGI.pm does even dumber things.
 103
 104 open my $REAL_STDIN, "<&=".fileno(*STDIN);
 105 open my $REAL_STDOUT, ">>&=".fileno(*STDOUT);
 106
 107 =head1 METHODS
 108
 109 =head2 cgi_to_response
 110
 111 C<< $self->cgi_to_response($c, $coderef) >>
 112
 113 Does the magic of running $coderef in a CGI environment, and populating the
 114 appropriate parts of your Catalyst context with the results.
 115
 116 Calls L</wrap_cgi>.
 117
 118 =cut
 119
 120 sub cgi_to_response {
 121   my ($self, $c, $script) = @_;
 122
 123   my $res = $self->wrap_cgi($c, $script);
 124
 125   # if the CGI doesn't set the response code but sets location they were
 126   # probably trying to redirect so set 302 for them
 127
 128   my $location = $res->headers->header('Location');
 129
 130   if (defined $location && length $location && $res->code == 200) {
 131     $c->res->status(302);
 132   } else {
 133     $c->res->status($res->code);
 134   }
 135   $c->res->body($res->content);
 136   $c->res->headers($res->headers);
 137 }
 138
 139 =head2 wrap_cgi
 140
 141 C<< $self->wrap_cgi($c, $coderef) >>
 142
 143 Runs C<$coderef> in a CGI environment using L<HTTP::Request::AsCGI>, returns an
 144 L<HTTP::Response>.
 145
 146 The CGI environment is set up based on C<$c>.
 147
 148 The environment variables to pass on are taken from the configuration for your
 149 Controller, see L</SYNOPSIS> for an example. If you don't supply a list of
 150 environment variables to pass, the whole of %ENV is used (with exceptions listed
 151 in L</FILTERED ENVIRONMENT>.
 152
 153 Used by L</cgi_to_response>, which is probably what you want to use as well.
 154
 155 =cut
 156
 157 sub wrap_cgi {
 158   my ($self, $c, $call) = @_;
 159   my $req = HTTP::Request->new(
 160     map { $c->req->$_ } qw/method uri headers/
 161   );
 162   my $body = $c->req->body;
 163   my $body_content = '';
 164
 165   $req->content_type($c->req->content_type); # set this now so we can override
 166
 167   if ($body) { # Slurp from body filehandle
 168     local $/; $body_content = <$body>;
 169   } else {
 170     my $body_params = $c->req->body_parameters;
 171
 172     if (my %uploads = %{ $c->req->uploads }) {
 173       my $post = POST 'http://localhost/',
 174         Content_Type => 'form-data',
 175         Content => [
 176           %$body_params,
 177           map {
 178             my $upl = $uploads{$_};
 179             $_ => [
 180               undef,
 181               $upl->filename,
 182               Content => $upl->slurp,
 183               map {
 184                 my $header = $_;
 185                 map { $header => $_ } $upl->headers->header($header)
 186               } $upl->headers->header_field_names
 187             ]
 188           } keys %uploads
 189         ];
 190       $body_content = $post->content;
 191       $req->content_type($post->header('Content-Type'));
 192     } elsif (%$body_params) {
 193       my $encoder = URI->new;
 194       $encoder->query_form(%$body_params);
 195       $body_content = $encoder->query;
 196       $req->content_type('application/x-www-form-urlencoded');
 197     }
 198   }
 199
 200   $req->content($body_content);
 201   $req->content_length(length($body_content));
 202
 203   my $username_field = $self->{CGI}{username_field} || 'username';
 204
 205   my $username = (($c->can('user_exists') && $c->user_exists)
 206                ? eval { $c->user->obj->$username_field }
 207                 : '');
 208
 209   $username ||= $c->req->remote_user if $c->req->can('remote_user');
 210
 211   my $path_info = '/'.join '/' => map {
 212     utf8::is_utf8($_) ? uri_escape_utf8($_) : uri_escape($_)
 213   } @{ $c->req->args };
 214
 215   my $env = HTTP::Request::AsCGI->new(
 216               $req,
 217               ($username ? (REMOTE_USER => $username) : ()),
 218               PATH_INFO => $path_info,
 219 # eww, this is likely broken:
 220               FILEPATH_INFO => '/'.$c->action.$path_info,
 221               SCRIPT_NAME => $c->uri_for($c->action, $c->req->captures)->path
 222             );
 223
 224   {
 225     local *STDIN = $REAL_STDIN;   # restore the real ones so the filenos
 226     local *STDOUT = $REAL_STDOUT; # are 0 and 1 for the env setup
 227
 228     my $old = select($REAL_STDOUT); # in case somebody just calls 'print'
 229
 230     my $saved_error;
 231
 232     local %ENV = %{ $self->_filtered_env(\%ENV) };
 233
 234     $env->setup;
 235     eval { $call->() };
 236     $saved_error = $@;
 237     $env->restore;
 238
 239     select($old);
 240
 241     Catalyst::Exception->throw(
 242         message => "CGI invocation failed: $saved_error"
 243     ) if $saved_error;
 244   }
 245
 246   return $env->response;
 247 }
 248
 249 =head1 FILTERED ENVIRONMENT
 250
 251 If you don't use the L</pass_env> option to restrict which environment variables
 252 are passed in, the default is to pass the whole of C<%ENV> except the variables
 253 listed below.
 254
 255   MOD_PERL
 256   SERVER_SOFTWARE
 257   SERVER_NAME
 258   GATEWAY_INTERFACE
 259   SERVER_PROTOCOL
 260   SERVER_PORT
 261   REQUEST_METHOD
 262   PATH_INFO
 263   PATH_TRANSLATED
 264   SCRIPT_NAME
 265   QUERY_STRING
 266   REMOTE_HOST
 267   REMOTE_ADDR
 268   AUTH_TYPE
 269   REMOTE_USER
 270   REMOTE_IDENT
 271   CONTENT_TYPE
 272   CONTENT_LENGTH
 273   HTTP_ACCEPT
 274   HTTP_USER_AGENT
 275
 276 C<%ENV> can be further trimmed using L</kill_env>.
 277
 278 =cut
 279
 280 my $DEFAULT_KILL_ENV = [qw/
 281   MOD_PERL SERVER_SOFTWARE SERVER_NAME GATEWAY_INTERFACE SERVER_PROTOCOL
 282   SERVER_PORT REQUEST_METHOD PATH_INFO PATH_TRANSLATED SCRIPT_NAME QUERY_STRING
 283   REMOTE_HOST REMOTE_ADDR AUTH_TYPE REMOTE_USER REMOTE_IDENT CONTENT_TYPE
 284   CONTENT_LENGTH HTTP_ACCEPT HTTP_USER_AGENT
 285 /];
 286
 287 sub _filtered_env {
 288   my ($self, $env) = @_;
 289   my @ok;
 290
 291   my $pass_env = $self->{CGI}{pass_env};
 292   $pass_env = []            if not defined $pass_env;
 293   $pass_env = [ $pass_env ] unless ref $pass_env;
 294
 295   my $kill_env = $self->{CGI}{kill_env};
 296   $kill_env = $DEFAULT_KILL_ENV unless defined $kill_env;
 297   $kill_env = [ $kill_env ]  unless ref $kill_env;
 298
 299   if (@$pass_env) {
 300     for (@$pass_env) {
 301       if (m!^/(.*)/\z!) {
 302         my $re = qr/$1/;
 303         push @ok, grep /$re/, keys %$env;
 304       } else {
 305         push @ok, $_;
 306       }
 307     }
 308   } else {
 309     @ok = keys %$env;
 310   }
 311
 312   for my $k (@$kill_env) {
 313     if ($k =~ m!^/(.*)/\z!) {
 314       my $re = qr/$1/;
 315       @ok = grep { ! /$re/ } @ok;
 316     } else {
 317       @ok = grep { $_ ne $k } @ok;
 318     }
 319   }
 320   return { map {; $_ => $env->{$_} } @ok };
 321 }
 322
 323 __PACKAGE__->meta->make_immutable;
 324
 325 =head1 DIRECT SOCKET/NPH SCRIPTS
 326
 327 This currently won't work:
 328
 329     #!/usr/bin/perl
 330
 331     use CGI ':standard';
 332
 333     $| = 1;
 334
 335     print header;
 336
 337     for (0..1000) {
 338         print $_, br, "\n";
 339         sleep 1;
 340     }
 341
 342 because the coderef is executed synchronously with C<STDOUT> pointing to a temp
 343 file.
 344
 345 =head1 ACKNOWLEDGEMENTS
 346
 347 Original development sponsored by L<http://www.altinity.com/>
 348
 349 =head1 SEE ALSO
 350
 351 L<Catalyst::Controller::CGIBin>, L<CatalystX::GlobalContext>,
 352 L<Catalyst::Controller>, L<CGI>, L<Catalyst>
 353
 354 =head1 BUGS
 355
 356 Please report any bugs or feature requests to C<bug-catalyst-controller-wrapcgi
 357 at rt.cpan.org>, or through the web interface at
 358 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Catalyst-Controller-WrapCGI>.
 359 I will be notified, and then you'll automatically be notified of progress on
 360 your bug as I make changes.
 361
 362 =head1 SUPPORT
 363
 364 More information at:
 365
 366 =over 4
 367
 368 =item * RT: CPAN's request tracker
 369
 370 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Catalyst-Controller-WrapCGI>
 371
 372 =item * AnnoCPAN: Annotated CPAN documentation
 373
 374 L<http://annocpan.org/dist/Catalyst-Controller-WrapCGI>
 375
 376 =item * CPAN Ratings
 377
 378 L<http://cpanratings.perl.org/d/Catalyst-Controller-WrapCGI>
 379
 380 =item * Search CPAN
 381
 382 L<http://search.cpan.org/dist/Catalyst-Controller-WrapCGI>
 383
 384 =back
 385
 386 =head1 AUTHOR
 387
 388 Matt S. Trout C<< <mst at shadowcat.co.uk> >>
 389
 390 =head1 CONTRIBUTORS
 391
 392 Rafael Kitover C<< <rkitover at cpan.org> >>
 393
 394 Hans Dieter Pearcey C<< <hdp at cpan.org> >>
 395
 396 Some code stolen from Tatsuhiko Miyagawa's L<CGI::Compile>.
 397
 398 =head1 COPYRIGHT & LICENSE
 399
 400 Copyright (c) 2008-2009 L<Catalyst::Controller::WrapCGI/AUTHOR> and
 401 L<Catalyst::Controller::WrapCGI/CONTRIBUTORS>.
 402
 403 This program is free software; you can redistribute it and/or modify it
 404 under the same terms as Perl itself.
 405
 406 =cut
 407
 408 1; # End of Catalyst::Controller::WrapCGI
 409
 410 # vim: expandtab shiftwidth=2 ts=2 tw=80: