lib/Catalyst/Controller/REST.pm

   1 package Catalyst::Controller::REST;
   2
   3 =head1 NAME
   4
   5 Catalyst::Controller::REST - A RESTful controller
   6
   7 =head1 SYNOPSIS
   8
   9     package Foo::Controller::Bar;
  10
  11     use base 'Catalyst::Controller::REST';
  12
  13     sub thing : Local : ActionClass('REST') { }
  14
  15     # Answer GET requests to "thing"
  16     sub thing_GET {
  17        my ( $self, $c ) = @_;
  18
  19        # Return a 200 OK, with the data in entity
  20        # serialized in the body
  21        $self->status_ok(
  22             $c,
  23             entity => {
  24                 some => 'data',
  25                 foo  => 'is real bar-y',
  26             },
  27        );
  28     }
  29
  30     # Answer PUT requests to "thing"
  31     sub thing_PUT {
  32       .. some action ..
  33     }
  34
  35 =head1 DESCRIPTION
  36
  37 Catalyst::Controller::REST implements a mechanism for building
  38 RESTful services in Catalyst.  It does this by extending the
  39 normal Catalyst dispatch mechanism to allow for different
  40 subroutines to be called based on the HTTP Method requested,
  41 while also transparently handling all the serialization/deserialization for
  42 you.
  43
  44 This is probably best served by an example.  In the above
  45 controller, we have declared a Local Catalyst action on
  46 "sub thing", and have used the ActionClass('REST').
  47
  48 Below, we have declared "thing_GET" and "thing_PUT".  Any
  49 GET requests to thing will be dispatched to "thing_GET",
  50 while any PUT requests will be dispatched to "thing_PUT".
  51
  52 Any unimplemented HTTP methods will be met with a "405 Method Not Allowed"
  53 response, automatically containing the proper list of available methods.  You
  54 can override this behavior through implementing a custom
  55 C<thing_not_implemented> method.
  56
  57 If you do not provide an OPTIONS handler, we will respond to any OPTIONS
  58 requests with a "200 OK", populating the Allowed header automatically.
  59
  60 Any data included in C<< $c->stash->{'rest'} >> will be serialized for you.
  61 The serialization format will be selected based on the content-type
  62 of the incoming request.  It is probably easier to use the L<STATUS HELPERS>,
  63 which are described below.
  64
  65 The HTTP POST, PUT, and OPTIONS methods will all automatically deserialize the
  66 contents of $c->request->body based on the requests content-type header.
  67 A list of understood serialization formats is below.
  68
  69 If we do not have (or cannot run) a serializer for a given content-type, a 415
  70 "Unsupported Media Type" error is generated.
  71
  72 To make your Controller RESTful, simply have it
  73
  74   use base 'Catalyst::Controller::REST';
  75
  76 =head1 SERIALIZATION
  77
  78 Catalyst::Controller::REST will automatically serialize your
  79 responses, and deserialize any POST, PUT or OPTIONS requests. It evaluates
  80 which serializer to use by mapping a content-type to a Serialization module.
  81 We select the content-type based on:
  82
  83 =over 2
  84
  85 =item B<The Content-Type Header>
  86
  87 If the incoming HTTP Request had a Content-Type header set, we will use it.
  88
  89 =item B<The content-type Query Parameter>
  90
  91 If this is a GET request, you can supply a content-type query parameter.
  92
  93 =item B<Evaluating the Accept Header>
  94
  95 Finally, if the client provided an Accept header, we will evaluate
  96 it and use the best-ranked choice.
  97
  98 =back
  99
 100 =head1 AVAILABLE SERIALIZERS
 101
 102 A given serialization mechanism is only available if you have the underlying
 103 modules installed.  For example, you can't use XML::Simple if it's not already
 104 installed.
 105
 106 In addition, each serializer has it's quirks in terms of what sorts of data
 107 structures it will properly handle.  L<Catalyst::Controller::REST> makes
 108 no attempt to svae you from yourself in this regard. :)
 109
 110 =over 2
 111
 112 =item C<text/x-yaml> => C<YAML::Syck>
 113
 114 Returns YAML generated by L<YAML::Syck>.
 115
 116 =item C<text/html> => C<YAML::HTML>
 117
 118 This uses L<YAML::Syck> and L<URI::Find> to generate YAML with all URLs turned
 119 to hyperlinks.  Only useable for Serialization.
 120
 121 =item C<text/x-json> => C<JSON::Syck>
 122
 123 Uses L<JSON::Syck> to generate JSON output
 124
 125 =item C<text/x-data-dumper> => C<Data::Serializer>
 126
 127 Uses the L<Data::Serializer> module to generate L<Data::Dumper> output.
 128
 129 =item C<text/x-data-denter> => C<Data::Serializer>
 130
 131 Uses the L<Data::Serializer> module to generate L<Data::Denter> output.
 132
 133 =item C<text/x-data-taxi> => C<Data::Serializer>
 134
 135 Uses the L<Data::Serializer> module to generate L<Data::Taxi> output.
 136
 137 =item C<application/x-storable> => C<Data::Serializer>
 138
 139 Uses the L<Data::Serializer> module to generate L<Storable> output.
 140
 141 =item C<application/x-freezethaw> => C<Data::Serializer>
 142
 143 Uses the L<Data::Serializer> module to generate L<FreezeThaw> output.
 144
 145 =item C<text/x-config-general> => C<Data::Serializer>
 146
 147 Uses the L<Data::Serializer> module to generate L<Config::General> output.
 148
 149 =item C<text/x-php-serialization> => C<Data::Serializer>
 150
 151 Uses the L<Data::Serializer> module to generate L<PHP::Serialization> output.
 152
 153 =item C<text/xml> => C<XML::Simple>
 154
 155 Uses L<XML::Simple> to generate XML output.  This is probably not suitable
 156 for any real heavy XML work. Due to L<XML::Simple>s requirement that the data
 157 you serialize be a HASHREF, we transform outgoing data to be in the form of:
 158
 159   { data => $yourdata }
 160
 161 =item L<View>
 162
 163 Uses a regular Catalyst view.  For example, if you wanted to have your
 164 C<text/html> and C<text/xml> views rendered by TT:
 165
 166         'text/html' => [ 'View', 'TT' ],
 167         'text/xml'  => [ 'View', 'XML' ],
 168
 169 Will do the trick nicely.
 170
 171 =back
 172
 173 By default, L<Catalyst::Controller::REST> will return a C<415 Unsupported Media Type>
 174 response if an attempt to use an unsupported content-type is made.  You
 175 can ensure that something is always returned by setting the C<default>
 176 config option:
 177
 178    __PACKAGE__->config->{'serialize'}->{'default'} = 'text/x-yaml';
 179
 180 Would make it always fall back to the serializer plugin defined for text/x-yaml.
 181
 182 Implementing new Serialization formats is easy!  Contributions
 183 are most welcome!  See L<Catalyst::Action::Serialize> and
 184 L<Catalyst::Action::Deserialize> for more information.
 185
 186 =head1 CUSTOM SERIALIZERS
 187
 188 If you would like to implement a custom serializer, you should create two new
 189 modules in the L<Catalyst::Action::Serialize> and
 190 L<Catalyst::Action::Deserialize> namespace.  Then assign your new class
 191 to the content-type's you want, and you're done.
 192
 193 =head1 STATUS HELPERS
 194
 195 Since so much of REST is in using HTTP, we provide these Status Helpers.
 196 Using them will ensure that you are responding with the proper codes,
 197 headers, and entities.
 198
 199 These helpers try and conform to the HTTP 1.1 Specification.  You can
 200 refer to it at: L<http://www.w3.org/Protocols/rfc2616/rfc2616.txt>.
 201 These routines are all implemented as regular subroutines, and as
 202 such require you pass the current context ($c) as the first argument.
 203
 204 =over 4
 205
 206 =cut
 207
 208 use strict;
 209 use warnings;
 210 use base 'Catalyst::Controller';
 211 use Params::Validate qw(:all);
 212
 213 __PACKAGE__->mk_accessors(qw(serialize));
 214
 215 __PACKAGE__->config(
 216     serialize => {
 217         'stash_key' => 'rest',
 218         'map'       => {
 219             'text/html'          => 'YAML::HTML',
 220             'text/xml'           => 'XML::Simple',
 221             'text/x-yaml'        => 'YAML',
 222             'text/x-json'        => 'JSON',
 223             'text/x-data-dumper' => [ 'Data::Serializer', 'Data::Dumper' ],
 224             'text/x-data-denter' => [ 'Data::Serializer', 'Data::Denter' ],
 225             'text/x-data-taxi'   => [ 'Data::Serializer', 'Data::Taxi'   ],
 226             'application/x-storable'    => [ 'Data::Serializer', 'Storable'     ],
 227             'application/x-freezethaw'  => [ 'Data::Serializer', 'FreezeThaw'   ],
 228             'text/x-config-general' => [ 'Data::Serializer', 'Config::General' ],
 229             'text/x-php-serialization' => [ 'Data::Serializer', 'PHP::Serialization' ],
 230         },
 231     }
 232 );
 233
 234 sub begin : ActionClass('Deserialize') {
 235 }
 236
 237 sub end : ActionClass('Serialize') {
 238 }
 239
 240 =item status_ok
 241
 242 Returns a "200 OK" response.  Takes an "entity" to serialize.
 243
 244 Example:
 245
 246   $self->status_ok(
 247     $c,
 248     entity => {
 249         radiohead => "Is a good band!",
 250     }
 251   );
 252
 253 =cut
 254
 255 sub status_ok {
 256     my $self = shift;
 257     my $c    = shift;
 258     my %p    = validate( @_, { entity => 1, }, );
 259
 260     $c->response->status(200);
 261     $self->_set_entity( $c, $p{'entity'} );
 262     return 1;
 263 }
 264
 265 =item status_created
 266
 267 Returns a "201 CREATED" response.  Takes an "entity" to serialize,
 268 and a "location" where the created object can be found.
 269
 270 Example:
 271
 272   $self->status_created(
 273     $c,
 274     location => $c->req->uri->as_string,
 275     entity => {
 276         radiohead => "Is a good band!",
 277     }
 278   );
 279
 280 In the above example, we use the requested URI as our location.
 281 This is probably what you want for most PUT requests.
 282
 283 =cut
 284
 285 sub status_created {
 286     my $self = shift;
 287     my $c    = shift;
 288     my %p    = validate(
 289         @_,
 290         {
 291             location => { type     => SCALAR | OBJECT },
 292             entity   => { optional => 1 },
 293         },
 294     );
 295
 296     my $location;
 297     if ( ref( $p{'location'} ) ) {
 298         $location = $p{'location'}->as_string;
 299     } else {
 300         $location = $p{'location'};
 301     }
 302     $c->response->status(201);
 303     $c->response->header( 'Location' => $location );
 304     $self->_set_entity( $c, $p{'entity'} );
 305     return 1;
 306 }
 307
 308 =item status_accepted
 309
 310 Returns a "202 ACCEPTED" response.  Takes an "entity" to serialize.
 311
 312 Example:
 313
 314   $self->status_accepted(
 315     $c,
 316     entity => {
 317         status => "queued",
 318     }
 319   );
 320
 321 =cut
 322
 323 sub status_accepted {
 324     my $self = shift;
 325     my $c    = shift;
 326     my %p    = validate( @_, { entity => 1, }, );
 327
 328     $c->response->status(202);
 329     $self->_set_entity( $c, $p{'entity'} );
 330     return 1;
 331 }
 332
 333 =item status_bad_request
 334
 335 Returns a "400 BAD REQUEST" response.  Takes a "message" argument
 336 as a scalar, which will become the value of "error" in the serialized
 337 response.
 338
 339 Example:
 340
 341   $self->status_bad_request(
 342     $c,
 343     message => "Cannot do what you have asked!",
 344   );
 345
 346 =cut
 347
 348 sub status_bad_request {
 349     my $self = shift;
 350     my $c    = shift;
 351     my %p    = validate( @_, { message => { type => SCALAR }, }, );
 352
 353     $c->response->status(400);
 354     $c->log->debug( "Status Bad Request: " . $p{'message'} );
 355     $self->_set_entity( $c, { error => $p{'message'} } );
 356     return 1;
 357 }
 358
 359 =item status_not_found
 360
 361 Returns a "404 NOT FOUND" response.  Takes a "message" argument
 362 as a scalar, which will become the value of "error" in the serialized
 363 response.
 364
 365 Example:
 366
 367   $self->status_not_found(
 368     $c,
 369     message => "Cannot find what you were looking for!",
 370   );
 371
 372 =cut
 373
 374 sub status_not_found {
 375     my $self = shift;
 376     my $c    = shift;
 377     my %p    = validate( @_, { message => { type => SCALAR }, }, );
 378
 379     $c->response->status(404);
 380     $c->log->debug( "Status Not Found: " . $p{'message'} );
 381     $self->_set_entity( $c, { error => $p{'message'} } );
 382     return 1;
 383 }
 384
 385 sub _set_entity {
 386     my $self   = shift;
 387     my $c      = shift;
 388     my $entity = shift;
 389     if ( defined($entity) ) {
 390         $c->stash->{ $self->config->{'serialize'}->{'stash_key'} } = $entity;
 391     }
 392     return 1;
 393 }
 394
 395 =back
 396
 397 =head1 MANUAL RESPONSES
 398
 399 If you want to construct your responses yourself, all you need to
 400 do is put the object you want serialized in $c->stash->{'rest'}.
 401
 402 =head1 IMPLEMENTATION DETAILS
 403
 404 This Controller ties together L<Catalyst::Action::REST>,
 405 L<Catalyst::Action::Serialize> and L<Catalyst::Action::Deserialize>.  It should be suitable for most applications.  You should be aware that it:
 406
 407 =over 4
 408
 409 =item Configures the Serialization Actions
 410
 411 This class provides a default configuration for Serialization.  It is currently:
 412
 413   __PACKAGE__->config(
 414       serialize => {
 415          'stash_key' => 'rest',
 416          'map'       => {
 417             'text/html'          => 'YAML::HTML',
 418             'text/xml'           => 'XML::Simple',
 419             'text/x-yaml'        => 'YAML',
 420             'text/x-json'        => 'JSON',
 421             'text/x-data-dumper' => [ 'Data::Serializer', 'Data::Dumper' ],
 422             'text/x-data-denter' => [ 'Data::Serializer', 'Data::Denter' ],
 423             'text/x-data-taxi'   => [ 'Data::Serializer', 'Data::Taxi'   ],
 424             'application/x-storable'    => [ 'Data::Serializer', 'Storable'
 425 ],
 426             'application/x-freezethaw'  => [ 'Data::Serializer', 'FreezeThaw'
 427 ],
 428             'text/x-config-general' => [ 'Data::Serializer', 'Config::General' ]
 429 ,
 430             'text/x-php-serialization' => [ 'Data::Serializer', 'PHP::Serialization' ],
 431           },
 432       }
 433   );
 434
 435 You can read the full set of options for this configuration block in
 436 L<Catalyst::Action::Serialize>.
 437
 438 =item Sets a C<begin> and C<end> method for you
 439
 440 The C<begin> method uses L<Catalyst::Action::Deserialize>.  The C<end>
 441 method uses L<Catalyst::Action::Serialize>.  If you want to override
 442 either behavior, simply implement your own C<begin> and C<end> actions
 443 and use NEXT:
 444
 445   my Foo::Controller::Monkey;
 446   use base qw(Catalyst::Controller::REST);
 447
 448   sub begin :Private {
 449     my ($self, $c) = @_;
 450     ... do things before Deserializing ...
 451     $self->NEXT::begin($c);
 452     ... do things after Deserializing ...
 453   }
 454
 455   sub end :Private {
 456     my ($self, $c) = @_;
 457     ... do things before Serializing ...
 458     $self->NEXT::end($c);
 459     ... do things after Serializing ...
 460   }
 461
 462 =head1 A MILD WARNING
 463
 464 I have code in production using L<Catalyst::Controller::REST>.  That said,
 465 it is still under development, and it's possible that things may change
 466 between releases.  I promise to not break things unneccesarily. :)
 467
 468 =head1 SEE ALSO
 469
 470 L<Catalyst::Action::REST>, L<Catalyst::Action::Serialize>,
 471 L<Catalyst::Action::Deserialize>
 472
 473 For help with REST in general:
 474
 475 The HTTP 1.1 Spec is required reading. http://www.w3.org/Protocols/rfc2616/rfc2616.txt
 476
 477 Wikipedia! http://en.wikipedia.org/wiki/Representational_State_Transfer
 478
 479 The REST Wiki: http://rest.blueoxen.net/cgi-bin/wiki.pl?FrontPage
 480
 481 =head1 AUTHOR
 482
 483 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 484
 485 Marchex, Inc. paid me while I developed this module.  (http://www.marchex.com)
 486
 487 =head1 LICENSE
 488
 489 You may distribute this code under the same terms as Perl itself.
 490
 491 =cut
 492
 493 1;