lib/Catalyst/Controller/CGIBin.pm

   1 package Catalyst::Controller::CGIBin;
   2
   3 use Moose;
   4 use mro 'c3';
   5
   6 extends 'Catalyst::Controller::WrapCGI';
   7
   8 use File::Slurp 'slurp';
   9 use File::Find::Rule ();
  10 use Catalyst::Exception ();
  11 use File::Spec::Functions qw/splitdir abs2rel/;
  12 use IPC::Open3;
  13 use Symbol 'gensym';
  14 use List::MoreUtils 'any';
  15 use IO::File ();
  16 use Carp;
  17
  18 use namespace::clean -except => 'meta';
  19
  20 =head1 NAME
  21
  22 Catalyst::Controller::CGIBin - Serve CGIs from root/cgi-bin
  23
  24 =head1 VERSION
  25
  26 Version 0.020
  27
  28 =cut
  29
  30 our $VERSION = '0.020';
  31
  32 =head1 SYNOPSIS
  33
  34 In your controller:
  35
  36     package MyApp::Controller::Foo;
  37
  38     use parent qw/Catalyst::Controller::CGIBin/;
  39
  40 In your .conf:
  41
  42     <Controller::Foo>
  43         cgi_root_path cgi-bin
  44         cgi_dir       cgi-bin
  45         <CGI>
  46             username_field username # used for REMOTE_USER env var
  47             pass_env PERL5LIB
  48             pass_env PATH
  49             pass_env /^MYAPP_/
  50         </CGI>
  51     </Controller::Foo>
  52
  53 =head1 DESCRIPTION
  54
  55 Dispatches to CGI files in root/cgi-bin for /cgi-bin/ paths.
  56
  57 Unlike L<ModPerl::Registry> this module does _NOT_ stat and recompile the CGI
  58 for every invocation. This may be supported in the future if there's interest.
  59
  60 CGI paths are converted into action names using L</cgi_action>.
  61
  62 Inherits from L<Catalyst::Controller::WrapCGI>, see the documentation for that
  63 module for other configuration information.
  64
  65 =head1 CONFIG PARAMS
  66
  67 =head2 cgi_root_path
  68
  69 The global URI path prefix for CGIs, defaults to C<cgi-bin>.
  70
  71 =head2 cgi_dir
  72
  73 Path from which to read CGI files. Can be relative to C<$MYAPP_HOME/root> or
  74 absolute.  Defaults to C<$MYAPP_HOME/root/cgi-bin>.
  75
  76 =cut
  77
  78 has cgi_root_path => (is => 'ro', isa => 'Str', default => 'cgi-bin');
  79 has cgi_dir       => (is => 'ro', isa => 'Str', default => 'cgi-bin');
  80
  81 sub register_actions {
  82     my ($self, $app) = @_;
  83
  84     my $cgi_bin = File::Spec->file_name_is_absolute($self->cgi_dir) ?
  85         $self->cgi_dir
  86         : $app->path_to('root', $self->cgi_dir);
  87
  88     my $namespace = $self->action_namespace($app);
  89
  90     my $class = ref $self || $self;
  91
  92     for my $file (File::Find::Rule->file->in($cgi_bin)) {
  93         my $cgi_path = abs2rel($file, $cgi_bin);
  94
  95         next if any { $_ eq '.svn' } splitdir $cgi_path;
  96         next if $cgi_path =~ /\.swp\z/;
  97
  98         my $path        = join '/' => splitdir($cgi_path);
  99         my $action_name = $self->cgi_action($path);
 100         my $public_path = $self->cgi_path($path);
 101         my $reverse     = $namespace ? "$namespace/$action_name" : $action_name;
 102         my $attrs       = { Path => [ $public_path ] };
 103
 104         my ($cgi, $type);
 105
 106         if ($self->is_perl_cgi($file)) { # syntax check passed
 107             $type = 'Perl';
 108             $cgi  = $self->wrap_perl_cgi($file, $action_name);
 109         } else {
 110             $type = 'Non-Perl';
 111             $cgi  = $self->wrap_nonperl_cgi($file, $action_name);
 112         }
 113
 114         $app->log->info("Registering root/cgi-bin/$cgi_path as a $type CGI.")
 115             if $app->debug;
 116
 117         my $code = sub {
 118             my ($controller, $context) = @_;
 119             $controller->cgi_to_response($context, $cgi)
 120         };
 121
 122         my $action = $self->create_action(
 123             name       => $action_name,
 124             code       => $code,
 125             reverse    => $reverse,
 126             namespace  => $namespace,
 127             class      => $class,
 128             attributes => $attrs
 129         );
 130
 131         $app->dispatcher->register($app, $action);
 132     }
 133
 134     $self->next::method($app, @_);
 135
 136 # Tell Static::Simple to ignore cgi_dir
 137     if ($cgi_bin =~ /^@{[ $app->path_to('root') ]}/) {
 138         my $rel = File::Spec->abs2rel($cgi_bin, $app->path_to('root'));
 139
 140         if (!any { $_ eq $rel }
 141                 @{ $app->config->{static}{ignore_dirs}||[] }) {
 142             push @{ $app->config->{static}{ignore_dirs} }, $rel;
 143         }
 144     }
 145 }
 146
 147 =head1 METHODS
 148
 149 =head2 cgi_action
 150
 151 C<< $self->cgi_action($cgi) >>
 152
 153 Takes a path to a CGI from C<root/cgi-bin> such as C<foo/bar.cgi> and returns
 154 the action name it is registered as. See L</DESCRIPTION> for a discussion on how
 155 CGI actions are named.
 156
 157 A path such as C<root/cgi-bin/hlagh/bar.cgi> will get the private path
 158 C<foo/CGI_hlagh__bar_cgi>, for controller Foo, with the C</>s converted to C<__>
 159 and prepended with C<CGI_>, as well as all non-word characters converted to
 160 C<_>s. This is because L<Catalyst> action names can't have non-word characters
 161 in them.
 162
 163 This means that C<foo/bar.cgi> and C<foo__bar.cgi> for example will both map to
 164 the action C<CGI_foo__bar_cgi> so B<DON'T DO THAT>.
 165
 166 =cut
 167
 168 sub cgi_action {
 169     my ($self, $cgi) = @_;
 170
 171     my $action_name = 'CGI_' . join '__' => split '/' => $cgi;
 172     $action_name    =~ s/\W/_/g;
 173
 174     $action_name
 175 }
 176
 177 =head2 cgi_path
 178
 179 C<< $self->cgi_path($cgi) >>
 180
 181 Takes a path to a CGI from C<root/cgi-bin> such as C<foo/bar.cgi> and returns
 182 the public path it should be registered under.
 183
 184 The default is to prefix with C<$cgi_root_path/>, using the C<cgi_root_path>
 185 config setting, above.
 186
 187 =cut
 188
 189 sub cgi_path {
 190     my ($self, $cgi) = @_;
 191
 192     my $root = $self->cgi_root_path;
 193     $root =~ s{/*$}{};
 194     return "$root/$cgi";
 195 }
 196
 197 =head2 is_perl_cgi
 198
 199 C<< $self->is_perl_cgi($path) >>
 200
 201 Tries to figure out whether the CGI is Perl or not.
 202
 203 If it's Perl, it will be inlined into a sub instead of being forked off, see
 204 L</wrap_perl_cgi>.
 205
 206 =cut
 207
 208 sub is_perl_cgi {
 209     my ($self, $cgi) = @_;
 210
 211     my $shebang = IO::File->new($cgi)->getline;
 212
 213     return 0 if $shebang !~ /perl/ && $cgi !~ /\.pl\z/;
 214
 215     my $taint_check = $shebang =~ /-T/ ?  '-T' : '';
 216
 217     open NULL, '>', File::Spec->devnull;
 218     my $pid = open3(gensym, '&>NULL', '&>NULL', "$^X $taint_check -c $cgi");
 219     close NULL;
 220     waitpid $pid, 0;
 221
 222     $? >> 8 == 0
 223 }
 224
 225 =head2 wrap_perl_cgi
 226
 227 C<< $self->wrap_perl_cgi($path, $action_name) >>
 228
 229 Takes the path to a Perl CGI and returns a coderef suitable for passing to
 230 cgi_to_response (from L<Catalyst::Controller::WrapCGI>.)
 231
 232 C<$action_name> is the generated name for the action representing the CGI file
 233 from C<cgi_action>.
 234
 235 This is similar to how L<ModPerl::Registry> works, but will only work for
 236 well-written CGIs. Otherwise, you may have to override this method to do
 237 something more involved (see L<ModPerl::PerlRun>.)
 238
 239 Scripts with C<__DATA__> sections now work too, as well as scripts that call
 240 C<exit()>.
 241
 242 =cut
 243
 244 sub wrap_perl_cgi {
 245     my ($self, $cgi, $action_name) = @_;
 246
 247     my $code = slurp $cgi;
 248
 249     $code =~ s/^__DATA__(?:\r?\n|\r\n?)(.*)//ms;
 250     my $data = $1;
 251
 252     my $coderef = do {
 253         no warnings;
 254         # catch exit() and turn it into (effectively) a return
 255         # we *must* eval STRING because the code needs to be compiled with the
 256         # overridden CORE::GLOBAL::exit in view
 257         #
 258         # set $0 to the name of the cgi file in case it's used there
 259         eval '
 260             my $cgi_exited = "EXIT\n";
 261             BEGIN { *CORE::GLOBAL::exit = sub (;$) {
 262                 die [ $cgi_exited, $_[0] || 0 ];
 263             } }
 264             package Catalyst::Controller::CGIBin::_CGIs_::'.$action_name.';
 265             sub {'
 266                 . 'local *DATA;'
 267                 . q{open DATA, '<', \$data;}
 268                 . qq{local \$0 = "\Q$cgi\E";}
 269                 . q/my $rv = eval {/
 270                 . $code
 271                 . q/};/
 272                 . q{
 273                     return $rv unless $@;
 274                     die $@ if $@ and not (
 275                       ref($@) eq 'ARRAY' and
 276                       $@->[0] eq $cgi_exited
 277                     );
 278                     die "exited nonzero: $@->[1]" if $@->[1] != 0;
 279                     return $rv;
 280                 }
 281          . '}';
 282     };
 283
 284     croak __PACKAGE__ . ": Could not compile $cgi to coderef: $@" if $@;
 285
 286     $coderef
 287 }
 288
 289 =head2 wrap_nonperl_cgi
 290
 291 C<< $self->wrap_nonperl_cgi($path, $action_name) >>
 292
 293 Takes the path to a non-Perl CGI and returns a coderef for executing it.
 294
 295 C<$action_name> is the generated name for the action representing the CGI file.
 296
 297 By default returns:
 298
 299     sub { system $path }
 300
 301 =cut
 302
 303 sub wrap_nonperl_cgi {
 304     my ($self, $cgi, $action_name) = @_;
 305
 306     sub { system $cgi }
 307 }
 308
 309 __PACKAGE__->meta->make_immutable;
 310
 311 =head1 SEE ALSO
 312
 313 L<Catalyst::Controller::WrapCGI>, L<CatalystX::GlobalContext>,
 314 L<Catalyst::Controller>, L<CGI>, L<Catalyst>
 315
 316 =head1 AUTHOR
 317
 318 Rafael Kitover, C<< <rkitover at cpan.org> >>
 319
 320 =head1 CONTRIBUTORS
 321
 322 Hans Dieter Pearcey, C<< <hdp at cpan.org> >>
 323
 324 =head1 BUGS
 325
 326 Please report any bugs or feature requests to C<bug-catalyst-controller-wrapcgi at
 327 rt.cpan.org>, or through the web interface at
 328 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Catalyst-Controller-WrapCGI>.
 329 I will be notified, and then you'll automatically be notified of progress on
 330 your bug as I make changes.
 331
 332 =head1 SUPPORT
 333
 334 More information at:
 335
 336 =over 4
 337
 338 =item * RT: CPAN's request tracker
 339
 340 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Catalyst-Controller-WrapCGI>
 341
 342 =item * AnnoCPAN: Annotated CPAN documentation
 343
 344 L<http://annocpan.org/dist/Catalyst-Controller-WrapCGI>
 345
 346 =item * CPAN Ratings
 347
 348 L<http://cpanratings.perl.org/d/Catalyst-Controller-WrapCGI>
 349
 350 =item * Search CPAN
 351
 352 L<http://search.cpan.org/dist/Catalyst-Controller-WrapCGI>
 353
 354 =back
 355
 356 =head1 COPYRIGHT & LICENSE
 357
 358 Copyright (c) 2008 Rafael Kitover
 359
 360 This program is free software; you can redistribute it and/or modify it
 361 under the same terms as Perl itself.
 362
 363 =cut
 364
 365 1; # End of Catalyst::Controller::CGIBin
 366
 367 # vim: expandtab shiftwidth=4 ts=4 tw=80: