t/rest/item.t

   1 use strict;
   2 use warnings;
   3
   4 use lib 't/lib';
   5
   6 my $base = 'http://localhost';
   7
   8 use RestTest;
   9 use DBICTest;
  10 use URI;
  11 use Test::More;
  12 use Test::WWW::Mechanize::Catalyst 'RestTest';
  13 use HTTP::Request::Common;
  14 use JSON;
  15
  16 my $json = JSON->new->utf8;
  17
  18 my $mech = Test::WWW::Mechanize::Catalyst->new;
  19 ok( my $schema = DBICTest->init_schema(), 'got schema' );
  20
  21 my $artist_view_url = "$base/api/rest/artist/";
  22
  23 {
  24     my $id = 1;
  25     my $req =
  26         GET( $artist_view_url . $id, 'Accept' => 'application/json' );
  27     $mech->request($req);
  28     cmp_ok( $mech->status, '==', 200, 'open attempt okay' );
  29     my %expected_response =
  30         $schema->resultset('Artist')->find($id)->get_columns;
  31     my $response = $json->decode( $mech->content );
  32     #artist does not have use_json_boolean => 1, so true values are stringified to 'true'
  33     is_deeply(
  34         $response,
  35
  36         # artist doesn't set use_json_boolean
  37         { data => \%expected_response, success => 'true' },
  38         'correct data returned'
  39     );
  40 }
  41
  42 {
  43     my $id = 5;
  44     my $req =
  45         GET( $artist_view_url . $id, 'Accept' => 'application/json' );
  46     $mech->request($req);
  47     cmp_ok( $mech->status, '==', 400, 'open attempt not ok' );
  48     my $response = $json->decode( $mech->content );
  49     is( $response->{success}, 'false',
  50         'not existing object fetch failed ok' );
  51     like(
  52         $response->{messages}->[0],
  53         qr/^No object found for id/,
  54         'error message for not existing object fetch ok'
  55     );
  56 }
  57
  58 my $track_view_url = "$base/api/rest/track/";
  59
  60 {
  61     my $id = 9;
  62     my $req =
  63         GET( $track_view_url . $id, 'Accept' => 'application/json' );
  64     $mech->request($req);
  65     cmp_ok( $mech->status, '==', 200, 'got track with datetime object okay' );
  66     my %expected_response =
  67         $schema->resultset('Track')->find($id)->get_columns;
  68     my $response = $json->decode( $mech->content );
  69     is_deeply(
  70         $response,
  71
  72         # track does set use_json_boolean
  73         { data => \%expected_response, success => JSON::true },
  74         'correct data returned for track with datetime'
  75     );
  76 }
  77
  78 {
  79     my $req =
  80         GET( $artist_view_url . 'action_with_error', 'Accept' => 'application/json' );
  81     $mech->request($req);
  82     cmp_ok( $mech->status, '==', 404, 'action returned error 404' );
  83     my $response = $json->decode( $mech->content );
  84     is_deeply(
  85         $response,
  86
  87         # artist doesn't set use_json_boolean
  88         { success => 'false' },
  89         'correct data returned'
  90     );
  91 }
  92
  93 done_testing();