lib/Catalyst/Controller/CGIBin.pm

   1 package Catalyst::Controller::CGIBin;
   2
   3 use Moose;
   4 use mro 'c3';
   5
   6 extends 'Catalyst::Controller::WrapCGI';
   7
   8 use File::Find::Rule ();
   9 use File::Spec::Functions qw/splitdir abs2rel/;
  10 use IPC::Open3;
  11 use Symbol 'gensym';
  12 use List::MoreUtils 'any';
  13 use IO::File ();
  14 use File::Temp 'tempfile';
  15 use File::pushd;
  16 use CGI::Compile;
  17
  18 use namespace::clean -except => 'meta';
  19
  20 =head1 NAME
  21
  22 Catalyst::Controller::CGIBin - Serve CGIs from root/cgi-bin
  23
  24 =cut
  25
  26 our $VERSION = '0.030';
  27
  28 =head1 SYNOPSIS
  29
  30 In your controller:
  31
  32     package MyApp::Controller::Foo;
  33
  34     use parent qw/Catalyst::Controller::CGIBin/;
  35
  36 In your .conf:
  37
  38     <Controller::Foo>
  39         cgi_root_path    cgi-bin
  40         cgi_dir          cgi-bin
  41         cgi_chain_root   /optional/private/path/to/Chained/root
  42         cgi_file_pattern *.cgi
  43         # or regex
  44         cgi_file_pattern /\.pl\z/
  45         <CGI>
  46             username_field username # used for REMOTE_USER env var
  47             pass_env PERL5LIB
  48             pass_env PATH
  49             pass_env /^MYAPP_/
  50         </CGI>
  51     </Controller::Foo>
  52
  53 =head1 DESCRIPTION
  54
  55 Dispatches to CGI files in root/cgi-bin for /cgi-bin/ paths.
  56
  57 Unlike L<ModPerl::Registry> this module does _NOT_ stat and recompile the CGI
  58 for every invocation. This may be supported in the future if there's interest.
  59
  60 CGI paths are converted into action names using L</cgi_action>.
  61
  62 Inherits from L<Catalyst::Controller::WrapCGI>, see the documentation for that
  63 module for other configuration information.
  64
  65 =head1 CONFIG PARAMS
  66
  67 =head2 cgi_root_path
  68
  69 The global URI path prefix for CGIs, defaults to C<cgi-bin>.
  70
  71 =head2 cgi_chain_root
  72
  73 By default L<Path|Catalyst::DispatchType::Path> actions are created for CGIs,
  74 but if you specify this option, the actions will be created as
  75 L<Chained|Catalyst::DispatchType::Chained> end-points, chaining off the
  76 specified private path.
  77
  78 If this option is used, the L</cgi_root_path> option is ignored. The root path
  79 will be determined by your chain.
  80
  81 The L<PathPart|Catalyst::DispatchType::Chained/PathPart> of the action will be
  82 the path to the CGI file.
  83
  84 =head2 cgi_dir
  85
  86 Path from which to read CGI files. Can be relative to C<$MYAPP_HOME/root> or
  87 absolute.  Defaults to C<$MYAPP_HOME/root/cgi-bin>.
  88
  89 =head2 cgi_file_pattern
  90
  91 By default all files in L</cgi_dir> will be loaded as CGIs, however, with this
  92 option you can specify either a glob or a regex to match the names of files you
  93 want to be loaded.
  94
  95 Can be an array of globs/regexes as well.
  96
  97 =cut
  98
  99 has cgi_root_path    => (is => 'ro', isa => 'Str', default => 'cgi-bin');
 100 has cgi_chain_root   => (is => 'ro', isa => 'Str');
 101 has cgi_dir          => (is => 'ro', isa => 'Str', default => 'cgi-bin');
 102 has cgi_file_pattern => (is => 'rw', default => sub { ['*'] });
 103
 104 sub register_actions {
 105     my ($self, $app) = @_;
 106
 107     my $cgi_bin;
 108     if( File::Spec->file_name_is_absolute($self->cgi_dir) ) {
 109         $cgi_bin = $self->cgi_dir;
 110     } elsif( File::Spec->file_name_is_absolute( $app->config->{root} ) ) {
 111         $cgi_bin = File::Spec->catdir( $app->config->{root}, $self->cgi_dir );
 112     } else {
 113         $cgi_bin = $app->path_to( $app->config->{root}, $self->cgi_dir);
 114     }
 115
 116     my $namespace = $self->action_namespace($app);
 117
 118     my $class = ref $self || $self;
 119
 120     my $patterns = $self->cgi_file_pattern;
 121     $patterns = [ $patterns ] if not ref $patterns;
 122     for my $pat (@$patterns) {
 123         if ($pat =~ m{^/(.*)/\z}) {
 124             $pat = qr/$1/;
 125         }
 126     }
 127     $self->cgi_file_pattern($patterns);
 128
 129     for my $file (File::Find::Rule->file->name(@$patterns)->in($cgi_bin)) {
 130         my $cgi_path = abs2rel($file, $cgi_bin);
 131
 132         next if any { $_ eq '.svn' } splitdir $cgi_path;
 133         next if $cgi_path =~ /\.swp\z/;
 134
 135         my $path        = join '/' => splitdir($cgi_path);
 136         my $action_name = $self->cgi_action($path);
 137         my $reverse     = $namespace ? "$namespace/$action_name" : $action_name;
 138
 139         my $attrs = do {
 140             if (my $chain_root = $self->cgi_chain_root) {
 141                 { Chained => [ $chain_root ], PathPart => [ $path ], Args => [] };
 142             }
 143             else {
 144                 { Path => [ $self->cgi_path($path) ] };
 145             }
 146         };
 147
 148         my ($cgi, $type);
 149
 150         if ($self->is_perl_cgi($file)) { # syntax check passed
 151             $type = 'Perl';
 152             $cgi  = $self->wrap_perl_cgi($file, $action_name);
 153         } else {
 154             $type = 'Non-Perl';
 155             $cgi  = $self->wrap_nonperl_cgi($file, $action_name);
 156         }
 157
 158         $app->log->info("Registering root/cgi-bin/$cgi_path as a $type CGI.")
 159             if $app->debug;
 160
 161         my $code = sub {
 162             my ($controller, $context) = @_;
 163             $controller->cgi_to_response($context, $cgi)
 164         };
 165
 166         my $action = $self->create_action(
 167             name       => $action_name,
 168             code       => $code,
 169             reverse    => $reverse,
 170             namespace  => $namespace,
 171             class      => $class,
 172             attributes => $attrs
 173         );
 174
 175         $app->dispatcher->register($app, $action);
 176     }
 177
 178     $self->next::method($app, @_);
 179
 180 # Tell Static::Simple to ignore cgi_dir
 181     if ($cgi_bin =~ /^@{[ $app->path_to('root') ]}/) {
 182         my $rel = File::Spec->abs2rel($cgi_bin, $app->path_to('root'));
 183
 184         if (!any { $_ eq $rel }
 185                 @{ $app->config->{static}{ignore_dirs}||[] }) {
 186             push @{ $app->config->{static}{ignore_dirs} }, $rel;
 187         }
 188     }
 189 }
 190
 191 =head1 METHODS
 192
 193 =head2 cgi_action
 194
 195 C<< $self->cgi_action($cgi) >>
 196
 197 Takes a path to a CGI from C<root/cgi-bin> such as C<foo/bar.cgi> and returns
 198 the action name it is registered as.
 199
 200 =cut
 201
 202 sub cgi_action {
 203     my ($self, $cgi) = @_;
 204
 205     my $action_name = 'CGI_' . $cgi;
 206     $action_name =~ s/([^A-Za-z0-9_])/sprintf("_%2x", unpack("C", $1))/eg;
 207
 208     return $action_name;
 209 }
 210
 211 =head2 cgi_path
 212
 213 C<< $self->cgi_path($cgi) >>
 214
 215 Takes a path to a CGI from C<root/cgi-bin> such as C<foo/bar.cgi> and returns
 216 the public path it should be registered under.
 217
 218 The default is to prefix with C<$cgi_root_path/>, using the C<cgi_root_path>
 219 config setting, above.
 220
 221 =cut
 222
 223 sub cgi_path {
 224     my ($self, $cgi) = @_;
 225
 226     my $root = $self->cgi_root_path;
 227     $root =~ s{/*$}{};
 228     return "$root/$cgi";
 229 }
 230
 231 =head2 is_perl_cgi
 232
 233 C<< $self->is_perl_cgi($path) >>
 234
 235 Tries to figure out whether the CGI is Perl or not.
 236
 237 If it's Perl, it will be inlined into a sub instead of being forked off, see
 238 L</wrap_perl_cgi>.
 239
 240 =cut
 241
 242 sub is_perl_cgi {
 243     my ($self, $cgi) = @_;
 244
 245     my (undef, $tempfile) = tempfile;
 246
 247     my $pid = fork;
 248     die "Cannot fork: $!" unless defined $pid;
 249
 250     if ($pid) {
 251         waitpid $pid, 0;
 252         my $errors = IO::File->new($tempfile)->getline;
 253         unlink $tempfile;
 254         return $errors ? 0 : 1;
 255     }
 256
 257     # child
 258     local *NULL;
 259     open NULL, '>', File::Spec->devnull;
 260     open STDOUT, '>&', \*NULL;
 261     open STDERR, '>&', \*NULL;
 262     close STDIN;
 263
 264     eval { $self->wrap_perl_cgi($cgi, '__DUMMY__') };
 265
 266     IO::File->new(">$tempfile")->print($@);
 267
 268     exit;
 269 }
 270
 271 =head2 wrap_perl_cgi
 272
 273 C<< $self->wrap_perl_cgi($path, $action_name) >>
 274
 275 Takes the path to a Perl CGI and returns a coderef suitable for passing to
 276 cgi_to_response (from L<Catalyst::Controller::WrapCGI>) using L<CGI::Compile>.
 277
 278 C<$action_name> is the generated name for the action representing the CGI file
 279 from C<cgi_action>.
 280
 281 This is similar to how L<ModPerl::Registry> works, but will only work for
 282 well-written CGIs. Otherwise, you may have to override this method to do
 283 something more involved (see L<ModPerl::PerlRun>.)
 284
 285 Scripts with C<__DATA__> sections now work too, as well as scripts that call
 286 C<exit()>.
 287
 288 =cut
 289
 290 sub wrap_perl_cgi {
 291     my ($self, $cgi, $action_name) = @_;
 292
 293     return CGI::Compile->compile($cgi,
 294         "Catalyst::Controller::CGIBin::_CGIs_::$action_name");
 295 }
 296
 297 =head2 wrap_nonperl_cgi
 298
 299 C<< $self->wrap_nonperl_cgi($path, $action_name) >>
 300
 301 Takes the path to a non-Perl CGI and returns a coderef for executing it.
 302
 303 C<$action_name> is the generated name for the action representing the CGI file.
 304
 305 By default returns something like:
 306
 307     sub { system $path }
 308
 309 =cut
 310
 311 sub wrap_nonperl_cgi {
 312     my ($self, $cgi, $action_name) = @_;
 313
 314     return sub {
 315         system $cgi;
 316
 317         if ($? == -1) {
 318             die "failed to execute CGI '$cgi': $!";
 319         }
 320         elsif ($? & 127) {
 321             die sprintf "CGI '$cgi' died with signal %d, %s coredump",
 322                 ($? & 127),  ($? & 128) ? 'with' : 'without';
 323         }
 324         else {
 325             my $exit_code = $? >> 8;
 326
 327             return 0 if $exit_code == 0;
 328
 329             die "CGI '$cgi' exited non-zero with: $exit_code";
 330         }
 331     };
 332 }
 333
 334 __PACKAGE__->meta->make_immutable;
 335
 336 =head1 SEE ALSO
 337
 338 L<Catalyst::Controller::WrapCGI>, L<CatalystX::GlobalContext>,
 339 L<Catalyst::Controller>, L<CGI>, L<CGI::Compile>, L<Catalyst>
 340
 341 =head1 BUGS
 342
 343 Please report any bugs or feature requests to C<bug-catalyst-controller-wrapcgi at
 344 rt.cpan.org>, or through the web interface at
 345 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Catalyst-Controller-WrapCGI>.
 346 I will be notified, and then you'll automatically be notified of progress on
 347 your bug as I make changes.
 348
 349 =head1 SUPPORT
 350
 351 More information at:
 352
 353 =over 4
 354
 355 =item * RT: CPAN's request tracker
 356
 357 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Catalyst-Controller-WrapCGI>
 358
 359 =item * AnnoCPAN: Annotated CPAN documentation
 360
 361 L<http://annocpan.org/dist/Catalyst-Controller-WrapCGI>
 362
 363 =item * CPAN Ratings
 364
 365 L<http://cpanratings.perl.org/d/Catalyst-Controller-WrapCGI>
 366
 367 =item * Search CPAN
 368
 369 L<http://search.cpan.org/dist/Catalyst-Controller-WrapCGI>
 370
 371 =back
 372
 373 =head1 AUTHOR
 374
 375 See L<Catalyst::Controller::WrapCGI/AUTHOR> and
 376 L<Catalyst::Controller::WrapCGI/CONTRIBUTORS>.
 377
 378 =head1 COPYRIGHT & LICENSE
 379
 380 Copyright (c) 2008-2009 L<Catalyst::Controller::WrapCGI/AUTHOR> and
 381 L<Catalyst::Controller::WrapCGI/CONTRIBUTORS>.
 382
 383 This program is free software; you can redistribute it and/or modify it
 384 under the same terms as Perl itself.
 385
 386 =cut
 387
 388 1; # End of Catalyst::Controller::CGIBin
 389 # vim:et sw=4 sts=4 tw=0: