lib/Catalyst/Authentication/Store/DBIx/Class/User.pm

   1 package Catalyst::Authentication::Store::DBIx::Class::User;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5 extends 'Catalyst::Authentication::User';
   6
   7 use List::MoreUtils 'all';
   8 use Try::Tiny;
   9
  10 has 'config'    => (is => 'rw');
  11 has 'resultset' => (is => 'rw');
  12 has '_user'     => (is => 'rw');
  13 has '_roles'    => (is => 'rw');
  14
  15 sub new {
  16     my ( $class, $config, $c) = @_;
  17
  18         $config->{user_model} = $config->{user_class}
  19         unless defined $config->{user_model};
  20
  21     my $self = {
  22         resultset => $c->model($config->{'user_model'}),
  23         config => $config,
  24         _roles => undef,
  25         _user => undef
  26     };
  27
  28     bless $self, $class;
  29
  30     Catalyst::Exception->throw(
  31         "\$c->model('${ \$self->config->{user_model} }') did not return a resultset."
  32           . " Did you set user_model correctly?"
  33     ) unless $self->{resultset};
  34
  35     $self->config->{'id_field'} = [$self->{'resultset'}->result_source->primary_columns]
  36         unless exists $self->config->{'id_field'};
  37
  38     $self->config->{'id_field'} = [$self->config->{'id_field'}]
  39         unless ref $self->config->{'id_field'} eq 'ARRAY';
  40
  41     Catalyst::Exception->throw(
  42         "id_field set to "
  43           . join(q{,} => @{ $self->config->{'id_field'} })
  44           . " but user table has no column by that name!"
  45     ) unless all { $self->{'resultset'}->result_source->has_column($_) } @{ $self->config->{'id_field'} };
  46
  47     ## if we have lazyloading turned on - we should not query the DB unless something gets read.
  48     ## that's the idea anyway - still have to work out how to manage that - so for now we always force
  49     ## lazyload to off.
  50     $self->config->{lazyload} = 0;
  51
  52 #    if (!$self->config->{lazyload}) {
  53 #        return $self->load_user($authinfo, $c);
  54 #    } else {
  55 #        ## what do we do with a lazyload?
  56 #        ## presumably this is coming out of session storage.
  57 #        ## use $authinfo to fill in the user in that case?
  58 #    }
  59
  60     return $self;
  61 }
  62
  63
  64 sub load {
  65     my ($self, $authinfo, $c) = @_;
  66
  67     my $dbix_class_config = 0;
  68
  69     if (exists($authinfo->{'dbix_class'})) {
  70         $authinfo = $authinfo->{'dbix_class'};
  71         $dbix_class_config = 1;
  72     }
  73
  74     ## User can provide an arrayref containing the arguments to search on the user class.
  75     ## or even provide a prepared resultset, allowing maximum flexibility for user retreival.
  76     ## these options are only available when using the dbix_class authinfo hash.
  77     if ($dbix_class_config && exists($authinfo->{'result'})) {
  78         $self->_user($authinfo->{'result'});
  79     } elsif ($dbix_class_config && exists($authinfo->{'resultset'})) {
  80         $self->_user($authinfo->{'resultset'}->first);
  81     } elsif ($dbix_class_config && exists($authinfo->{'searchargs'})) {
  82         $self->_user($self->resultset->search(@{$authinfo->{'searchargs'}})->first);
  83     } else {
  84         ## merge the ignore fields array into a hash - so we can do an easy check while building the query
  85         my %ignorefields = map { $_ => 1} @{$self->config->{'ignore_fields_in_find'}};
  86         my $searchargs = {};
  87
  88         # now we walk all the fields passed in, and build up a search hash.
  89         foreach my $key (grep {!$ignorefields{$_}} keys %{$authinfo}) {
  90             if ($self->resultset->result_source->has_column($key)) {
  91                 $searchargs->{$key} = $authinfo->{$key};
  92             }
  93         }
  94         if (keys %{$searchargs}) {
  95             $self->_user($self->resultset->search($searchargs)->first);
  96         } else {
  97             Catalyst::Exception->throw(
  98                 "Failed to load user data.  You passed [" . join(',', keys %{$authinfo}) . "]"
  99                   . " to authenticate() but your user source (" .  $self->config->{'user_model'} . ")"
 100                   . " only has these columns: [" . join( ",", $self->resultset->result_source->columns ) . "]"
 101                   . "   Check your authenticate() call."
 102             );
 103         }
 104     }
 105
 106     if ($self->get_object) {
 107         return $self;
 108     } else {
 109         return undef;
 110     }
 111
 112 }
 113
 114 sub supported_features {
 115     my $self = shift;
 116
 117     return {
 118         session         => 1,
 119         roles           => 1,
 120     };
 121 }
 122
 123
 124 sub roles {
 125     my ( $self ) = shift;
 126     ## this used to load @wantedroles - but that doesn't seem to be used by the roles plugin, so I dropped it.
 127
 128     ## shortcut if we have already retrieved them
 129     if (ref $self->_roles eq 'ARRAY') {
 130         return(@{$self->_roles});
 131     }
 132
 133     my @roles = ();
 134     if (exists($self->config->{'role_column'})) {
 135         my $role_data = $self->get($self->config->{'role_column'});
 136         if ($role_data) {
 137             @roles = split /[\s,\|]+/, $self->get($self->config->{'role_column'});
 138         }
 139         $self->_roles(\@roles);
 140     } elsif (exists($self->config->{'role_relation'})) {
 141         my $relation = $self->config->{'role_relation'};
 142         if ($self->_user->$relation->result_source->has_column($self->config->{'role_field'})) {
 143             @roles = map {
 144                 $_->get_column($self->config->{role_field})
 145             } $self->_user->$relation->search(undef, {
 146                 columns => [ $self->config->{role_field} ]
 147             })->all;
 148             $self->_roles(\@roles);
 149         } else {
 150             Catalyst::Exception->throw("role table does not have a column called " . $self->config->{'role_field'});
 151         }
 152     } else {
 153         Catalyst::Exception->throw("user->roles accessed, but no role configuration found");
 154     }
 155
 156     return @{$self->_roles};
 157 }
 158
 159 sub for_session {
 160     my $self = shift;
 161
 162     #return $self->get($self->config->{'id_field'});
 163
 164     #my $frozenuser = $self->_user->result_source->schema->freeze( $self->_user );
 165     #return $frozenuser;
 166
 167     my %userdata = $self->_user->get_columns();
 168
 169     # If use_userdata_from_session is set, then store all of the columns of the user obj in the session
 170     if (exists($self->config->{'use_userdata_from_session'}) && $self->config->{'use_userdata_from_session'} != 0) {
 171         return \%userdata;
 172     } else { # Otherwise, we just need the PKs for load() to use.
 173         my %pk_fields = map { ($_ => $userdata{$_}) } @{ $self->config->{id_field} };
 174         return \%pk_fields;
 175     }
 176 }
 177
 178 sub from_session {
 179     my ($self, $frozenuser, $c) = @_;
 180
 181     #my $obj = $self->resultset->result_source->schema->thaw( $frozenuser );
 182     #$self->_user($obj);
 183
 184     #if (!exists($self->config->{'use_userdata_from_session'}) || $self->config->{'use_userdata_from_session'} == 0) {
 185 #        $self->_user->discard_changes();
 186 #    }
 187 #
 188 #    return $self;
 189 #
 190 ## if use_userdata_from_session is defined in the config, we fill in the user data from the session.
 191     if (exists($self->config->{'use_userdata_from_session'}) && $self->config->{'use_userdata_from_session'} != 0) {
 192
 193         # We need to use inflate_result here since we -are- inflating a
 194         # result object from cached data, not creating a fresh one.
 195         # Components such as EncodedColumn wrap new() to ensure that a
 196         # provided password is hashed on the way in, and re-running the
 197         # hash function on data being restored is expensive and incorrect.
 198
 199         my $class = $self->resultset->result_class;
 200         my $source = $self->resultset->result_source;
 201         my $obj = $class->inflate_result($source, { %$frozenuser });
 202
 203         $obj->in_storage(1);
 204         $self->_user($obj);
 205         return $self;
 206     }
 207
 208     if (ref $frozenuser eq 'HASH') {
 209         return $self->load({
 210             map { ($_ => $frozenuser->{$_}) }
 211             @{ $self->config->{id_field} }
 212         }, $c);
 213     }
 214
 215     return $self->load( { $self->config->{'id_field'} => $frozenuser }, $c);
 216 }
 217
 218 sub get {
 219     my ($self, $field) = @_;
 220
 221     if (my $code = $self->_user->can($field)) {
 222         return $self->_user->$code;
 223     }
 224     elsif (my $accessor =
 225          try { $self->_user->result_source->column_info($field)->{accessor} }) {
 226         return $self->_user->$accessor;
 227     } else {
 228         # XXX this should probably throw
 229         return undef;
 230     }
 231 }
 232
 233 sub get_object {
 234     my ($self, $force) = @_;
 235
 236     if ($force) {
 237         $self->_user->discard_changes;
 238     }
 239
 240     return $self->_user;
 241 }
 242
 243 sub obj {
 244     my ($self, $force) = @_;
 245
 246     return $self->get_object($force);
 247 }
 248
 249 sub auto_create {
 250     my $self = shift;
 251     $self->_user( $self->resultset->auto_create( @_ ) );
 252     return $self;
 253 }
 254
 255 sub auto_update {
 256     my $self = shift;
 257     $self->_user->auto_update( @_ );
 258 }
 259
 260 sub can {
 261     my $self = shift;
 262     return $self->SUPER::can(@_) || do {
 263         my ($method) = @_;
 264         if (my $code = $self->_user->can($method)) {
 265             sub { shift->_user->$code(@_) }
 266         } elsif (my $accessor =
 267             try { $self->_user->result_source->column_info($method)->{accessor} }) {
 268             sub { shift->_user->$accessor }
 269         } else {
 270             undef;
 271         }
 272     };
 273 }
 274
 275 sub AUTOLOAD {
 276     my $self = shift;
 277     (my $method) = (our $AUTOLOAD =~ /([^:]+)$/);
 278     return if $method eq "DESTROY";
 279
 280     if (my $code = $self->_user->can($method)) {
 281         return $self->_user->$code(@_);
 282     }
 283     elsif (my $accessor =
 284          try { $self->_user->result_source->column_info($method)->{accessor} }) {
 285         return $self->_user->$accessor(@_);
 286     } else {
 287         # XXX this should also throw
 288         return undef;
 289     }
 290 }
 291
 292 __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 293
 294 1;
 295 __END__
 296
 297 =head1 NAME
 298
 299 Catalyst::Authentication::Store::DBIx::Class::User - The backing user
 300 class for the Catalyst::Authentication::Store::DBIx::Class storage
 301 module.
 302
 303 =head1 VERSION
 304
 305 This documentation refers to version 0.1503.
 306
 307 =head1 SYNOPSIS
 308
 309 Internal - not used directly, please see
 310 L<Catalyst::Authentication::Store::DBIx::Class> for details on how to
 311 use this module. If you need more information than is present there, read the
 312 source.
 313
 314
 315
 316 =head1 DESCRIPTION
 317
 318 The Catalyst::Authentication::Store::DBIx::Class::User class implements user storage
 319 connected to an underlying DBIx::Class schema object.
 320
 321 =head1 SUBROUTINES / METHODS
 322
 323 =head2 new
 324
 325 Constructor.
 326
 327 =head2 load ( $authinfo, $c )
 328
 329 Retrieves a user from storage using the information provided in $authinfo.
 330
 331 =head2 supported_features
 332
 333 Indicates the features supported by this class.  These are currently Roles and Session.
 334
 335 =head2 roles
 336
 337 Returns an array of roles associated with this user, if roles are configured for this user class.
 338
 339 =head2 for_session
 340
 341 Returns a serialized user for storage in the session.
 342
 343 =head2 from_session
 344
 345 Revives a serialized user from storage in the session.
 346
 347 =head2 get ( $fieldname )
 348
 349 Returns the value of $fieldname for the user in question.  Roughly translates to a call to
 350 the DBIx::Class::Row's get_column( $fieldname ) routine.
 351
 352 =head2 get_object
 353
 354 Retrieves the DBIx::Class object that corresponds to this user
 355
 356 =head2 obj (method)
 357
 358 Synonym for get_object
 359
 360 =head2 auto_create
 361
 362 This is called when the auto_create_user option is turned on in
 363 Catalyst::Plugin::Authentication and a user matching the authinfo provided is not found.
 364 By default, this will call the C<auto_create()> method of the resultset associated
 365 with this object. It is up to you to implement that method.
 366
 367 =head2 auto_update
 368
 369 This is called when the auto_update_user option is turned on in
 370 Catalyst::Plugin::Authentication. Note that by default the DBIx::Class store
 371 uses every field in the authinfo hash to match the user. This means any
 372 information you provide with the intent to update must be ignored during the
 373 user search process. Otherwise the information will most likely cause the user
 374 record to not be found. To ignore fields in the search process, you
 375 have to add the fields you wish to update to the 'ignore_fields_in_find'
 376 authinfo element.  Alternately, you can use one of the advanced row retrieval
 377 methods (searchargs or resultset).
 378
 379 By default, auto_update will call the C<auto_update()> method of the
 380 DBIx::Class::Row object associated with the user. It is up to you to implement
 381 that method (probably in your schema file)
 382
 383 =head2 AUTOLOAD
 384
 385 Delegates method calls to the underlieing user row.
 386
 387 =head2 can
 388
 389 Delegates handling of the C<< can >> method to the underlieing user row.
 390
 391 =head1 BUGS AND LIMITATIONS
 392
 393 None known currently, please email the author if you find any.
 394
 395 =head1 AUTHOR
 396
 397 Jason Kuri (jayk@cpan.org)
 398
 399 =head1 CONTRIBUTORS
 400
 401 Matt S Trout (mst) <mst@shadowcat.co.uk>
 402
 403 (fixes wrt can/AUTOLOAD sponsored by L<http://reask.com/>)
 404
 405 =head1 LICENSE
 406
 407 Copyright (c) 2007-2010 the aforementioned authors. All rights
 408 reserved. This program is free software; you can redistribute
 409 it and/or modify it under the same terms as Perl itself.
 410
 411 =cut