lib/Catalyst/Controller/CGIBin.pm

   1 package Catalyst::Controller::CGIBin;
   2
   3 use Moose;
   4 use mro 'c3';
   5
   6 extends 'Catalyst::Controller::WrapCGI';
   7
   8 use File::Find::Rule ();
   9 use Catalyst::Exception ();
  10 use File::Spec::Functions qw/splitdir abs2rel/;
  11 use IPC::Open3;
  12 use Symbol 'gensym';
  13 use List::MoreUtils 'any';
  14 use IO::File ();
  15 use File::Temp 'tempfile';
  16 use File::pushd;
  17 use CGI::Compile;
  18
  19 use namespace::clean -except => 'meta';
  20
  21 =head1 NAME
  22
  23 Catalyst::Controller::CGIBin - Serve CGIs from root/cgi-bin
  24
  25 =cut
  26
  27 our $VERSION = '0.029';
  28
  29 =head1 SYNOPSIS
  30
  31 In your controller:
  32
  33     package MyApp::Controller::Foo;
  34
  35     use parent qw/Catalyst::Controller::CGIBin/;
  36
  37 In your .conf:
  38
  39     <Controller::Foo>
  40         cgi_root_path    cgi-bin
  41         cgi_dir          cgi-bin
  42         cgi_chain_root   /optional/private/path/to/Chained/root
  43         cgi_file_pattern *.cgi
  44         # or regex
  45         cgi_file_pattern /\.pl\z/
  46         <CGI>
  47             username_field username # used for REMOTE_USER env var
  48             pass_env PERL5LIB
  49             pass_env PATH
  50             pass_env /^MYAPP_/
  51         </CGI>
  52     </Controller::Foo>
  53
  54 =head1 DESCRIPTION
  55
  56 Dispatches to CGI files in root/cgi-bin for /cgi-bin/ paths.
  57
  58 Unlike L<ModPerl::Registry> this module does _NOT_ stat and recompile the CGI
  59 for every invocation. This may be supported in the future if there's interest.
  60
  61 CGI paths are converted into action names using L</cgi_action>.
  62
  63 Inherits from L<Catalyst::Controller::WrapCGI>, see the documentation for that
  64 module for other configuration information.
  65
  66 =head1 CONFIG PARAMS
  67
  68 =head2 cgi_root_path
  69
  70 The global URI path prefix for CGIs, defaults to C<cgi-bin>.
  71
  72 =head2 cgi_chain_root
  73
  74 By default L<Path|Catalyst::DispatchType::Path> actions are created for CGIs,
  75 but if you specify this option, the actions will be created as
  76 L<Chained|Catalyst::DispatchType::Chained> end-points, chaining off the
  77 specified private path.
  78
  79 If this option is used, the L</cgi_root_path> option is ignored. The root path
  80 will be determined by your chain.
  81
  82 The L<PathPart|Catalyst::DispatchType::Chained/PathPart> of the action will be
  83 the path to the CGI file.
  84
  85 =head2 cgi_dir
  86
  87 Path from which to read CGI files. Can be relative to C<$MYAPP_HOME/root> or
  88 absolute.  Defaults to C<$MYAPP_HOME/root/cgi-bin>.
  89
  90 =head2 cgi_file_pattern
  91
  92 By default all files in L</cgi_dir> will be loaded as CGIs, however, with this
  93 option you can specify either a glob or a regex to match the names of files you
  94 want to be loaded.
  95
  96 Can be an array of globs/regexes as well.
  97
  98 =cut
  99
 100 has cgi_root_path    => (is => 'ro', isa => 'Str', default => 'cgi-bin');
 101 has cgi_chain_root   => (is => 'ro', isa => 'Str');
 102 has cgi_dir          => (is => 'ro', isa => 'Str', default => 'cgi-bin');
 103 has cgi_file_pattern => (is => 'rw', default => sub { ['*'] });
 104
 105 sub register_actions {
 106     my ($self, $app) = @_;
 107
 108     my $cgi_bin = File::Spec->file_name_is_absolute($self->cgi_dir) ?
 109         $self->cgi_dir
 110         : $app->path_to('root', $self->cgi_dir);
 111
 112     my $namespace = $self->action_namespace($app);
 113
 114     my $class = ref $self || $self;
 115
 116     my $patterns = $self->cgi_file_pattern;
 117     $patterns = [ $patterns ] if not ref $patterns;
 118     for my $pat (@$patterns) {
 119         if ($pat =~ m{^/(.*)/\z}) {
 120             $pat = qr/$1/;
 121         }
 122     }
 123     $self->cgi_file_pattern($patterns);
 124
 125     for my $file (File::Find::Rule->file->name(@$patterns)->in($cgi_bin)) {
 126         my $cgi_path = abs2rel($file, $cgi_bin);
 127
 128         next if any { $_ eq '.svn' } splitdir $cgi_path;
 129         next if $cgi_path =~ /\.swp\z/;
 130
 131         my $path        = join '/' => splitdir($cgi_path);
 132         my $action_name = $self->cgi_action($path);
 133         my $reverse     = $namespace ? "$namespace/$action_name" : $action_name;
 134
 135         my $attrs = do {
 136             if (my $chain_root = $self->cgi_chain_root) {
 137                 { Chained => [ $chain_root ], PathPart => [ $path ], Args => [] };
 138             }
 139             else {
 140                 { Path => [ $self->cgi_path($path) ] };
 141             }
 142         };
 143
 144         my ($cgi, $type);
 145
 146         if ($self->is_perl_cgi($file)) { # syntax check passed
 147             $type = 'Perl';
 148             $cgi  = $self->wrap_perl_cgi($file, $action_name);
 149         } else {
 150             $type = 'Non-Perl';
 151             $cgi  = $self->wrap_nonperl_cgi($file, $action_name);
 152         }
 153
 154         $app->log->info("Registering root/cgi-bin/$cgi_path as a $type CGI.")
 155             if $app->debug;
 156
 157         my $code = sub {
 158             my ($controller, $context) = @_;
 159             $controller->cgi_to_response($context, $cgi)
 160         };
 161
 162         my $action = $self->create_action(
 163             name       => $action_name,
 164             code       => $code,
 165             reverse    => $reverse,
 166             namespace  => $namespace,
 167             class      => $class,
 168             attributes => $attrs
 169         );
 170
 171         $app->dispatcher->register($app, $action);
 172     }
 173
 174     $self->next::method($app, @_);
 175
 176 # Tell Static::Simple to ignore cgi_dir
 177     if ($cgi_bin =~ /^@{[ $app->path_to('root') ]}/) {
 178         my $rel = File::Spec->abs2rel($cgi_bin, $app->path_to('root'));
 179
 180         if (!any { $_ eq $rel }
 181                 @{ $app->config->{static}{ignore_dirs}||[] }) {
 182             push @{ $app->config->{static}{ignore_dirs} }, $rel;
 183         }
 184     }
 185 }
 186
 187 =head1 METHODS
 188
 189 =head2 cgi_action
 190
 191 C<< $self->cgi_action($cgi) >>
 192
 193 Takes a path to a CGI from C<root/cgi-bin> such as C<foo/bar.cgi> and returns
 194 the action name it is registered as.
 195
 196 =cut
 197
 198 sub cgi_action {
 199     my ($self, $cgi) = @_;
 200
 201     my $action_name = 'CGI_' . $cgi;
 202     $action_name =~ s/([^A-Za-z0-9_])/sprintf("_%2x", unpack("C", $1))/eg;
 203
 204     return $action_name;
 205 }
 206
 207 =head2 cgi_path
 208
 209 C<< $self->cgi_path($cgi) >>
 210
 211 Takes a path to a CGI from C<root/cgi-bin> such as C<foo/bar.cgi> and returns
 212 the public path it should be registered under.
 213
 214 The default is to prefix with C<$cgi_root_path/>, using the C<cgi_root_path>
 215 config setting, above.
 216
 217 =cut
 218
 219 sub cgi_path {
 220     my ($self, $cgi) = @_;
 221
 222     my $root = $self->cgi_root_path;
 223     $root =~ s{/*$}{};
 224     return "$root/$cgi";
 225 }
 226
 227 =head2 is_perl_cgi
 228
 229 C<< $self->is_perl_cgi($path) >>
 230
 231 Tries to figure out whether the CGI is Perl or not.
 232
 233 If it's Perl, it will be inlined into a sub instead of being forked off, see
 234 L</wrap_perl_cgi>.
 235
 236 =cut
 237
 238 sub is_perl_cgi {
 239     my ($self, $cgi) = @_;
 240
 241     my (undef, $tempfile) = tempfile;
 242
 243     my $pid = fork;
 244     die "Cannot fork: $!" unless defined $pid;
 245
 246     if ($pid) {
 247         waitpid $pid, 0;
 248         my $errors = IO::File->new($tempfile)->getline;
 249         unlink $tempfile;
 250         return $errors ? 0 : 1;
 251     }
 252
 253     # child
 254     local *NULL;
 255     open NULL, '>', File::Spec->devnull;
 256     open STDOUT, '>&', \*NULL;
 257     open STDERR, '>&', \*NULL;
 258     close STDIN;
 259
 260     eval { $self->wrap_perl_cgi($cgi, '__DUMMY__') };
 261
 262     IO::File->new(">$tempfile")->print($@);
 263
 264     exit;
 265 }
 266
 267 =head2 wrap_perl_cgi
 268
 269 C<< $self->wrap_perl_cgi($path, $action_name) >>
 270
 271 Takes the path to a Perl CGI and returns a coderef suitable for passing to
 272 cgi_to_response (from L<Catalyst::Controller::WrapCGI>) using L<CGI::Compile>.
 273
 274 C<$action_name> is the generated name for the action representing the CGI file
 275 from C<cgi_action>.
 276
 277 This is similar to how L<ModPerl::Registry> works, but will only work for
 278 well-written CGIs. Otherwise, you may have to override this method to do
 279 something more involved (see L<ModPerl::PerlRun>.)
 280
 281 Scripts with C<__DATA__> sections now work too, as well as scripts that call
 282 C<exit()>.
 283
 284 =cut
 285
 286 sub wrap_perl_cgi {
 287     my ($self, $cgi, $action_name) = @_;
 288
 289     return CGI::Compile->compile($cgi,
 290         "Catalyst::Controller::CGIBin::_CGIs_::$action_name");
 291 }
 292
 293 =head2 wrap_nonperl_cgi
 294
 295 C<< $self->wrap_nonperl_cgi($path, $action_name) >>
 296
 297 Takes the path to a non-Perl CGI and returns a coderef for executing it.
 298
 299 C<$action_name> is the generated name for the action representing the CGI file.
 300
 301 By default returns something like:
 302
 303     sub { system $path }
 304
 305 =cut
 306
 307 sub wrap_nonperl_cgi {
 308     my ($self, $cgi, $action_name) = @_;
 309
 310     return sub {
 311         system $cgi;
 312
 313         if ($? == -1) {
 314             die "failed to execute CGI '$cgi': $!";
 315         }
 316         elsif ($? & 127) {
 317             die sprintf "CGI '$cgi' died with signal %d, %s coredump",
 318                 ($? & 127),  ($? & 128) ? 'with' : 'without';
 319         }
 320         else {
 321             my $exit_code = $? >> 8;
 322
 323             return 0 if $exit_code == 0;
 324
 325             die "CGI '$cgi' exited non-zero with: $exit_code";
 326         }
 327     };
 328 }
 329
 330 __PACKAGE__->meta->make_immutable;
 331
 332 =head1 SEE ALSO
 333
 334 L<Catalyst::Controller::WrapCGI>, L<CatalystX::GlobalContext>,
 335 L<Catalyst::Controller>, L<CGI>, L<CGI::Compile>, L<Catalyst>
 336
 337 =head1 BUGS
 338
 339 Please report any bugs or feature requests to C<bug-catalyst-controller-wrapcgi at
 340 rt.cpan.org>, or through the web interface at
 341 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Catalyst-Controller-WrapCGI>.
 342 I will be notified, and then you'll automatically be notified of progress on
 343 your bug as I make changes.
 344
 345 =head1 SUPPORT
 346
 347 More information at:
 348
 349 =over 4
 350
 351 =item * RT: CPAN's request tracker
 352
 353 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Catalyst-Controller-WrapCGI>
 354
 355 =item * AnnoCPAN: Annotated CPAN documentation
 356
 357 L<http://annocpan.org/dist/Catalyst-Controller-WrapCGI>
 358
 359 =item * CPAN Ratings
 360
 361 L<http://cpanratings.perl.org/d/Catalyst-Controller-WrapCGI>
 362
 363 =item * Search CPAN
 364
 365 L<http://search.cpan.org/dist/Catalyst-Controller-WrapCGI>
 366
 367 =back
 368
 369 =head1 AUTHOR
 370
 371 See L<Catalyst::Controller::WrapCGI/AUTHOR> and
 372 L<Catalyst::Controller::WrapCGI/CONTRIBUTORS>.
 373
 374 =head1 COPYRIGHT & LICENSE
 375
 376 Copyright (c) 2008-2009 L<Catalyst::Controller::WrapCGI/AUTHOR> and
 377 L<Catalyst::Controller::WrapCGI/CONTRIBUTORS>.
 378
 379 This program is free software; you can redistribute it and/or modify it
 380 under the same terms as Perl itself.
 381
 382 =cut
 383
 384 1; # End of Catalyst::Controller::CGIBin
 385 # vim:et sw=4 sts=4 tw=0: