lib/Catalyst/Authentication/Store/LDAP/Backend.pm

   1
   2 =pod
   3
   4 =head1 NAME
   5
   6 Catalyst::Authentication::Store::LDAP::Backend
   7   - LDAP authentication storage backend.
   8
   9 =head1 SYNOPSIS
  10
  11     # you probably just want Store::LDAP under most cases,
  12     # but if you insist you can instantiate your own store:
  13
  14     use Catalyst::Authentication::Store::LDAP::Backend;
  15
  16     use Catalyst qw/
  17         Authentication
  18         Authentication::Credential::Password
  19     /;
  20
  21     my %config = (
  22             'ldap_server' => 'ldap1.yourcompany.com',
  23             'ldap_server_options' => {
  24                 'timeout' => 30,
  25             },
  26             'binddn' => 'anonymous',
  27             'bindpw' => 'dontcarehow',
  28             'start_tls' => 1,
  29             'start_tls_options' => {
  30                 'verify' => 'none',
  31             },
  32             'user_basedn' => 'ou=people,dc=yourcompany,dc=com',
  33             'user_filter' => '(&(objectClass=posixAccount)(uid=%s))',
  34             'user_scope' => 'one',  # or 'sub' for Active Directory
  35             'user_field' => 'uid',
  36             'user_search_options' => {
  37                 'deref' => 'always',
  38             },
  39             'user_results_filter' => sub { return shift->pop_entry },
  40             'entry_class' => 'MyApp::LDAP::Entry',
  41             'user_class' => 'MyUser',
  42             'use_roles' => 1,
  43             'role_basedn' => 'ou=groups,dc=yourcompany,dc=com',
  44             'role_filter' => '(&(objectClass=posixGroup)(member=%s))',
  45             'role_scope' => 'one',
  46             'role_field' => 'cn',
  47             'role_value' => 'dn',
  48             'role_search_options' => {
  49                 'deref' => 'always',
  50             },
  51             'role_search_as_user' => 0,
  52     );
  53
  54     our $users = Catalyst::Authentication::Store::LDAP::Backend->new(\%config);
  55
  56 =head1 DESCRIPTION
  57
  58 You probably want L<Catalyst::Authentication::Store::LDAP>.
  59
  60 Otherwise, this lets you create a store manually.
  61
  62 See the L<Catalyst::Authentication::Store::LDAP> documentation for
  63 an explanation of the configuration options.
  64
  65 =head1 METHODS
  66
  67 =cut
  68
  69 package Catalyst::Authentication::Store::LDAP::Backend;
  70 use base qw( Class::Accessor::Fast );
  71
  72 use strict;
  73 use warnings;
  74
  75 our $VERSION = '1.014';
  76
  77 use Catalyst::Authentication::Store::LDAP::User;
  78 use Net::LDAP;
  79 use Catalyst::Utils ();
  80
  81 BEGIN {
  82     __PACKAGE__->mk_accessors(
  83         qw( ldap_server ldap_server_options binddn
  84             bindpw entry_class user_search_options
  85             user_filter user_basedn user_scope
  86             user_attrs user_field use_roles role_basedn
  87             role_filter role_scope role_field role_value
  88             role_search_options start_tls start_tls_options
  89             user_results_filter user_class role_search_as_user
  90             )
  91     );
  92 }
  93
  94 =head2 new($config)
  95
  96 Creates a new L<Catalyst::Authentication::Store::LDAP::Backend> object.
  97 $config should be a hashref, which should contain the configuration options
  98 listed in L<Catalyst::Authentication::Store::LDAP>'s documentation.
  99
 100 Also sets a few sensible defaults.
 101
 102 =cut
 103
 104 sub new {
 105     my ( $class, $config ) = @_;
 106
 107     unless ( defined($config) && ref($config) eq "HASH" ) {
 108         Catalyst::Exception->throw(
 109             "Catalyst::Authentication::Store::LDAP::Backend needs to be configured with a hashref."
 110         );
 111     }
 112     my %config_hash = %{$config};
 113     $config_hash{'binddn'}      ||= 'anonymous';
 114     $config_hash{'user_filter'} ||= '(uid=%s)';
 115     $config_hash{'user_scope'}  ||= 'sub';
 116     $config_hash{'user_field'}  ||= 'uid';
 117     $config_hash{'role_filter'} ||= '(memberUid=%s)';
 118     $config_hash{'role_scope'}  ||= 'sub';
 119     $config_hash{'role_field'}  ||= 'cn';
 120     $config_hash{'use_roles'}   ||= '1';
 121     $config_hash{'start_tls'}   ||= '0';
 122     $config_hash{'entry_class'} ||= 'Catalyst::Model::LDAP::Entry';
 123     $config_hash{'user_class'}
 124         ||= 'Catalyst::Authentication::Store::LDAP::User';
 125     $config_hash{'role_search_as_user'} ||= 0;
 126
 127     Catalyst::Utils::ensure_class_loaded( $config_hash{'user_class'} );
 128     my $self = \%config_hash;
 129     bless( $self, $class );
 130     return $self;
 131 }
 132
 133 =head2 find_user( I<authinfo>, $c )
 134
 135 Creates a L<Catalyst::Authentication::Store::LDAP::User> object
 136 for the given User ID.  This is the preferred mechanism for getting a
 137 given User out of the Store.
 138
 139 I<authinfo> should be a hashref with a key of either C<id> or
 140 C<username>. The value will be compared against the LDAP C<user_field> field.
 141
 142 =cut
 143
 144 sub find_user {
 145     my ( $self, $authinfo, $c ) = @_;
 146     return $self->get_user( $authinfo->{id} || $authinfo->{username}, $c );
 147 }
 148
 149 =head2 get_user( I<id>, $c)
 150
 151 Creates a L<Catalyst::Authentication::Store::LDAP::User> object
 152 for the given User ID, or calls C<new> on the class specified in
 153 C<user_class>.  This instance of the store object, the results of
 154 C<lookup_user> and $c are passed as arguments (in that order) to C<new>.
 155 This is the preferred mechanism for getting a given User out of the Store.
 156
 157 =cut
 158
 159 sub get_user {
 160     my ( $self, $id, $c ) = @_;
 161     my $user = $self->user_class->new( $self, $self->lookup_user($id), $c );
 162     return $user;
 163 }
 164
 165 =head2 ldap_connect
 166
 167 Returns a L<Net::LDAP> object, connected to your LDAP server. (According
 168 to how you configured the Backend, of course)
 169
 170 =cut
 171
 172 sub ldap_connect {
 173     my ($self) = shift;
 174     my $ldap;
 175     if ( defined( $self->ldap_server_options() ) ) {
 176         $ldap
 177             = Net::LDAP->new( $self->ldap_server,
 178             %{ $self->ldap_server_options } )
 179             or Catalyst::Exception->throw($@);
 180     }
 181     else {
 182         $ldap = Net::LDAP->new( $self->ldap_server )
 183             or Catalyst::Exception->throw($@);
 184     }
 185     if ( defined( $self->start_tls ) && $self->start_tls =~ /(1|true)/i ) {
 186         my $mesg;
 187         if ( defined( $self->start_tls_options ) ) {
 188             $mesg = $ldap->start_tls( %{ $self->start_tls_options } );
 189         }
 190         else {
 191             $mesg = $ldap->start_tls;
 192         }
 193         if ( $mesg->is_error ) {
 194             Catalyst::Exception->throw( "TLS Error: " . $mesg->error );
 195         }
 196     }
 197     return $ldap;
 198 }
 199
 200 =head2 ldap_bind($ldap, $binddn, $bindpw)
 201
 202 Bind's to the directory.  If $ldap is undef, it will connect to the
 203 LDAP server first.  $binddn should be the DN of the object you wish
 204 to bind as, and $bindpw the password.
 205
 206 If $binddn is "anonymous", an anonymous bind will be performed.
 207
 208 =cut
 209
 210 sub ldap_bind {
 211     my ( $self, $ldap, $binddn, $bindpw ) = @_;
 212     $ldap ||= $self->ldap_connect;
 213     if ( !defined($ldap) ) {
 214         Catalyst::Exception->throw("LDAP Server undefined!");
 215     }
 216
 217     # if username is present, make sure password is present too.
 218     # see https://rt.cpan.org/Ticket/Display.html?id=81908
 219     if ( !defined $binddn ) {
 220         $binddn = $self->binddn;
 221         $bindpw = $self->bindpw;
 222     }
 223
 224     if ( $binddn eq "anonymous" ) {
 225         $self->_ldap_bind_anon($ldap);
 226     }
 227     else {
 228         if ($bindpw) {
 229             my $mesg = $ldap->bind( $binddn, 'password' => $bindpw );
 230             if ( $mesg->is_error ) {
 231                 Catalyst::Exception->throw(
 232                     "Error on Initial Bind: " . $mesg->error );
 233             }
 234         }
 235         else {
 236             $self->_ldap_bind_anon( $ldap, $binddn );
 237         }
 238     }
 239     return $ldap;
 240 }
 241
 242 sub _ldap_bind_anon {
 243     my ( $self, $ldap, $dn ) = @_;
 244     my $mesg = $ldap->bind($dn);
 245     if ( $mesg->is_error ) {
 246         Catalyst::Exception->throw( "Error on Bind: " . $mesg->error );
 247     }
 248 }
 249
 250 =head2 ldap_auth( $binddn, $bindpw )
 251
 252 Connect to the LDAP server and do an authenticated bind against the
 253 directory. Throws an exception if connecting to the LDAP server fails.
 254 Returns 1 if binding succeeds, 0 if it fails.
 255
 256 =cut
 257
 258 sub ldap_auth {
 259     my ( $self, $binddn, $bindpw ) = @_;
 260     my $ldap = $self->ldap_connect;
 261     if ( !defined $ldap ) {
 262         Catalyst::Exception->throw("LDAP server undefined!");
 263     }
 264     my $mesg = $ldap->bind( $binddn, password => $bindpw );
 265     return $mesg->is_error ? 0 : 1;
 266 }
 267
 268 =head2 lookup_user($id)
 269
 270 Given a User ID, this method will:
 271
 272   A) Bind to the directory using the configured binddn and bindpw
 273   B) Perform a search for the User Object in the directory, using
 274      user_basedn, user_filter, and user_scope.
 275   C) Assuming we found the object, we will walk it's attributes
 276      using L<Net::LDAP::Entry>'s get_value method.  We store the
 277      results in a hashref. If we do not find the object, then
 278      undef is returned.
 279   D) Return a hashref that looks like:
 280
 281      $results = {
 282         'ldap_entry' => $entry, # The Net::LDAP::Entry object
 283         'attributes' => $attributes,
 284      }
 285
 286 This method is usually only called by find_user().
 287
 288 =cut
 289
 290 sub lookup_user {
 291     my ( $self, $id ) = @_;
 292
 293     # Trim trailing space or we confuse ourselves
 294     $id =~ s/\s+$//;
 295     my $ldap = $self->ldap_bind;
 296     my @searchopts;
 297     if ( defined( $self->user_basedn ) ) {
 298         push( @searchopts, 'base' => $self->user_basedn );
 299     }
 300     else {
 301         Catalyst::Exception->throw(
 302             "You must set user_basedn before looking up users!");
 303     }
 304     my $filter = $self->_replace_filter( $self->user_filter, $id );
 305     push( @searchopts, 'filter' => $filter );
 306     push( @searchopts, 'scope'  => $self->user_scope );
 307     if ( defined( $self->user_search_options ) ) {
 308         push( @searchopts, %{ $self->user_search_options } );
 309     }
 310     my $usersearch = $ldap->search(@searchopts);
 311
 312     return undef if ( $usersearch->is_error );
 313
 314     my $userentry;
 315     my $user_field     = $self->user_field;
 316     my $results_filter = $self->user_results_filter;
 317     my $entry;
 318     if ( defined($results_filter) ) {
 319         $entry = &$results_filter($usersearch);
 320     }
 321     else {
 322         $entry = $usersearch->pop_entry;
 323     }
 324     if ( $usersearch->pop_entry ) {
 325         Catalyst::Exception->throw(
 326                   "More than one entry matches user search.\n"
 327                 . "Consider defining a user_results_filter sub." );
 328     }
 329
 330     # a little extra sanity check with the 'eq' since LDAP already
 331     # says it matches.
 332     # NOTE that Net::LDAP returns exactly what you asked for, but
 333     # because LDAP is often case insensitive, FoO can match foo
 334     # and so we normalize with lc().
 335     if ( defined($entry) ) {
 336         unless ( lc( $entry->get_value($user_field) ) eq lc($id) ) {
 337             Catalyst::Exception->throw(
 338                 "LDAP claims '$user_field' equals '$id' but results entry does not match."
 339             );
 340         }
 341         $userentry = $entry;
 342     }
 343
 344     $ldap->unbind;
 345     $ldap->disconnect;
 346     unless ($userentry) {
 347         return undef;
 348     }
 349     my $attrhash;
 350     foreach my $attr ( $userentry->attributes ) {
 351         my @attrvalues = $userentry->get_value($attr);
 352         if ( scalar(@attrvalues) == 1 ) {
 353             $attrhash->{ lc($attr) } = $attrvalues[0];
 354         }
 355         else {
 356             $attrhash->{ lc($attr) } = \@attrvalues;
 357         }
 358     }
 359
 360     eval { Catalyst::Utils::ensure_class_loaded( $self->entry_class ) };
 361     if ( !$@ ) {
 362         bless( $userentry, $self->entry_class );
 363         $userentry->{_use_unicode}++;
 364     }
 365     my $rv = {
 366         'ldap_entry' => $userentry,
 367         'attributes' => $attrhash,
 368     };
 369     return $rv;
 370 }
 371
 372 =head2 lookup_roles($userobj, [$ldap])
 373
 374 This method looks up the roles for a given user.  It takes a
 375 L<Catalyst::Authentication::Store::LDAP::User> object
 376 as it's first argument, and can optionally take a I<Net::LDAP> object which
 377 is used rather than the default binding if supplied.
 378
 379 It returns an array containing the role_field attribute from all the
 380 objects that match it's criteria.
 381
 382 =cut
 383
 384 sub lookup_roles {
 385     my ( $self, $userobj, $ldap ) = @_;
 386     if ( $self->use_roles == 0 || $self->use_roles =~ /^false$/i ) {
 387         return undef;
 388     }
 389     $ldap ||= $self->role_search_as_user
 390         ? $userobj->ldap_connection : $self->ldap_bind;
 391     my @searchopts;
 392     if ( defined( $self->role_basedn ) ) {
 393         push( @searchopts, 'base' => $self->role_basedn );
 394     }
 395     else {
 396         Catalyst::Exception->throw(
 397             "You must set up role_basedn before looking up roles!");
 398     }
 399     my $filter_value = $userobj->has_attribute( $self->role_value );
 400     if ( !defined($filter_value) ) {
 401         Catalyst::Exception->throw( "User object "
 402                 . $userobj->username
 403                 . " has no "
 404                 . $self->role_value
 405                 . " attribute, so I can't look up it's roles!" );
 406     }
 407     my $filter = $self->_replace_filter( $self->role_filter, $filter_value );
 408     push( @searchopts, 'filter' => $filter );
 409     push( @searchopts, 'scope'  => $self->role_scope );
 410     push( @searchopts, 'attrs'  => [ $self->role_field ] );
 411     if ( defined( $self->role_search_options ) ) {
 412         push( @searchopts, %{ $self->role_search_options } );
 413     }
 414     my $rolesearch = $ldap->search(@searchopts);
 415     my @roles;
 416 RESULT: foreach my $entry ( $rolesearch->entries ) {
 417         push( @roles, $entry->get_value( $self->role_field ) );
 418     }
 419     return @roles;
 420 }
 421
 422 sub _replace_filter {
 423     my $self    = shift;
 424     my $filter  = shift;
 425     my $replace = shift;
 426     $replace =~ s/([*()\\\x{0}])/sprintf '\\%02x', ord($1)/ge;
 427     $filter =~ s/\%s/$replace/g;
 428     return $filter;
 429 }
 430
 431 =head2 user_supports
 432
 433 Returns the value of
 434 Catalyst::Authentication::Store::LDAP::User->supports(@_).
 435
 436 =cut
 437
 438 sub user_supports {
 439     my $self = shift;
 440
 441     # this can work as a class method
 442     Catalyst::Authentication::Store::LDAP::User->supports(@_);
 443 }
 444
 445 =head2 from_session( I<id>, I<$c> )
 446
 447 Returns get_user() for I<id>.
 448
 449 =cut
 450
 451 sub from_session {
 452     my ( $self, $c, $id ) = @_;
 453     $self->get_user( $id, $c );
 454 }
 455
 456 1;
 457
 458 __END__
 459
 460 =head1 AUTHORS
 461
 462 Adam Jacob <holoway@cpan.org>
 463
 464 Some parts stolen shamelessly and entirely from
 465 L<Catalyst::Plugin::Authentication::Store::Htpasswd>.
 466
 467 Currently maintained by Peter Karman <karman@cpan.org>.
 468
 469 =head1 THANKS
 470
 471 To nothingmuch, ghenry, castaway and the rest of #catalyst for the help. :)
 472
 473 =head1 SEE ALSO
 474
 475 L<Catalyst::Authentication::Store::LDAP>, L<Catalyst::Authentication::Store::LDAP::User>, L<Catalyst::Plugin::Authentication>, L<Net::LDAP>
 476
 477 =head1 COPYRIGHT & LICENSE
 478
 479 Copyright (c) 2005 the aforementioned authors. All rights
 480 reserved. This program is free software; you can redistribute
 481 it and/or modify it under the same terms as Perl itself.
 482
 483 =cut
 484