lib/Catalyst/Controller/CGIBin.pm

   1 package Catalyst::Controller::CGIBin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Class::C3;
   7 use URI::Escape;
   8 use File::Slurp 'slurp';
   9 use File::Find::Rule ();
  10 use Catalyst::Exception ();
  11 use File::Spec::Functions qw/splitdir abs2rel/;
  12 use IPC::Open3;
  13 use Symbol 'gensym';
  14 use List::MoreUtils 'any';
  15 use IO::File ();
  16
  17 use parent 'Catalyst::Controller::WrapCGI';
  18
  19 =head1 NAME
  20
  21 Catalyst::Controller::CGIBin - Serve CGIs from root/cgi-bin
  22
  23 =head1 VERSION
  24
  25 Version 0.002
  26
  27 =cut
  28
  29 our $VERSION = '0.002';
  30
  31 =head1 SYNOPSIS
  32
  33 In your controller:
  34
  35     package MyApp::Controller::Foo;
  36
  37     use parent qw/Catalyst::Controller::CGIBin/;
  38
  39     # example of a forward to /cgi-bin/hlagh/mtfnpy.cgi
  40     sub dongs : Local Args(0) {
  41         my ($self, $c) = @_;
  42         $c->forward($self->cgi_action('hlagh/mtfnpy.cgi'));
  43     }
  44
  45 In your .conf:
  46
  47     <Controller::Foo>
  48         <CGI>
  49             username_field username # used for REMOTE_USER env var
  50             pass_env PERL5LIB
  51             pass_env PATH
  52             pass_env /^MYAPP_/
  53         </CGI>
  54     </Controller::Foo>
  55
  56 =head1 DESCRIPTION
  57
  58 Dispatches to CGI files in root/cgi-bin for /cgi-bin/ paths.
  59
  60 Unlike L<ModPerl::Registry> this module does _NOT_ stat and recompile the CGI
  61 for every invocation. If this is something you need, let me know.
  62
  63 CGI paths are converted into action names using cgi_action (below.)
  64
  65 A path such as C<root/cgi-bin/hlagh/bar.cgi> will get the private path
  66 C<foo/CGI_hlagh_bar_cgi>, for controller Foo, with the C</>s converted to C<_>s
  67 and prepended with C<CGI_>, as well as all non-word characters converted to
  68 C<_>s. This is because L<Catalyst> action names can't have non-word characters
  69 in them.
  70
  71 Inherits from L<Catalyst::Controller::WrapCGI>, see the documentation for that
  72 module for configuration information.
  73
  74 =cut
  75
  76 sub register_actions {
  77     my ($self, $app) = @_;
  78
  79     my $cgi_bin = $app->path_to('root', 'cgi-bin');
  80
  81     my $namespace = $self->action_namespace($app);
  82
  83     my $class = ref $self || $self;
  84
  85     for my $file (File::Find::Rule->file->in($cgi_bin)) {
  86         my $cgi_path = abs2rel($file, $cgi_bin);
  87
  88         next if any { $_ eq '.svn' } splitdir $cgi_path;
  89
  90         my ($cgi, $type);
  91
  92         if ($self->is_perl_cgi($file)) { # syntax check passed
  93             $type = 'Perl';
  94             $cgi  = $self->wrap_perl_cgi($file);
  95         } else {
  96             $type = 'Non-Perl';
  97             $cgi  = $self->wrap_nonperl_cgi($file);
  98         }
  99
 100         $app->log->info("Registering root/cgi-bin/$cgi_path as a $type CGI.")
 101             if $app->debug;
 102
 103         my $path        = join '/' => splitdir($cgi_path);
 104         my $action_name = $self->cgi_action($path);
 105         my $reverse     = $namespace ? "$namespace/$action_name" : $action_name;
 106         my $attrs       = { Path => [ "cgi-bin/$path" ], Args => [ 0 ] };
 107
 108         my $code = sub {
 109             my ($controller, $context) = @_;
 110             $controller->cgi_to_response($context, $cgi)
 111         };
 112
 113         my $action = $self->create_action(
 114             name       => $action_name,
 115             code       => $code,
 116             reverse    => $reverse,
 117             namespace  => $namespace,
 118             class      => $class,
 119             attributes => $attrs
 120         );
 121
 122         $app->dispatcher->register($app, $action);
 123     }
 124
 125     $self->next::method($app, @_);
 126 }
 127
 128 =head1 METHODS
 129
 130 =head2 $self->cgi_action($cgi_path)
 131
 132 Takes a path to a CGI from C<root/cgi-bin> such as C<foo/bar.cgi> and returns
 133 the action name it is registered as. See L</DESCRIPTION> for a discussion on how
 134 CGI actions are named.
 135
 136 =cut
 137
 138 sub cgi_action {
 139     my ($self, $cgi) = @_;
 140
 141     my $action_name = 'CGI_' . join '_' => split '/' => $cgi;
 142     $action_name    =~ s/\W/_/g;
 143
 144     $action_name
 145 }
 146
 147 =head2 $self->is_perl_cgi($path)
 148
 149 Tries to figure out whether the CGI is Perl or not.
 150
 151 If it's Perl, it will be inlined into a sub instead of being forked off, see
 152 wrap_perl_cgi (below.)
 153
 154 If it's not doing what you expect, you might want to override it, and let me
 155 know as well!
 156
 157 =cut
 158
 159 sub is_perl_cgi {
 160     my ($self, $cgi) = @_;
 161
 162     my $shebang = IO::File->new($cgi)->getline;
 163
 164     return 0 if $shebang !~ /perl/ && $cgi !~ /\.pl\z/;
 165
 166     my $taint_check = $shebang =~ /-T/ ?  '-T' : '';
 167
 168     open NULL, '>', File::Spec->devnull;
 169     my $pid = open3(gensym, '&>NULL', '&>NULL', "$^X $taint_check -c $cgi");
 170     close NULL;
 171     waitpid $pid, 0;
 172
 173     $? >> 8 == 0
 174 }
 175
 176 =head2 $self->wrap_perl_cgi($path)
 177
 178 Takes the path to a Perl CGI and returns a coderef suitable for passing to
 179 cgi_to_response (from L<Catalyst::Controller::WrapCGI>.)
 180
 181 By default returns:
 182
 183     eval 'sub {' . slurp($path) . '}'
 184
 185 This is similar to how L<ModPerl::Registry> works, but will only work for
 186 well-written CGIs. Otherwise, you may have to override this method to do
 187 something more involved (see L<ModPerl::PerlRun>.)
 188
 189 =cut
 190
 191 sub wrap_perl_cgi {
 192     my ($self, $cgi) = @_;
 193
 194     do { no warnings; eval 'sub {' . slurp($cgi) . '}' }
 195 }
 196
 197 =head2 $self->wrap_nonperl_cgi($path)
 198
 199 Takes the path to a non-Perl CGI and returns a coderef for executing it.
 200
 201 By default returns:
 202
 203     sub { system $path }
 204
 205 =cut
 206
 207 sub wrap_nonperl_cgi {
 208     my ($self, $cgi) = @_;
 209
 210     sub { system $cgi }
 211 }
 212
 213 =head1 SEE ALSO
 214
 215 L<Catalyst::Controller::WrapCGI>, L<CatalystX::GlobalContext>,
 216 L<Catalyst::Controller>, L<CGI>, L<Catalyst>
 217
 218 =head1 AUTHOR
 219
 220 Rafael Kitover, C<< <rkitover at cpan.org> >>
 221
 222 =head1 BUGS
 223
 224 Please report any bugs or feature requests to C<bug-catalyst-controller-wrapcgi at
 225 rt.cpan.org>, or through the web interface at
 226 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Catalyst-Controller-WrapCGI>.
 227 I will be notified, and then you'll automatically be notified of progress on
 228 your bug as I make changes.
 229
 230 =head1 SUPPORT
 231
 232 More information at:
 233
 234 =over 4
 235
 236 =item * RT: CPAN's request tracker
 237
 238 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Catalyst-Controller-WrapCGI>
 239
 240 =item * AnnoCPAN: Annotated CPAN documentation
 241
 242 L<http://annocpan.org/dist/Catalyst-Controller-WrapCGI>
 243
 244 =item * CPAN Ratings
 245
 246 L<http://cpanratings.perl.org/d/Catalyst-Controller-WrapCGI>
 247
 248 =item * Search CPAN
 249
 250 L<http://search.cpan.org/dist/Catalyst-Controller-WrapCGI>
 251
 252 =back
 253
 254 =head1 COPYRIGHT & LICENSE
 255
 256 Copyright (c) 2008 Rafael Kitover
 257
 258 This program is free software; you can redistribute it and/or modify it
 259 under the same terms as Perl itself.
 260
 261 =cut
 262
 263 1; # End of Catalyst::Controller::CGIBin
 264
 265 # vim: expandtab shiftwidth=4 ts=4 tw=80: