lib/Catalyst/Controller/REST.pm

   1 package Catalyst::Controller::REST;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 =head1 NAME
   7
   8 Catalyst::Controller::REST - A RESTful controller
   9
  10 =head1 SYNOPSIS
  11
  12     package Foo::Controller::Bar;
  13     use Moose;
  14     use namespace::autoclean;
  15
  16     BEGIN { extends 'Catalyst::Controller::REST' }
  17
  18     sub thing : Local : ActionClass('REST') { }
  19
  20     # Answer GET requests to "thing"
  21     sub thing_GET {
  22        my ( $self, $c ) = @_;
  23
  24        # Return a 200 OK, with the data in entity
  25        # serialized in the body
  26        $self->status_ok(
  27             $c,
  28             entity => {
  29                 some => 'data',
  30                 foo  => 'is real bar-y',
  31             },
  32        );
  33     }
  34
  35     # Answer PUT requests to "thing"
  36     sub thing_PUT {
  37         my ( $self, $c ) = @_;
  38
  39         $radiohead = $c->req->data->{radiohead};
  40
  41         $self->status_created(
  42             $c,
  43             location => $c->req->uri,
  44             entity => {
  45                 radiohead => $radiohead,
  46             }
  47         );
  48     }
  49
  50 =head1 DESCRIPTION
  51
  52 Catalyst::Controller::REST implements a mechanism for building
  53 RESTful services in Catalyst.  It does this by extending the
  54 normal Catalyst dispatch mechanism to allow for different
  55 subroutines to be called based on the HTTP Method requested,
  56 while also transparently handling all the serialization/deserialization for
  57 you.
  58
  59 This is probably best served by an example.  In the above
  60 controller, we have declared a Local Catalyst action on
  61 "sub thing", and have used the ActionClass('REST').
  62
  63 Below, we have declared "thing_GET" and "thing_PUT".  Any
  64 GET requests to thing will be dispatched to "thing_GET",
  65 while any PUT requests will be dispatched to "thing_PUT".
  66
  67 Any unimplemented HTTP methods will be met with a "405 Method Not Allowed"
  68 response, automatically containing the proper list of available methods.  You
  69 can override this behavior through implementing a custom
  70 C<thing_not_implemented> method.
  71
  72 If you do not provide an OPTIONS handler, we will respond to any OPTIONS
  73 requests with a "200 OK", populating the Allowed header automatically.
  74
  75 Any data included in C<< $c->stash->{'rest'} >> will be serialized for you.
  76 The serialization format will be selected based on the content-type
  77 of the incoming request.  It is probably easier to use the L<STATUS HELPERS>,
  78 which are described below.
  79
  80 "The HTTP POST, PUT, and OPTIONS methods will all automatically
  81 L<deserialize|Catalyst::Action::Deserialize> the contents of
  82 C<< $c->request->body >> into the C<< $c->request->data >> hashref", based on
  83 the request's C<Content-type> header. A list of understood serialization
  84 formats is L<below|/AVAILABLE SERIALIZERS>.
  85
  86 If we do not have (or cannot run) a serializer for a given content-type, a 415
  87 "Unsupported Media Type" error is generated.
  88
  89 To make your Controller RESTful, simply have it
  90
  91   BEGIN { extends 'Catalyst::Controller::REST' }
  92
  93 =head1 CONFIGURATION
  94
  95 See L<Catalyst::Action::Serialize/CONFIGURATION>. Note that the C<serialize>
  96 key has been deprecated.
  97
  98 =head1 SERIALIZATION
  99
 100 Catalyst::Controller::REST will automatically serialize your
 101 responses, and deserialize any POST, PUT or OPTIONS requests. It evaluates
 102 which serializer to use by mapping a content-type to a Serialization module.
 103 We select the content-type based on:
 104
 105 =over
 106
 107 =item B<The Content-Type Header>
 108
 109 If the incoming HTTP Request had a Content-Type header set, we will use it.
 110
 111 =item B<The content-type Query Parameter>
 112
 113 If this is a GET request, you can supply a content-type query parameter.
 114
 115 =item B<Evaluating the Accept Header>
 116
 117 Finally, if the client provided an Accept header, we will evaluate
 118 it and use the best-ranked choice.
 119
 120 =back
 121
 122 =head1 AVAILABLE SERIALIZERS
 123
 124 A given serialization mechanism is only available if you have the underlying
 125 modules installed.  For example, you can't use XML::Simple if it's not already
 126 installed.
 127
 128 In addition, each serializer has its quirks in terms of what sorts of data
 129 structures it will properly handle.  L<Catalyst::Controller::REST> makes
 130 no attempt to save you from yourself in this regard. :)
 131
 132 =over 2
 133
 134 =item * C<text/x-yaml> => C<YAML::Syck>
 135
 136 Returns YAML generated by L<YAML::Syck>.
 137
 138 =item * C<text/html> => C<YAML::HTML>
 139
 140 This uses L<YAML::Syck> and L<URI::Find> to generate YAML with all URLs turned
 141 to hyperlinks.  Only usable for Serialization.
 142
 143 =item * C<application/json> => C<JSON>
 144
 145 Uses L<JSON> to generate JSON output.  It is strongly advised to also have
 146 L<JSON::XS> installed.  The C<text/x-json> content type is supported but is
 147 deprecated and you will receive warnings in your log.
 148
 149 You can also add a hash in your controller config to pass options to the json object.
 150 For instance, to relax permissions when deserializing input, add:
 151   __PACKAGE__->config(
 152     json_options => { relaxed => 1 }
 153   )
 154
 155 =item * C<text/javascript> => C<JSONP>
 156
 157 If a callback=? parameter is passed, this returns javascript in the form of: $callback($serializedJSON);
 158
 159 Note - this is disabled by default as it can be a security risk if you are unaware.
 160
 161 The usual MIME types for this serialization format are: 'text/javascript', 'application/x-javascript',
 162 'application/javascript'.
 163
 164 =item * C<text/x-data-dumper> => C<Data::Serializer>
 165
 166 Uses the L<Data::Serializer> module to generate L<Data::Dumper> output.
 167
 168 =item * C<text/x-data-denter> => C<Data::Serializer>
 169
 170 Uses the L<Data::Serializer> module to generate L<Data::Denter> output.
 171
 172 =item * C<text/x-data-taxi> => C<Data::Serializer>
 173
 174 Uses the L<Data::Serializer> module to generate L<Data::Taxi> output.
 175
 176 =item * C<text/x-config-general> => C<Data::Serializer>
 177
 178 Uses the L<Data::Serializer> module to generate L<Config::General> output.
 179
 180 =item * C<text/x-php-serialization> => C<Data::Serializer>
 181
 182 Uses the L<Data::Serializer> module to generate L<PHP::Serialization> output.
 183
 184 =item * C<text/xml> => C<XML::Simple>
 185
 186 Uses L<XML::Simple> to generate XML output.  This is probably not suitable
 187 for any real heavy XML work. Due to L<XML::Simple>s requirement that the data
 188 you serialize be a HASHREF, we transform outgoing data to be in the form of:
 189
 190   { data => $yourdata }
 191
 192 =item * L<View>
 193
 194 Uses a regular Catalyst view.  For example, if you wanted to have your
 195 C<text/html> and C<text/xml> views rendered by TT, set:
 196
 197   __PACKAGE__->config(
 198       map => {
 199           'text/html' => [ 'View', 'TT' ],
 200           'text/xml'  => [ 'View', 'XML' ],
 201       }
 202   );
 203
 204 Your views should have a C<process> method like this:
 205
 206   sub process {
 207       my ( $self, $c, $stash_key ) = @_;
 208
 209       my $output;
 210       eval {
 211           $output = $self->serialize( $c->stash->{$stash_key} );
 212       };
 213       return $@ if $@;
 214
 215       $c->response->body( $output );
 216       return 1;  # important
 217   }
 218
 219   sub serialize {
 220       my ( $self, $data ) = @_;
 221
 222       my $serialized = ... process $data here ...
 223
 224       return $serialized;
 225   }
 226
 227 =item * Callback
 228
 229 For infinite flexibility, you can provide a callback for the
 230 deserialization/serialization steps.
 231
 232   __PACKAGE__->config(
 233       map => {
 234           'text/xml'  => [ 'Callback', { deserialize => \&parse_xml, serialize => \&render_xml } ],
 235       }
 236   );
 237
 238 The C<deserialize> callback is passed a string that is the body of the
 239 request and is expected to return a scalar value that results from
 240 the deserialization.  The C<serialize> callback is passed the data
 241 structure that needs to be serialized and must return a string suitable
 242 for returning in the HTTP response.  In addition to receiving the scalar
 243 to act on, both callbacks are passed the controller object and the context
 244 (i.e. C<$c>) as the second and third arguments.
 245
 246 =back
 247
 248 By default, L<Catalyst::Controller::REST> will return a
 249 C<415 Unsupported Media Type> response if an attempt to use an unsupported
 250 content-type is made.  You can ensure that something is always returned by
 251 setting the C<default> config option:
 252
 253   __PACKAGE__->config(default => 'text/x-yaml');
 254
 255 would make it always fall back to the serializer plugin defined for
 256 C<text/x-yaml>.
 257
 258 =head1 CUSTOM SERIALIZERS
 259
 260 Implementing new Serialization formats is easy!  Contributions
 261 are most welcome!  If you would like to implement a custom serializer,
 262 you should create two new modules in the L<Catalyst::Action::Serialize>
 263 and L<Catalyst::Action::Deserialize> namespace.  Then assign your new
 264 class to the content-type's you want, and you're done.
 265
 266 See L<Catalyst::Action::Serialize> and L<Catalyst::Action::Deserialize>
 267 for more information.
 268
 269 =head1 STATUS HELPERS
 270
 271 Since so much of REST is in using HTTP, we provide these Status Helpers.
 272 Using them will ensure that you are responding with the proper codes,
 273 headers, and entities.
 274
 275 These helpers try and conform to the HTTP 1.1 Specification.  You can
 276 refer to it at: L<http://www.w3.org/Protocols/rfc2616/rfc2616.txt>.
 277 These routines are all implemented as regular subroutines, and as
 278 such require you pass the current context ($c) as the first argument.
 279
 280 =over
 281
 282 =cut
 283
 284 BEGIN { extends 'Catalyst::Controller' }
 285 use Params::Validate qw(SCALAR OBJECT);
 286
 287 __PACKAGE__->mk_accessors(qw(serialize));
 288
 289 __PACKAGE__->config(
 290     'stash_key' => 'rest',
 291     'map'       => {
 292         'text/xml'           => 'XML::Simple',
 293         'application/json'   => 'JSON',
 294         'text/x-json'        => 'JSON',
 295     },
 296 );
 297
 298 sub begin : ActionClass('Deserialize') { }
 299
 300 sub end : ActionClass('Serialize') { }
 301
 302 =item status_ok
 303
 304 Returns a "200 OK" response.  Takes an "entity" to serialize.
 305
 306 Example:
 307
 308   $self->status_ok(
 309     $c,
 310     entity => {
 311         radiohead => "Is a good band!",
 312     }
 313   );
 314
 315 =cut
 316
 317 sub status_ok {
 318     my $self = shift;
 319     my $c    = shift;
 320     my %p    = Params::Validate::validate( @_, { entity => 1, }, );
 321
 322     $c->response->status(200);
 323     $self->_set_entity( $c, $p{'entity'} );
 324     return 1;
 325 }
 326
 327 =item status_created
 328
 329 Returns a "201 CREATED" response.  Takes an "entity" to serialize,
 330 and a "location" where the created object can be found.
 331
 332 Example:
 333
 334   $self->status_created(
 335     $c,
 336     location => $c->req->uri,
 337     entity => {
 338         radiohead => "Is a good band!",
 339     }
 340   );
 341
 342 In the above example, we use the requested URI as our location.
 343 This is probably what you want for most PUT requests.
 344
 345 =cut
 346
 347 sub status_created {
 348     my $self = shift;
 349     my $c    = shift;
 350     my %p    = Params::Validate::validate(
 351         @_,
 352         {
 353             location => { type     => SCALAR | OBJECT },
 354             entity   => { optional => 1 },
 355         },
 356     );
 357
 358     $c->response->status(201);
 359     $c->response->header( 'Location' => $p{location} );
 360     $self->_set_entity( $c, $p{'entity'} );
 361     return 1;
 362 }
 363
 364 =item status_accepted
 365
 366 Returns a "202 ACCEPTED" response.  Takes an "entity" to serialize.
 367 Also takes optional "location" for queue type scenarios.
 368
 369 Example:
 370
 371   $self->status_accepted(
 372     $c,
 373     location => $c->req->uri,
 374     entity => {
 375         status => "queued",
 376     }
 377   );
 378
 379 =cut
 380
 381 sub status_accepted {
 382     my $self = shift;
 383     my $c    = shift;
 384     my %p    = Params::Validate::validate(
 385         @_,
 386         {
 387             location => { type => SCALAR | OBJECT, optional => 1 },
 388             entity   => 1,
 389         },
 390     );
 391
 392     $c->response->status(202);
 393     $c->response->header( 'Location' => $p{location} ) if exists $p{location};
 394     $self->_set_entity( $c, $p{'entity'} );
 395     return 1;
 396 }
 397
 398 =item status_no_content
 399
 400 Returns a "204 NO CONTENT" response.
 401
 402 =cut
 403
 404 sub status_no_content {
 405     my $self = shift;
 406     my $c    = shift;
 407     $c->response->status(204);
 408     $self->_set_entity( $c, undef );
 409     return 1;
 410 }
 411
 412 =item status_multiple_choices
 413
 414 Returns a "300 MULTIPLE CHOICES" response. Takes an "entity" to serialize, which should
 415 provide list of possible locations. Also takes optional "location" for preferred choice.
 416
 417 =cut
 418
 419 sub status_multiple_choices {
 420     my $self = shift;
 421     my $c    = shift;
 422     my %p    = Params::Validate::validate(
 423         @_,
 424         {
 425             entity => 1,
 426             location => { type     => SCALAR | OBJECT, optional => 1 },
 427         },
 428     );
 429
 430     $c->response->status(300);
 431     $c->response->header( 'Location' => $p{location} ) if exists $p{'location'};
 432     $self->_set_entity( $c, $p{'entity'} );
 433     return 1;
 434 }
 435
 436 =item status_found
 437
 438 Returns a "302 FOUND" response. Takes an "entity" to serialize.
 439 Also takes optional "location".
 440
 441 =cut
 442
 443 sub status_found {
 444     my $self = shift;
 445     my $c    = shift;
 446     my %p    = Params::Validate::validate(
 447         @_,
 448         {
 449             entity => 1,
 450             location => { type     => SCALAR | OBJECT, optional => 1 },
 451         },
 452     );
 453
 454     $c->response->status(302);
 455     $c->response->header( 'Location' => $p{location} ) if exists $p{'location'};
 456     $self->_set_entity( $c, $p{'entity'} );
 457     return 1;
 458 }
 459
 460 =item status_bad_request
 461
 462 Returns a "400 BAD REQUEST" response.  Takes a "message" argument
 463 as a scalar, which will become the value of "error" in the serialized
 464 response.
 465
 466 Example:
 467
 468   $self->status_bad_request(
 469     $c,
 470     message => "Cannot do what you have asked!",
 471   );
 472
 473 =cut
 474
 475 sub status_bad_request {
 476     my $self = shift;
 477     my $c    = shift;
 478     my %p    = Params::Validate::validate( @_, { message => { type => SCALAR }, }, );
 479
 480     $c->response->status(400);
 481     $c->log->debug( "Status Bad Request: " . $p{'message'} ) if $c->debug;
 482     $self->_set_entity( $c, { error => $p{'message'} } );
 483     return 1;
 484 }
 485
 486 =item status_forbidden
 487
 488 Returns a "403 FORBIDDEN" response.  Takes a "message" argument
 489 as a scalar, which will become the value of "error" in the serialized
 490 response.
 491
 492 Example:
 493
 494   $self->status_forbidden(
 495     $c,
 496     message => "access denied",
 497   );
 498
 499 =cut
 500
 501 sub status_forbidden {
 502     my $self = shift;
 503     my $c    = shift;
 504     my %p    = Params::Validate::validate( @_, { message => { type => SCALAR }, }, );
 505
 506     $c->response->status(403);
 507     $c->log->debug( "Status Forbidden: " . $p{'message'} ) if $c->debug;
 508     $self->_set_entity( $c, { error => $p{'message'} } );
 509     return 1;
 510 }
 511
 512 =item status_not_found
 513
 514 Returns a "404 NOT FOUND" response.  Takes a "message" argument
 515 as a scalar, which will become the value of "error" in the serialized
 516 response.
 517
 518 Example:
 519
 520   $self->status_not_found(
 521     $c,
 522     message => "Cannot find what you were looking for!",
 523   );
 524
 525 =cut
 526
 527 sub status_not_found {
 528     my $self = shift;
 529     my $c    = shift;
 530     my %p    = Params::Validate::validate( @_, { message => { type => SCALAR }, }, );
 531
 532     $c->response->status(404);
 533     $c->log->debug( "Status Not Found: " . $p{'message'} ) if $c->debug;
 534     $self->_set_entity( $c, { error => $p{'message'} } );
 535     return 1;
 536 }
 537
 538 =item gone
 539
 540 Returns a "41O GONE" response.  Takes a "message" argument as a scalar,
 541 which will become the value of "error" in the serialized response.
 542
 543 Example:
 544
 545   $self->status_gone(
 546     $c,
 547     message => "The document have been deleted by foo",
 548   );
 549
 550 =cut
 551
 552 sub status_gone {
 553     my $self = shift;
 554     my $c    = shift;
 555     my %p    = Params::Validate::validate( @_, { message => { type => SCALAR }, }, );
 556
 557     $c->response->status(410);
 558     $c->log->debug( "Status Gone " . $p{'message'} ) if $c->debug;
 559     $self->_set_entity( $c, { error => $p{'message'} } );
 560     return 1;
 561 }
 562
 563 =item status_see_other
 564
 565 Returns a "303 See Other" response.  Takes an optional "entity" to serialize,
 566 and a "location" where the client should redirect to.
 567
 568 Example:
 569
 570   $self->status_see_other(
 571     $c,
 572     location => $some_other_url,
 573     entity => {
 574         radiohead => "Is a good band!",
 575     }
 576   );
 577
 578 =cut
 579
 580 sub status_see_other {
 581     my $self = shift;
 582     my $c    = shift;
 583     my %p    = Params::Validate::validate(
 584         @_,
 585         {
 586             location => { type     => SCALAR | OBJECT },
 587             entity   => { optional => 1 },
 588         },
 589     );
 590
 591     $c->response->status(303);
 592     $c->response->header( 'Location' => $p{location} );
 593     $self->_set_entity( $c, $p{'entity'} );
 594     return 1;
 595 }
 596
 597 =item status_moved
 598
 599 Returns a "301 MOVED" response.  Takes an "entity" to serialize, and a
 600 "location" where the created object can be found.
 601
 602 Example:
 603
 604  $self->status_moved(
 605    $c,
 606    location => '/somewhere/else',
 607    entity => {
 608      radiohead => "Is a good band!",
 609    },
 610  );
 611
 612 =cut
 613
 614 sub status_moved {
 615    my $self = shift;
 616    my $c    = shift;
 617    my %p    = Params::Validate::validate(
 618       @_,
 619       {
 620          location => { type     => SCALAR | OBJECT },
 621          entity   => { optional => 1 },
 622       },
 623    );
 624
 625    my $location = ref $p{location}
 626       ? $p{location}->as_string
 627       : $p{location}
 628    ;
 629
 630    $c->response->status(301);
 631    $c->response->header( Location => $location );
 632    $self->_set_entity($c, $p{entity});
 633    return 1;
 634 }
 635
 636 sub _set_entity {
 637     my $self   = shift;
 638     my $c      = shift;
 639     my $entity = shift;
 640     if ( defined($entity) ) {
 641         $c->stash->{ $self->{'stash_key'} } = $entity;
 642     }
 643     return 1;
 644 }
 645
 646 =back
 647
 648 =head1 MANUAL RESPONSES
 649
 650 If you want to construct your responses yourself, all you need to
 651 do is put the object you want serialized in $c->stash->{'rest'}.
 652
 653 =head1 IMPLEMENTATION DETAILS
 654
 655 This Controller ties together L<Catalyst::Action::REST>,
 656 L<Catalyst::Action::Serialize> and L<Catalyst::Action::Deserialize>.  It should be suitable for most applications.  You should be aware that it:
 657
 658 =over 4
 659
 660 =item Configures the Serialization Actions
 661
 662 This class provides a default configuration for Serialization.  It is currently:
 663
 664   __PACKAGE__->config(
 665       'stash_key' => 'rest',
 666       'map'       => {
 667          'text/html'          => 'YAML::HTML',
 668          'text/xml'           => 'XML::Simple',
 669          'text/x-yaml'        => 'YAML',
 670          'application/json'   => 'JSON',
 671          'text/x-json'        => 'JSON',
 672          'text/x-data-dumper' => [ 'Data::Serializer', 'Data::Dumper' ],
 673          'text/x-data-denter' => [ 'Data::Serializer', 'Data::Denter' ],
 674          'text/x-data-taxi'   => [ 'Data::Serializer', 'Data::Taxi'   ],
 675          'application/x-storable'   => [ 'Data::Serializer', 'Storable' ],
 676          'application/x-freezethaw' => [ 'Data::Serializer', 'FreezeThaw' ],
 677          'text/x-config-general'    => [ 'Data::Serializer', 'Config::General' ],
 678          'text/x-php-serialization' => [ 'Data::Serializer', 'PHP::Serialization' ],
 679       },
 680   );
 681
 682 You can read the full set of options for this configuration block in
 683 L<Catalyst::Action::Serialize>.
 684
 685 =item Sets a C<begin> and C<end> method for you
 686
 687 The C<begin> method uses L<Catalyst::Action::Deserialize>.  The C<end>
 688 method uses L<Catalyst::Action::Serialize>.  If you want to override
 689 either behavior, simply implement your own C<begin> and C<end> actions
 690 and forward to another action with the Serialize and/or Deserialize
 691 action classes:
 692
 693   package Foo::Controller::Monkey;
 694   use Moose;
 695   use namespace::autoclean;
 696
 697   BEGIN { extends 'Catalyst::Controller::REST' }
 698
 699   sub begin : Private {
 700     my ($self, $c) = @_;
 701     ... do things before Deserializing ...
 702     $c->forward('deserialize');
 703     ... do things after Deserializing ...
 704   }
 705
 706   sub deserialize : ActionClass('Deserialize') {}
 707
 708   sub end :Private {
 709     my ($self, $c) = @_;
 710     ... do things before Serializing ...
 711     $c->forward('serialize');
 712     ... do things after Serializing ...
 713   }
 714
 715   sub serialize : ActionClass('Serialize') {}
 716
 717 If you need to deserialize multipart requests (i.e. REST data in
 718 one part and file uploads in others) you can do so by using the
 719 L<Catalyst::Action::DeserializeMultiPart> action class.
 720
 721 =back
 722
 723 =head1 A MILD WARNING
 724
 725 I have code in production using L<Catalyst::Controller::REST>.  That said,
 726 it is still under development, and it's possible that things may change
 727 between releases.  I promise to not break things unnecessarily. :)
 728
 729 =head1 SEE ALSO
 730
 731 L<Catalyst::Action::REST>, L<Catalyst::Action::Serialize>,
 732 L<Catalyst::Action::Deserialize>
 733
 734 For help with REST in general:
 735
 736 The HTTP 1.1 Spec is required reading. http://www.w3.org/Protocols/rfc2616/rfc2616.txt
 737
 738 Wikipedia! http://en.wikipedia.org/wiki/Representational_State_Transfer
 739
 740 The REST Wiki: http://rest.blueoxen.net/cgi-bin/wiki.pl?FrontPage
 741
 742 =head1 AUTHORS
 743
 744 See L<Catalyst::Action::REST> for authors.
 745
 746 =head1 LICENSE
 747
 748 You may distribute this code under the same terms as Perl itself.
 749
 750 =cut
 751
 752 __PACKAGE__->meta->make_immutable;
 753
 754 1;