lib/Catalyst/Controller/CGIBin.pm

   1 package Catalyst::Controller::CGIBin;
   2
   3 use Moose;
   4 use mro 'c3';
   5
   6 extends 'Catalyst::Controller::WrapCGI';
   7
   8 use File::Slurp 'slurp';
   9 use File::Find::Rule ();
  10 use Catalyst::Exception ();
  11 use File::Spec::Functions qw/splitdir abs2rel/;
  12 use IPC::Open3;
  13 use Symbol 'gensym';
  14 use List::MoreUtils 'any';
  15 use IO::File ();
  16 use Carp;
  17 use File::Temp 'tempfile';
  18
  19 use namespace::clean -except => 'meta';
  20
  21 =head1 NAME
  22
  23 Catalyst::Controller::CGIBin - Serve CGIs from root/cgi-bin
  24
  25 =head1 VERSION
  26
  27 Version 0.021
  28
  29 =cut
  30
  31 our $VERSION = '0.021';
  32
  33 =head1 SYNOPSIS
  34
  35 In your controller:
  36
  37     package MyApp::Controller::Foo;
  38
  39     use parent qw/Catalyst::Controller::CGIBin/;
  40
  41 In your .conf:
  42
  43     <Controller::Foo>
  44         cgi_root_path cgi-bin
  45         cgi_dir       cgi-bin
  46         <CGI>
  47             username_field username # used for REMOTE_USER env var
  48             pass_env PERL5LIB
  49             pass_env PATH
  50             pass_env /^MYAPP_/
  51         </CGI>
  52     </Controller::Foo>
  53
  54 =head1 DESCRIPTION
  55
  56 Dispatches to CGI files in root/cgi-bin for /cgi-bin/ paths.
  57
  58 Unlike L<ModPerl::Registry> this module does _NOT_ stat and recompile the CGI
  59 for every invocation. This may be supported in the future if there's interest.
  60
  61 CGI paths are converted into action names using L</cgi_action>.
  62
  63 Inherits from L<Catalyst::Controller::WrapCGI>, see the documentation for that
  64 module for other configuration information.
  65
  66 =head1 CONFIG PARAMS
  67
  68 =head2 cgi_root_path
  69
  70 The global URI path prefix for CGIs, defaults to C<cgi-bin>.
  71
  72 =head2 cgi_dir
  73
  74 Path from which to read CGI files. Can be relative to C<$MYAPP_HOME/root> or
  75 absolute.  Defaults to C<$MYAPP_HOME/root/cgi-bin>.
  76
  77 =cut
  78
  79 has cgi_root_path => (is => 'ro', isa => 'Str', default => 'cgi-bin');
  80 has cgi_dir       => (is => 'ro', isa => 'Str', default => 'cgi-bin');
  81
  82 sub register_actions {
  83     my ($self, $app) = @_;
  84
  85     my $cgi_bin = File::Spec->file_name_is_absolute($self->cgi_dir) ?
  86         $self->cgi_dir
  87         : $app->path_to('root', $self->cgi_dir);
  88
  89     my $namespace = $self->action_namespace($app);
  90
  91     my $class = ref $self || $self;
  92
  93     for my $file (File::Find::Rule->file->in($cgi_bin)) {
  94         my $cgi_path = abs2rel($file, $cgi_bin);
  95
  96         next if any { $_ eq '.svn' } splitdir $cgi_path;
  97         next if $cgi_path =~ /\.swp\z/;
  98
  99         my $path        = join '/' => splitdir($cgi_path);
 100         my $action_name = $self->cgi_action($path);
 101         my $public_path = $self->cgi_path($path);
 102         my $reverse     = $namespace ? "$namespace/$action_name" : $action_name;
 103         my $attrs       = { Path => [ $public_path ] };
 104
 105         my ($cgi, $type);
 106
 107         if ($self->is_perl_cgi($file)) { # syntax check passed
 108             $type = 'Perl';
 109             $cgi  = $self->wrap_perl_cgi($file, $action_name);
 110         } else {
 111             $type = 'Non-Perl';
 112             $cgi  = $self->wrap_nonperl_cgi($file, $action_name);
 113         }
 114
 115         $app->log->info("Registering root/cgi-bin/$cgi_path as a $type CGI.")
 116             if $app->debug;
 117
 118         my $code = sub {
 119             my ($controller, $context) = @_;
 120             $controller->cgi_to_response($context, $cgi)
 121         };
 122
 123         my $action = $self->create_action(
 124             name       => $action_name,
 125             code       => $code,
 126             reverse    => $reverse,
 127             namespace  => $namespace,
 128             class      => $class,
 129             attributes => $attrs
 130         );
 131
 132         $app->dispatcher->register($app, $action);
 133     }
 134
 135     $self->next::method($app, @_);
 136
 137 # Tell Static::Simple to ignore cgi_dir
 138     if ($cgi_bin =~ /^@{[ $app->path_to('root') ]}/) {
 139         my $rel = File::Spec->abs2rel($cgi_bin, $app->path_to('root'));
 140
 141         if (!any { $_ eq $rel }
 142                 @{ $app->config->{static}{ignore_dirs}||[] }) {
 143             push @{ $app->config->{static}{ignore_dirs} }, $rel;
 144         }
 145     }
 146 }
 147
 148 =head1 METHODS
 149
 150 =head2 cgi_action
 151
 152 C<< $self->cgi_action($cgi) >>
 153
 154 Takes a path to a CGI from C<root/cgi-bin> such as C<foo/bar.cgi> and returns
 155 the action name it is registered as. See L</DESCRIPTION> for a discussion on how
 156 CGI actions are named.
 157
 158 A path such as C<root/cgi-bin/hlagh/bar.cgi> will get the private path
 159 C<foo/CGI_hlagh__bar_cgi>, for controller Foo, with the C</>s converted to C<__>
 160 and prepended with C<CGI_>, as well as all non-word characters converted to
 161 C<_>s. This is because L<Catalyst> action names can't have non-word characters
 162 in them.
 163
 164 This means that C<foo/bar.cgi> and C<foo__bar.cgi> for example will both map to
 165 the action C<CGI_foo__bar_cgi> so B<DON'T DO THAT>.
 166
 167 =cut
 168
 169 sub cgi_action {
 170     my ($self, $cgi) = @_;
 171
 172     my $action_name = 'CGI_' . join '__' => split '/' => $cgi;
 173     $action_name    =~ s/\W/_/g;
 174
 175     $action_name
 176 }
 177
 178 =head2 cgi_path
 179
 180 C<< $self->cgi_path($cgi) >>
 181
 182 Takes a path to a CGI from C<root/cgi-bin> such as C<foo/bar.cgi> and returns
 183 the public path it should be registered under.
 184
 185 The default is to prefix with C<$cgi_root_path/>, using the C<cgi_root_path>
 186 config setting, above.
 187
 188 =cut
 189
 190 sub cgi_path {
 191     my ($self, $cgi) = @_;
 192
 193     my $root = $self->cgi_root_path;
 194     $root =~ s{/*$}{};
 195     return "$root/$cgi";
 196 }
 197
 198 =head2 is_perl_cgi
 199
 200 C<< $self->is_perl_cgi($path) >>
 201
 202 Tries to figure out whether the CGI is Perl or not.
 203
 204 If it's Perl, it will be inlined into a sub instead of being forked off, see
 205 L</wrap_perl_cgi>.
 206
 207 =cut
 208
 209 sub is_perl_cgi {
 210     my ($self, $cgi) = @_;
 211
 212     my (undef, $tempfile) = tempfile;
 213
 214     my $pid = fork;
 215     die "Cannot fork: $!" unless defined $pid;
 216
 217     if ($pid) {
 218         waitpid $pid, 0;
 219         my $errors = IO::File->new($tempfile)->getline;
 220         unlink $tempfile;
 221         return $errors ? 0 : 1;
 222     }
 223
 224     # child
 225     local *NULL;
 226     open NULL, '>', File::Spec->devnull;
 227     open STDOUT, '>&', \*NULL;
 228     open STDERR, '>&', \*NULL;
 229     close STDIN;
 230
 231     do $cgi;
 232     IO::File->new(">$tempfile")->print($@);
 233     exit;
 234 }
 235
 236 =head2 wrap_perl_cgi
 237
 238 C<< $self->wrap_perl_cgi($path, $action_name) >>
 239
 240 Takes the path to a Perl CGI and returns a coderef suitable for passing to
 241 cgi_to_response (from L<Catalyst::Controller::WrapCGI>.)
 242
 243 C<$action_name> is the generated name for the action representing the CGI file
 244 from C<cgi_action>.
 245
 246 This is similar to how L<ModPerl::Registry> works, but will only work for
 247 well-written CGIs. Otherwise, you may have to override this method to do
 248 something more involved (see L<ModPerl::PerlRun>.)
 249
 250 Scripts with C<__DATA__> sections now work too, as well as scripts that call
 251 C<exit()>.
 252
 253 =cut
 254
 255 sub wrap_perl_cgi {
 256     my ($self, $cgi, $action_name) = @_;
 257
 258     my $code = slurp $cgi;
 259
 260     $code =~ s/^__DATA__(?:\r?\n|\r\n?)(.*)//ms;
 261     my $data = $1;
 262
 263     my $coderef = do {
 264         no warnings;
 265         # catch exit() and turn it into (effectively) a return
 266         # we *must* eval STRING because the code needs to be compiled with the
 267         # overridden CORE::GLOBAL::exit in view
 268         #
 269         # set $0 to the name of the cgi file in case it's used there
 270         eval '
 271             my $cgi_exited = "EXIT\n";
 272             BEGIN { *CORE::GLOBAL::exit = sub (;$) {
 273                 die [ $cgi_exited, $_[0] || 0 ];
 274             } }
 275             package Catalyst::Controller::CGIBin::_CGIs_::'.$action_name.';
 276             sub {'
 277                 . 'local *DATA;'
 278                 . q{open DATA, '<', \$data;}
 279                 . qq{local \$0 = "\Q$cgi\E";}
 280                 . q/my $rv = eval {/
 281                 . $code
 282                 . q/};/
 283                 . q{
 284                     return $rv unless $@;
 285                     die $@ if $@ and not (
 286                       ref($@) eq 'ARRAY' and
 287                       $@->[0] eq $cgi_exited
 288                     );
 289                     die "exited nonzero: $@->[1]" if $@->[1] != 0;
 290                     return $rv;
 291                 }
 292          . '}';
 293     };
 294
 295     croak __PACKAGE__ . ": Could not compile $cgi to coderef: $@" if $@;
 296
 297     $coderef
 298 }
 299
 300 =head2 wrap_nonperl_cgi
 301
 302 C<< $self->wrap_nonperl_cgi($path, $action_name) >>
 303
 304 Takes the path to a non-Perl CGI and returns a coderef for executing it.
 305
 306 C<$action_name> is the generated name for the action representing the CGI file.
 307
 308 By default returns:
 309
 310     sub { system $path }
 311
 312 =cut
 313
 314 sub wrap_nonperl_cgi {
 315     my ($self, $cgi, $action_name) = @_;
 316
 317     sub { system $cgi }
 318 }
 319
 320 __PACKAGE__->meta->make_immutable;
 321
 322 =head1 SEE ALSO
 323
 324 L<Catalyst::Controller::WrapCGI>, L<CatalystX::GlobalContext>,
 325 L<Catalyst::Controller>, L<CGI>, L<Catalyst>
 326
 327 =head1 AUTHOR
 328
 329 Rafael Kitover, C<< <rkitover at cpan.org> >>
 330
 331 =head1 CONTRIBUTORS
 332
 333 Hans Dieter Pearcey, C<< <hdp at cpan.org> >>
 334
 335 =head1 BUGS
 336
 337 Please report any bugs or feature requests to C<bug-catalyst-controller-wrapcgi at
 338 rt.cpan.org>, or through the web interface at
 339 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Catalyst-Controller-WrapCGI>.
 340 I will be notified, and then you'll automatically be notified of progress on
 341 your bug as I make changes.
 342
 343 =head1 SUPPORT
 344
 345 More information at:
 346
 347 =over 4
 348
 349 =item * RT: CPAN's request tracker
 350
 351 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Catalyst-Controller-WrapCGI>
 352
 353 =item * AnnoCPAN: Annotated CPAN documentation
 354
 355 L<http://annocpan.org/dist/Catalyst-Controller-WrapCGI>
 356
 357 =item * CPAN Ratings
 358
 359 L<http://cpanratings.perl.org/d/Catalyst-Controller-WrapCGI>
 360
 361 =item * Search CPAN
 362
 363 L<http://search.cpan.org/dist/Catalyst-Controller-WrapCGI>
 364
 365 =back
 366
 367 =head1 COPYRIGHT & LICENSE
 368
 369 Copyright (c) 2008 Rafael Kitover
 370
 371 This program is free software; you can redistribute it and/or modify it
 372 under the same terms as Perl itself.
 373
 374 =cut
 375
 376 1; # End of Catalyst::Controller::CGIBin
 377
 378 # vim: expandtab shiftwidth=4 ts=4 tw=80: