lib/Catalyst/Controller/CGIBin.pm

   1 package Catalyst::Controller::CGIBin;
   2
   3 use Moose;
   4 use Moose::Util::TypeConstraints;
   5 use mro 'c3';
   6
   7 extends 'Catalyst::Controller::WrapCGI';
   8
   9 use File::Find::Rule ();
  10 use File::Spec::Functions qw/splitdir abs2rel/;
  11 use IPC::Open3;
  12 use Symbol 'gensym';
  13 use List::MoreUtils 'any';
  14 use IO::File ();
  15 use File::Temp 'tempfile';
  16 use File::pushd;
  17 use CGI::Compile;
  18
  19 use namespace::clean -except => 'meta';
  20
  21 =head1 NAME
  22
  23 Catalyst::Controller::CGIBin - Serve CGIs from root/cgi-bin
  24
  25 =cut
  26
  27 our $VERSION = '0.031';
  28
  29 =head1 SYNOPSIS
  30
  31 In your controller:
  32
  33     package MyApp::Controller::Foo;
  34
  35     use parent qw/Catalyst::Controller::CGIBin/;
  36
  37 In your .conf:
  38
  39     <Controller::Foo>
  40         cgi_root_path    cgi-bin
  41         cgi_dir          cgi-bin
  42         cgi_chain_root   /optional/private/path/to/Chained/root
  43         cgi_file_pattern *.cgi
  44         # or regex
  45         cgi_file_pattern /\.pl\z/
  46         <CGI>
  47             username_field username # used for REMOTE_USER env var
  48             pass_env PERL5LIB
  49             pass_env PATH
  50             pass_env /^MYAPP_/
  51         </CGI>
  52     </Controller::Foo>
  53
  54 =head1 DESCRIPTION
  55
  56 Dispatches to CGI files in root/cgi-bin for /cgi-bin/ paths.
  57
  58 Unlike L<ModPerl::Registry> this module does _NOT_ stat and recompile the CGI
  59 for every invocation. This may be supported in the future if there's interest.
  60
  61 CGI paths are converted into action names using L</cgi_action>.
  62
  63 Inherits from L<Catalyst::Controller::WrapCGI>, see the documentation for that
  64 module for other configuration information.
  65
  66 =head1 CONFIG PARAMS
  67
  68 =head2 cgi_root_path
  69
  70 The global URI path prefix for CGIs, defaults to C<cgi-bin>.
  71
  72 =head2 cgi_chain_root
  73
  74 By default L<Path|Catalyst::DispatchType::Path> actions are created for CGIs,
  75 but if you specify this option, the actions will be created as
  76 L<Chained|Catalyst::DispatchType::Chained> end-points, chaining off the
  77 specified private path.
  78
  79 If this option is used, the L</cgi_root_path> option is ignored. The root path
  80 will be determined by your chain.
  81
  82 The L<PathPart|Catalyst::DispatchType::Chained/PathPart> of the action will be
  83 the path to the CGI file.
  84
  85 =head2 cgi_dir
  86
  87 Path from which to read CGI files. Can be relative to C<$MYAPP_HOME/root> or
  88 absolute.  Defaults to C<$MYAPP_HOME/root/cgi-bin>.
  89
  90 =head2 cgi_file_pattern
  91
  92 By default all files in L</cgi_dir> will be loaded as CGIs, however, with this
  93 option you can specify either a glob or a regex to match the names of files you
  94 want to be loaded.
  95
  96 Can be an array of globs/regexes as well.
  97
  98 =cut
  99
 100 { my $stringified = subtype as 'Str';
 101   coerce $stringified,
 102       from 'Object',
 103       via { "$_" };
 104
 105   has cgi_root_path    => (is => 'ro', coerce => 1, isa => $stringified, default => 'cgi-bin' );
 106   has cgi_chain_root   => (is => 'ro', isa => 'Str');
 107   has cgi_dir          => (is => 'ro', coerce => 1, isa => $stringified, default => 'cgi-bin');
 108   has cgi_file_pattern => (is => 'rw', default => sub { ['*'] });
 109
 110 }
 111
 112 sub register_actions {
 113     my ($self, $app) = @_;
 114
 115     my $cgi_bin;
 116     if( File::Spec->file_name_is_absolute($self->cgi_dir) ) {
 117         $cgi_bin = $self->cgi_dir;
 118     } elsif( File::Spec->file_name_is_absolute( $app->config->{root} ) ) {
 119         $cgi_bin = File::Spec->catdir( $app->config->{root}, $self->cgi_dir );
 120     } else {
 121         $cgi_bin = $app->path_to( $app->config->{root}, $self->cgi_dir);
 122     }
 123
 124     my $namespace = $self->action_namespace($app);
 125
 126     my $class = ref $self || $self;
 127
 128     my $patterns = $self->cgi_file_pattern;
 129     $patterns = [ $patterns ] if not ref $patterns;
 130     for my $pat (@$patterns) {
 131         if ($pat =~ m{^/(.*)/\z}) {
 132             $pat = qr/$1/;
 133         }
 134     }
 135     $self->cgi_file_pattern($patterns);
 136
 137     for my $file (File::Find::Rule->file->name(@$patterns)->in($cgi_bin)) {
 138         my $cgi_path = abs2rel($file, $cgi_bin);
 139
 140         next if any { $_ eq '.svn' } splitdir $cgi_path;
 141         next if $cgi_path =~ /\.swp\z/;
 142
 143         my $path        = join '/' => splitdir($cgi_path);
 144         my $action_name = $self->cgi_action($path);
 145         my $reverse     = $namespace ? "$namespace/$action_name" : $action_name;
 146
 147         my $attrs = do {
 148             if (my $chain_root = $self->cgi_chain_root) {
 149                 { Chained => [ $chain_root ], PathPart => [ $path ], Args => [] };
 150             }
 151             else {
 152                 { Path => [ $self->cgi_path($path) ] };
 153             }
 154         };
 155
 156         my ($cgi, $type);
 157
 158         if ($self->is_perl_cgi($file)) { # syntax check passed
 159             $type = 'Perl';
 160             $cgi  = $self->wrap_perl_cgi($file, $action_name);
 161         } else {
 162             $type = 'Non-Perl';
 163             $cgi  = $self->wrap_nonperl_cgi($file, $action_name);
 164         }
 165
 166         $app->log->info("Registering root/cgi-bin/$cgi_path as a $type CGI.")
 167             if $app->debug;
 168
 169         my $code = sub {
 170             my ($controller, $context) = @_;
 171             $controller->cgi_to_response($context, $cgi)
 172         };
 173
 174         my $action = $self->create_action(
 175             name       => $action_name,
 176             code       => $code,
 177             reverse    => $reverse,
 178             namespace  => $namespace,
 179             class      => $class,
 180             attributes => $attrs
 181         );
 182
 183         $app->dispatcher->register($app, $action);
 184     }
 185
 186     $self->next::method($app, @_);
 187
 188 # Tell Static::Simple to ignore cgi_dir
 189     if ($cgi_bin =~ /^@{[ $app->path_to('root') ]}/) {
 190         my $rel = File::Spec->abs2rel($cgi_bin, $app->path_to('root'));
 191
 192         if (!any { $_ eq $rel }
 193                 @{ $app->config->{static}{ignore_dirs}||[] }) {
 194             push @{ $app->config->{static}{ignore_dirs} }, $rel;
 195         }
 196     }
 197 }
 198
 199 =head1 METHODS
 200
 201 =head2 cgi_action
 202
 203 C<< $self->cgi_action($cgi) >>
 204
 205 Takes a path to a CGI from C<root/cgi-bin> such as C<foo/bar.cgi> and returns
 206 the action name it is registered as.
 207
 208 =cut
 209
 210 sub cgi_action {
 211     my ($self, $cgi) = @_;
 212
 213     my $action_name = 'CGI_' . $cgi;
 214     $action_name =~ s/([^A-Za-z0-9_])/sprintf("_%2x", unpack("C", $1))/eg;
 215
 216     return $action_name;
 217 }
 218
 219 =head2 cgi_path
 220
 221 C<< $self->cgi_path($cgi) >>
 222
 223 Takes a path to a CGI from C<root/cgi-bin> such as C<foo/bar.cgi> and returns
 224 the public path it should be registered under.
 225
 226 The default is to prefix with C<$cgi_root_path/>, using the C<cgi_root_path>
 227 config setting, above.
 228
 229 =cut
 230
 231 sub cgi_path {
 232     my ($self, $cgi) = @_;
 233
 234     my $root = $self->cgi_root_path;
 235     $root =~ s{/*$}{};
 236     return "$root/$cgi";
 237 }
 238
 239 =head2 is_perl_cgi
 240
 241 C<< $self->is_perl_cgi($path) >>
 242
 243 Tries to figure out whether the CGI is Perl or not.
 244
 245 If it's Perl, it will be inlined into a sub instead of being forked off, see
 246 L</wrap_perl_cgi>.
 247
 248 =cut
 249
 250 sub is_perl_cgi {
 251     my ($self, $cgi) = @_;
 252
 253     my (undef, $tempfile) = tempfile;
 254
 255     my $pid = fork;
 256     die "Cannot fork: $!" unless defined $pid;
 257
 258     if ($pid) {
 259         waitpid $pid, 0;
 260         my $errors = IO::File->new($tempfile)->getline;
 261         unlink $tempfile;
 262         return $errors ? 0 : 1;
 263     }
 264
 265     # child
 266     local *NULL;
 267     open NULL, '>', File::Spec->devnull;
 268     open STDOUT, '>&', \*NULL;
 269     open STDERR, '>&', \*NULL;
 270     close STDIN;
 271
 272     eval { $self->wrap_perl_cgi($cgi, '__DUMMY__') };
 273
 274     IO::File->new(">$tempfile")->print($@);
 275
 276     exit;
 277 }
 278
 279 =head2 wrap_perl_cgi
 280
 281 C<< $self->wrap_perl_cgi($path, $action_name) >>
 282
 283 Takes the path to a Perl CGI and returns a coderef suitable for passing to
 284 cgi_to_response (from L<Catalyst::Controller::WrapCGI>) using L<CGI::Compile>.
 285
 286 C<$action_name> is the generated name for the action representing the CGI file
 287 from C<cgi_action>.
 288
 289 This is similar to how L<ModPerl::Registry> works, but will only work for
 290 well-written CGIs. Otherwise, you may have to override this method to do
 291 something more involved (see L<ModPerl::PerlRun>.)
 292
 293 Scripts with C<__DATA__> sections now work too, as well as scripts that call
 294 C<exit()>.
 295
 296 =cut
 297
 298 sub wrap_perl_cgi {
 299     my ($self, $cgi, $action_name) = @_;
 300
 301     return CGI::Compile->compile($cgi,
 302         "Catalyst::Controller::CGIBin::_CGIs_::$action_name");
 303 }
 304
 305 =head2 wrap_nonperl_cgi
 306
 307 C<< $self->wrap_nonperl_cgi($path, $action_name) >>
 308
 309 Takes the path to a non-Perl CGI and returns a coderef for executing it.
 310
 311 C<$action_name> is the generated name for the action representing the CGI file.
 312
 313 By default returns something like:
 314
 315     sub { system $path }
 316
 317 =cut
 318
 319 sub wrap_nonperl_cgi {
 320     my ($self, $cgi, $action_name) = @_;
 321
 322     return sub {
 323         system $cgi;
 324
 325         if ($? == -1) {
 326             die "failed to execute CGI '$cgi': $!";
 327         }
 328         elsif ($? & 127) {
 329             die sprintf "CGI '$cgi' died with signal %d, %s coredump",
 330                 ($? & 127),  ($? & 128) ? 'with' : 'without';
 331         }
 332         else {
 333             my $exit_code = $? >> 8;
 334
 335             return 0 if $exit_code == 0;
 336
 337             die "CGI '$cgi' exited non-zero with: $exit_code";
 338         }
 339     };
 340 }
 341
 342 __PACKAGE__->meta->make_immutable;
 343
 344 =head1 SEE ALSO
 345
 346 L<Catalyst::Controller::WrapCGI>, L<CatalystX::GlobalContext>,
 347 L<Catalyst::Controller>, L<CGI>, L<CGI::Compile>, L<Catalyst>
 348
 349 =head1 BUGS
 350
 351 Please report any bugs or feature requests to C<bug-catalyst-controller-wrapcgi at
 352 rt.cpan.org>, or through the web interface at
 353 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Catalyst-Controller-WrapCGI>.
 354 I will be notified, and then you'll automatically be notified of progress on
 355 your bug as I make changes.
 356
 357 =head1 SUPPORT
 358
 359 More information at:
 360
 361 =over 4
 362
 363 =item * RT: CPAN's request tracker
 364
 365 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Catalyst-Controller-WrapCGI>
 366
 367 =item * AnnoCPAN: Annotated CPAN documentation
 368
 369 L<http://annocpan.org/dist/Catalyst-Controller-WrapCGI>
 370
 371 =item * CPAN Ratings
 372
 373 L<http://cpanratings.perl.org/d/Catalyst-Controller-WrapCGI>
 374
 375 =item * Search CPAN
 376
 377 L<http://search.cpan.org/dist/Catalyst-Controller-WrapCGI>
 378
 379 =back
 380
 381 =head1 AUTHOR
 382
 383 See L<Catalyst::Controller::WrapCGI/AUTHOR> and
 384 L<Catalyst::Controller::WrapCGI/CONTRIBUTORS>.
 385
 386 =head1 COPYRIGHT & LICENSE
 387
 388 Copyright (c) 2008-2009 L<Catalyst::Controller::WrapCGI/AUTHOR> and
 389 L<Catalyst::Controller::WrapCGI/CONTRIBUTORS>.
 390
 391 This program is free software; you can redistribute it and/or modify it
 392 under the same terms as Perl itself.
 393
 394 =cut
 395
 396 1; # End of Catalyst::Controller::CGIBin
 397 # vim:et sw=4 sts=4 tw=0: