lib/Catalyst/Authentication/Store/DBIx/Class/User.pm

   1 package Catalyst::Authentication::Store::DBIx::Class::User;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6 use base qw/Catalyst::Authentication::User/;
   7 use base qw/Class::Accessor::Fast/;
   8
   9 BEGIN {
  10     __PACKAGE__->mk_accessors(qw/config resultset _user _roles/);
  11 }
  12
  13 sub new {
  14     my ( $class, $config, $c) = @_;
  15
  16     my $self = {
  17         resultset => $c->model($config->{'user_class'}),
  18         config => $config,
  19         _roles => undef,
  20         _user => undef
  21     };
  22
  23     bless $self, $class;
  24
  25     ## Note to self- add handling of multiple-column primary keys.
  26     if (!exists($self->config->{'id_field'})) {
  27         my @pks = $self->{'resultset'}->result_source->primary_columns;
  28         if ($#pks == 0) {
  29             $self->config->{'id_field'} = $pks[0];
  30         } else {
  31             Catalyst::Exception->throw("user table does not contain a single primary key column - please specify 'id_field' in config!");
  32         }
  33     }
  34     if (!$self->{'resultset'}->result_source->has_column($self->config->{'id_field'})) {
  35         Catalyst::Exception->throw("id_field set to " .  $self->config->{'id_field'} . " but user table has no column by that name!");
  36     }
  37
  38     ## if we have lazyloading turned on - we should not query the DB unless something gets read.
  39     ## that's the idea anyway - still have to work out how to manage that - so for now we always force
  40     ## lazyload to off.
  41     $self->config->{lazyload} = 0;
  42
  43 #    if (!$self->config->{lazyload}) {
  44 #        return $self->load_user($authinfo, $c);
  45 #    } else {
  46 #        ## what do we do with a lazyload?
  47 #        ## presumably this is coming out of session storage.
  48 #        ## use $authinfo to fill in the user in that case?
  49 #    }
  50
  51     return $self;
  52 }
  53
  54
  55 sub load {
  56     my ($self, $authinfo, $c) = @_;
  57
  58     my $dbix_class_config = 0;
  59
  60     if (exists($authinfo->{'dbix_class'})) {
  61         $authinfo = $authinfo->{'dbix_class'};
  62         $dbix_class_config = 1;
  63     }
  64
  65     ## User can provide an arrayref containing the arguments to search on the user class.
  66     ## or even provide a prepared resultset, allowing maximum flexibility for user retreival.
  67     ## these options are only available when using the dbix_class authinfo hash.
  68     if ($dbix_class_config && exists($authinfo->{'resultset'})) {
  69         $self->_user($authinfo->{'resultset'}->first);
  70     } elsif ($dbix_class_config && exists($authinfo->{'searchargs'})) {
  71         $self->_user($self->resultset->search(@{$authinfo->{'searchargs'}})->first);
  72     } else {
  73         ## merge the ignore fields array into a hash - so we can do an easy check while building the query
  74         my %ignorefields = map { $_ => 1} @{$self->config->{'ignore_fields_in_find'}};
  75         my $searchargs = {};
  76
  77         # now we walk all the fields passed in, and build up a search hash.
  78         foreach my $key (grep {!$ignorefields{$_}} keys %{$authinfo}) {
  79             if ($self->resultset->result_source->has_column($key)) {
  80                 $searchargs->{$key} = $authinfo->{$key};
  81             }
  82         }
  83         $self->_user($self->resultset->search($searchargs)->first);
  84     }
  85
  86     if ($self->get_object) {
  87         return $self;
  88     } else {
  89         return undef;
  90     }
  91     #$c->log->debug(dumper($self->{'user'}));
  92
  93 }
  94
  95 sub supported_features {
  96     my $self = shift;
  97
  98     return {
  99         session         => 1,
 100         roles           => 1,
 101     };
 102 }
 103
 104
 105 sub roles {
 106     my ( $self ) = shift;
 107     ## this used to load @wantedroles - but that doesn't seem to be used by the roles plugin, so I dropped it.
 108
 109     ## shortcut if we have already retrieved them
 110     if (ref $self->_roles eq 'ARRAY') {
 111         return(@{$self->_roles});
 112     }
 113
 114     my @roles = ();
 115     if (exists($self->config->{'role_column'})) {
 116         my $role_data = $self->get($self->config->{'role_column'});
 117         if ($role_data) {
 118             @roles = split /[ ,\|]+/, $self->get($self->config->{'role_column'});
 119         }
 120         $self->_roles(\@roles);
 121     } elsif (exists($self->config->{'role_relation'})) {
 122         my $relation = $self->config->{'role_relation'};
 123         if ($self->_user->$relation->result_source->has_column($self->config->{'role_field'})) {
 124             @roles = map { $_->get_column($self->config->{'role_field'}) } $self->_user->$relation->search(undef, { columns => [ $self->config->{'role_field'}]})->all();
 125             $self->_roles(\@roles);
 126         } else {
 127             Catalyst::Exception->throw("role table does not have a column called " . $self->config->{'role_field'});
 128         }
 129     } else {
 130         Catalyst::Exception->throw("user->roles accessed, but no role configuration found");
 131     }
 132
 133     return @{$self->_roles};
 134 }
 135
 136 sub for_session {
 137     my $self = shift;
 138
 139     #return $self->get($self->config->{'id_field'});
 140
 141     #my $frozenuser = $self->_user->result_source->schema->freeze( $self->_user );
 142     #return $frozenuser;
 143
 144     my %userdata = $self->_user->get_columns();
 145     return \%userdata;
 146 }
 147
 148 sub from_session {
 149     my ($self, $frozenuser, $c) = @_;
 150
 151     #my $obj = $self->resultset->result_source->schema->thaw( $frozenuser );
 152     #$self->_user($obj);
 153
 154     #if (!exists($self->config->{'use_userdata_from_session'}) || $self->config->{'use_userdata_from_session'} == 0) {
 155 #        $self->_user->discard_changes();
 156 #    }
 157 #
 158 #    return $self;
 159 #
 160 ## if use_userdata_from_session is defined in the config, we fill in the user data from the session.
 161     if (exists($self->config->{'use_userdata_from_session'}) && $self->config->{'use_userdata_from_session'} != 0)
 162     {
 163         my $obj = $self->resultset->new_result({ %$frozenuser });
 164         $obj->in_storage(1);
 165         $self->_user($obj);
 166         return $self;
 167     } else {
 168         my $id;
 169         if (ref($frozenuser) eq 'HASH') {
 170             $id = $frozenuser->{$self->config->{'id_field'}};
 171         } else {
 172             $id = $frozenuser;
 173         }
 174         return $self->load( { $self->config->{'id_field'} => $id }, $c);
 175     }
 176 }
 177
 178 sub get {
 179     my ($self, $field) = @_;
 180
 181     if ($self->_user->can($field)) {
 182         return $self->_user->$field;
 183     } else {
 184         return undef;
 185     }
 186 }
 187
 188 sub get_object {
 189     my ($self, $force) = @_;
 190
 191     if ($force) {
 192         $self->_user->discard_changes;
 193     }
 194
 195     return $self->_user;
 196 }
 197
 198 sub obj {
 199     my ($self, $force) = @_;
 200
 201     return $self->get_object($force);
 202 }
 203
 204 sub auto_create {
 205     my $self = shift;
 206     $self->_user( $self->resultset->auto_create( @_ ) );
 207     return $self;
 208 }
 209
 210 sub auto_update {
 211     my $self = shift;
 212     $self->_user->auto_update( @_ );
 213 }
 214
 215 sub AUTOLOAD {
 216     my $self = shift;
 217     (my $method) = (our $AUTOLOAD =~ /([^:]+)$/);
 218     return if $method eq "DESTROY";
 219
 220     $self->_user->$method(@_);
 221 }
 222
 223 1;
 224 __END__
 225
 226 =head1 NAME
 227
 228 Catalyst::Authentication::Store::DBIx::Class::User - The backing user
 229 class for the Catalyst::Authentication::Store::DBIx::Class storage
 230 module.
 231
 232 =head1 VERSION
 233
 234 This documentation refers to version 0.10.
 235
 236 =head1 SYNOPSIS
 237
 238 Internal - not used directly, please see
 239 L<Catalyst::Authentication::Store::DBIx::Class> for details on how to
 240 use this module. If you need more information than is present there, read the
 241 source.
 242
 243
 244
 245 =head1 DESCRIPTION
 246
 247 The Catalyst::Authentication::Store::DBIx::Class::User class implements user storage
 248 connected to an underlying DBIx::Class schema object.
 249
 250 =head1 SUBROUTINES / METHODS
 251
 252 =head2 new
 253
 254 Constructor.
 255
 256 =head2 load ( $authinfo, $c )
 257
 258 Retrieves a user from storage using the information provided in $authinfo.
 259
 260 =head2 supported_features
 261
 262 Indicates the features supported by this class.  These are currently Roles and Session.
 263
 264 =head2 roles
 265
 266 Returns an array of roles associated with this user, if roles are configured for this user class.
 267
 268 =head2 for_session
 269
 270 Returns a serialized user for storage in the session.  Currently, this is the value of the field
 271 specified by the 'id_field' config variable.
 272
 273 =head2 from_session
 274
 275 Revives a serialized user from storage in the session.  Currently, this uses the serialized data as the
 276 value of the 'id_field' config variable.
 277
 278 =head2 get ( $fieldname )
 279
 280 Returns the value of $fieldname for the user in question.  Roughly translates to a call to
 281 the DBIx::Class::Row's get_column( $fieldname ) routine.
 282
 283 =head2 get_object
 284
 285 Retrieves the DBIx::Class object that corresponds to this user
 286
 287 =head2 obj (method)
 288
 289 Synonym for get_object
 290
 291 =head2 auto_create
 292
 293 This is called when the auto_create_user option is turned on in
 294 Catalyst::Plugin::Authentication and a user matching the authinfo provided is not found.
 295 By default, this will call the C<auto_create()> method of the resultset associated
 296 with this object. It is up to you to implement that method.
 297
 298 =head2 auto_update
 299
 300 This is called when the auto_update_user option is turned on in
 301 Catalyst::Plugin::Authentication. Note that by default the DBIx::Class store
 302 uses every field in the authinfo hash to match the user. This means any
 303 information you provide with the intent to update must be ignored during the
 304 user search process. Otherwise the information will most likely cause the user
 305 record to not be found. To ignore fields in the search process, you
 306 have to add the fields you wish to update to the 'ignore_fields_in_find'
 307 authinfo element.  Alternately, you can use one of the advanced row retrieval
 308 methods (searchargs or resultset).
 309
 310 By default, auto_update will call the C<auto_update()> method of the
 311 DBIx::Class::Row object associated with the user. It is up to you to implement
 312 that method (probably in your schema file)
 313
 314 =head1 BUGS AND LIMITATIONS
 315
 316 None known currently, please email the author if you find any.
 317
 318 =head1 AUTHOR
 319
 320 Jason Kuri (jayk@cpan.org)
 321
 322 =head1 LICENSE
 323
 324 Copyright (c) 2007 the aforementioned authors. All rights
 325 reserved. This program is free software; you can redistribute
 326 it and/or modify it under the same terms as Perl itself.
 327
 328 =cut