lib/Catalyst/Authentication/Store/DBIx/Class/User.pm

   1 package Catalyst::Authentication::Store::DBIx::Class::User;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6 use base qw/Catalyst::Authentication::User/;
   7 use base qw/Class::Accessor::Fast/;
   8
   9 BEGIN {
  10     __PACKAGE__->mk_accessors(qw/config resultset _user _roles/);
  11 }
  12
  13 sub new {
  14     my ( $class, $config, $c) = @_;
  15
  16     my $self = {
  17         resultset => $c->model($config->{'user_class'}),
  18         config => $config,
  19         _roles => undef,
  20         _user => undef
  21     };
  22
  23     bless $self, $class;
  24
  25     ## Note to self- add handling of multiple-column primary keys.
  26     if (!exists($self->config->{'id_field'})) {
  27         my @pks = $self->{'resultset'}->result_source->primary_columns;
  28         if ($#pks == 0) {
  29             $self->config->{'id_field'} = $pks[0];
  30         } else {
  31             Catalyst::Exception->throw("user table does not contain a single primary key column - please specify 'id_field' in config!");
  32         }
  33     }
  34     if (!$self->{'resultset'}->result_source->has_column($self->config->{'id_field'})) {
  35         Catalyst::Exception->throw("id_field set to " .  $self->config->{'id_field'} . " but user table has no column by that name!");
  36     }
  37
  38     ## if we have lazyloading turned on - we should not query the DB unless something gets read.
  39     ## that's the idea anyway - still have to work out how to manage that - so for now we always force
  40     ## lazyload to off.
  41     $self->config->{lazyload} = 0;
  42
  43 #    if (!$self->config->{lazyload}) {
  44 #        return $self->load_user($authinfo, $c);
  45 #    } else {
  46 #        ## what do we do with a lazyload?
  47 #        ## presumably this is coming out of session storage.
  48 #        ## use $authinfo to fill in the user in that case?
  49 #    }
  50
  51     return $self;
  52 }
  53
  54
  55 sub load {
  56     my ($self, $authinfo, $c) = @_;
  57
  58     my $dbix_class_config = 0;
  59
  60     if (exists($authinfo->{'dbix_class'})) {
  61         $authinfo = $authinfo->{'dbix_class'};
  62         $dbix_class_config = 1;
  63     }
  64
  65     ## User can provide an arrayref containing the arguments to search on the user class.
  66     ## or even provide a prepared resultset, allowing maximum flexibility for user retreival.
  67     ## these options are only available when using the dbix_class authinfo hash.
  68     if ($dbix_class_config && exists($authinfo->{'resultset'})) {
  69         $self->_user($authinfo->{'resultset'}->first);
  70     } elsif ($dbix_class_config && exists($authinfo->{'searchargs'})) {
  71         $self->_user($self->resultset->search(@{$authinfo->{'searchargs'}})->first);
  72     } else {
  73         ## merge the ignore fields array into a hash - so we can do an easy check while building the query
  74         my %ignorefields = map { $_ => 1} @{$self->config->{'ignore_fields_in_find'}};
  75         my $searchargs = {};
  76
  77         # now we walk all the fields passed in, and build up a search hash.
  78         foreach my $key (grep {!$ignorefields{$_}} keys %{$authinfo}) {
  79             if ($self->resultset->result_source->has_column($key)) {
  80                 $searchargs->{$key} = $authinfo->{$key};
  81             }
  82         }
  83         $self->_user($self->resultset->search($searchargs)->first);
  84     }
  85
  86     if ($self->get_object) {
  87         return $self;
  88     } else {
  89         return undef;
  90     }
  91     #$c->log->debug(dumper($self->{'user'}));
  92
  93 }
  94
  95 sub supported_features {
  96     my $self = shift;
  97
  98     return {
  99         session         => 1,
 100         roles           => 1,
 101     };
 102 }
 103
 104
 105 sub roles {
 106     my ( $self ) = shift;
 107     ## this used to load @wantedroles - but that doesn't seem to be used by the roles plugin, so I dropped it.
 108
 109     ## shortcut if we have already retrieved them
 110     if (ref $self->_roles eq 'ARRAY') {
 111         return(@{$self->_roles});
 112     }
 113
 114     my @roles = ();
 115     if (exists($self->config->{'role_column'})) {
 116         my $role_data = $self->get($self->config->{'role_column'});
 117         if ($role_data) {
 118             @roles = split /[ ,\|]+/, $self->get($self->config->{'role_column'});
 119         }
 120         $self->_roles(\@roles);
 121     } elsif (exists($self->config->{'role_relation'})) {
 122         my $relation = $self->config->{'role_relation'};
 123         if ($self->_user->$relation->result_source->has_column($self->config->{'role_field'})) {
 124             @roles = map { $_->get_column($self->config->{'role_field'}) } $self->_user->$relation->search(undef, { columns => [ $self->config->{'role_field'}]})->all();
 125             $self->_roles(\@roles);
 126         } else {
 127             Catalyst::Exception->throw("role table does not have a column called " . $self->config->{'role_field'});
 128         }
 129     } else {
 130         Catalyst::Exception->throw("user->roles accessed, but no role configuration found");
 131     }
 132
 133     return @{$self->_roles};
 134 }
 135
 136 sub for_session {
 137     my $self = shift;
 138
 139     #return $self->get($self->config->{'id_field'});
 140     my %userdata = $self->_user->get_columns();
 141     return \%userdata;
 142 }
 143
 144 sub from_session {
 145     my ($self, $frozenuser, $c) = @_;
 146
 147     ## if use_userdata_from_session is defined in the config, we fill in the user data from the session.
 148     if (exists($self->config->{'use_userdata_from_session'}) && $self->config->{'use_userdata_from_session'} != 0) {
 149         my $obj = $self->resultset->new_result({ %$frozenuser });
 150         $obj->in_storage(1);
 151         $self->_user($obj);
 152         return $self;
 153     } else {
 154         return $self->load( { $self->config->{'id_field'} => $frozenuser->{$self->config->{'id_field'}} }, $c);
 155     }
 156 }
 157
 158 sub get {
 159     my ($self, $field) = @_;
 160
 161     if ($self->_user->can($field)) {
 162         return $self->_user->$field;
 163     } else {
 164         return undef;
 165     }
 166 }
 167
 168 sub get_object {
 169     my ($self, $force) = @_;
 170
 171     if ($force) {
 172         $self->_user->discard_changes;
 173     }
 174
 175     return $self->_user;
 176 }
 177
 178 sub obj {
 179     my ($self, $force) = @_;
 180
 181     return $self->get_object($force);
 182 }
 183
 184 sub auto_create {
 185     my $self = shift;
 186     $self->_user( $self->resultset->auto_create( @_ ) );
 187     return $self;
 188 }
 189
 190 sub auto_update {
 191     my $self = shift;
 192     $self->_user->auto_update( @_ );
 193 }
 194
 195 sub AUTOLOAD {
 196     my $self = shift;
 197     (my $method) = (our $AUTOLOAD =~ /([^:]+)$/);
 198     return if $method eq "DESTROY";
 199
 200     $self->_user->$method(@_);
 201 }
 202
 203 1;
 204 __END__
 205
 206 =head1 NAME
 207
 208 Catalyst::Authentication::Store::DBIx::Class::User - The backing user
 209 class for the Catalyst::Authentication::Store::DBIx::Class storage
 210 module.
 211
 212 =head1 VERSION
 213
 214 This documentation refers to version 0.10.
 215
 216 =head1 SYNOPSIS
 217
 218 Internal - not used directly, please see
 219 L<Catalyst::Authentication::Store::DBIx::Class> for details on how to
 220 use this module. If you need more information than is present there, read the
 221 source.
 222
 223
 224
 225 =head1 DESCRIPTION
 226
 227 The Catalyst::Authentication::Store::DBIx::Class::User class implements user storage
 228 connected to an underlying DBIx::Class schema object.
 229
 230 =head1 SUBROUTINES / METHODS
 231
 232 =head2 new
 233
 234 Constructor.
 235
 236 =head2 load ( $authinfo, $c )
 237
 238 Retrieves a user from storage using the information provided in $authinfo.
 239
 240 =head2 supported_features
 241
 242 Indicates the features supported by this class.  These are currently Roles and Session.
 243
 244 =head2 roles
 245
 246 Returns an array of roles associated with this user, if roles are configured for this user class.
 247
 248 =head2 for_session
 249
 250 Returns a serialized user for storage in the session.  Currently, this is the value of the field
 251 specified by the 'id_field' config variable.
 252
 253 =head2 from_session
 254
 255 Revives a serialized user from storage in the session.  Currently, this uses the serialized data as the
 256 value of the 'id_field' config variable.
 257
 258 =head2 get ( $fieldname )
 259
 260 Returns the value of $fieldname for the user in question.  Roughly translates to a call to
 261 the DBIx::Class::Row's get_column( $fieldname ) routine.
 262
 263 =head2 get_object
 264
 265 Retrieves the DBIx::Class object that corresponds to this user
 266
 267 =head2 obj (method)
 268
 269 Synonym for get_object
 270
 271 =head2 auto_create
 272
 273 This is called when the auto_create_user option is turned on in
 274 Catalyst::Plugin::Authentication and a user matching the authinfo provided is not found.
 275 By default, this will call the C<auto_create()> method of the resultset associated
 276 with this object. It is up to you to implement that method.
 277
 278 =head2 auto_update
 279
 280 This is called when the auto_update_user option is turned on in
 281 Catalyst::Plugin::Authentication. Note that by default the DBIx::Class store
 282 uses every field in the authinfo hash to match the user. This means any
 283 information you provide with the intent to update must be ignored during the
 284 user search process. Otherwise the information will most likely cause the user
 285 record to not be found. To ignore fields in the search process, you
 286 have to add the fields you wish to update to the 'ignore_fields_in_find'
 287 authinfo element.  Alternately, you can use one of the advanced row retrieval
 288 methods (searchargs or resultset).
 289
 290 By default, auto_update will call the C<auto_update()> method of the
 291 DBIx::Class::Row object associated with the user. It is up to you to implement
 292 that method (probably in your schema file)
 293
 294 =head1 BUGS AND LIMITATIONS
 295
 296 None known currently, please email the author if you find any.
 297
 298 =head1 AUTHOR
 299
 300 Jason Kuri (jayk@cpan.org)
 301
 302 =head1 LICENSE
 303
 304 Copyright (c) 2007 the aforementioned authors. All rights
 305 reserved. This program is free software; you can redistribute
 306 it and/or modify it under the same terms as Perl itself.
 307
 308 =cut