lib/Catalyst/Action/SerializeBase.pm

   1 #
   2 # Catlyst::Action::SerializeBase.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 #
   5 # $Id$
   6
   7 package Catalyst::Action::SerializeBase;
   8
   9 use strict;
  10 use warnings;
  11
  12 use base 'Catalyst::Action';
  13 use Module::Pluggable::Object;
  14 use Catalyst::Request::REST;
  15 use Catalyst::Utils ();
  16
  17 sub new {
  18   my $class  = shift;
  19   my $config = shift;
  20   Catalyst::Request::REST->_insert_self_into(
  21     Catalyst::Utils::class2appclass($config->{class})
  22   );
  23   return $class->SUPER::new($config, @_);
  24 }
  25
  26 __PACKAGE__->mk_accessors(qw(_serialize_plugins _loaded_plugins));
  27
  28 sub _load_content_plugins {
  29     my $self = shift;
  30     my ( $search_path, $controller, $c ) = @_;
  31
  32     unless ( defined( $self->_loaded_plugins ) ) {
  33         $self->_loaded_plugins( {} );
  34     }
  35
  36     # Load the Serialize Classes
  37     unless ( defined( $self->_serialize_plugins ) ) {
  38         my @plugins;
  39         my $mpo =
  40           Module::Pluggable::Object->new( 'search_path' => [$search_path], );
  41         @plugins = $mpo->plugins;
  42         $self->_serialize_plugins( \@plugins );
  43     }
  44
  45     # Finally, we load the class.  If you have a default serializer,
  46     # and we still don't have a content-type that exists in the map,
  47     # we'll use it.
  48     my $sclass = $search_path . "::";
  49     my $sarg;
  50     my $map;
  51
  52     my $config;
  53
  54     if ( exists $controller->{'serialize'} ) {
  55         $c->log->info("Using deprecated configuration for Catalyst::Action::REST!");
  56         $c->log->info("Please see perldoc Catalyst::Action::REST for the update guide");
  57         $config = $controller->{'serialize'};
  58         # if they're using the deprecated config, they may be expecting a
  59         # default mapping too.
  60         $config->{map} ||= $controller->{map};
  61     } else {
  62         $config = $controller;
  63     }
  64     $map = $config->{'map'};
  65
  66     # pick preferred content type
  67     my @accepted_types; # priority order, best first
  68     # give top priority to content type specified by stash, if any
  69     my $content_type_stash_key = $config->{content_type_stash_key};
  70     if ($content_type_stash_key
  71         and my $stashed = $c->stash->{$content_type_stash_key}
  72     ) {
  73         # convert to array if not already a ref
  74         $stashed = [ $stashed ] if not ref $stashed;
  75         push @accepted_types, @$stashed;
  76     }
  77     # then content types requested by caller
  78     push @accepted_types, @{ $c->request->accepted_content_types };
  79     # then the default
  80     push @accepted_types, $config->{'default'} if $config->{'default'};
  81     # pick the best match that we have a serializer mapping for
  82     my ($content_type) = grep { $map->{$_} } @accepted_types;
  83
  84     return $self->_unsupported_media_type($c, $content_type)
  85         if not $content_type;
  86
  87     # carp about old text/x-json
  88     if ($content_type eq 'text/x-json') {
  89         $c->log->info('Using deprecated text/x-json content-type.');
  90         $c->log->info('Use application/json instead!');
  91     }
  92
  93     if ( exists( $map->{$content_type} ) ) {
  94         my $mc;
  95         if ( ref( $map->{$content_type} ) eq "ARRAY" ) {
  96             $mc   = $map->{$content_type}->[0];
  97             $sarg = $map->{$content_type}->[1];
  98         } else {
  99             $mc = $map->{$content_type};
 100         }
 101         # TODO: Handle custom serializers more elegantly.. this is a start,
 102         # but how do we determine which is Serialize and Deserialize?
 103         #if ($mc =~ /^+/) {
 104         #    $sclass = $mc;
 105         #    $sclass =~ s/^+//g;
 106         #} else {
 107         $sclass .= $mc;
 108         #}
 109         if ( !grep( /^$sclass$/, @{ $self->_serialize_plugins } ) ) {
 110             return $self->_unsupported_media_type($c, $content_type);
 111         }
 112     } else {
 113         return $self->_unsupported_media_type($c, $content_type);
 114     }
 115     unless ( exists( $self->_loaded_plugins->{$sclass} ) ) {
 116         my $load_class = $sclass;
 117         $load_class =~ s/::/\//g;
 118         $load_class =~ s/$/.pm/g;
 119         eval { require $load_class; };
 120         if ($@) {
 121             $c->log->error(
 122                 "Error loading $sclass for " . $content_type . ": $!" );
 123             return $self->_unsupported_media_type($c, $content_type);
 124         } else {
 125             $self->_loaded_plugins->{$sclass} = 1;
 126         }
 127     }
 128
 129     if ($search_path eq "Catalyst::Action::Serialize") {
 130         if ($content_type) {
 131             $c->response->header( 'Vary' => 'Content-Type' );
 132         } elsif ($c->request->accept_only) {
 133             $c->response->header( 'Vary' => 'Accept' );
 134         }
 135         $c->response->content_type($content_type);
 136     }
 137
 138     return $sclass, $sarg, $content_type;
 139 }
 140
 141 sub _unsupported_media_type {
 142     my ( $self, $c, $content_type ) = @_;
 143     $c->res->content_type('text/plain');
 144     $c->res->status(415);
 145     if (defined($content_type) && $content_type ne "") {
 146         $c->res->body(
 147             "Content-Type " . $content_type . " is not supported.\r\n" );
 148     } else {
 149         $c->res->body(
 150             "Cannot find a Content-Type supported by your client.\r\n" );
 151     }
 152     return undef;
 153 }
 154
 155 sub _serialize_bad_request {
 156     my ( $self, $c, $content_type, $error ) = @_;
 157     $c->res->content_type('text/plain');
 158     $c->res->status(400);
 159     $c->res->body(
 160         "Content-Type " . $content_type . " had a problem with your request.\r\n***ERROR***\r\n$error" );
 161     return undef;
 162 }
 163
 164 1;
 165
 166 =head1 NAME
 167
 168 B<Catalyst::Action::SerializeBase>
 169
 170 Base class for Catalyst::Action::Serialize and Catlayst::Action::Deserialize.
 171
 172 =head1 DESCRIPTION
 173
 174 This module implements the plugin loading and content-type negotiating
 175 code for L<Catalyst::Action::Serialize> and L<Catalyst::Action::Deserialize>.
 176
 177 =head1 SEE ALSO
 178
 179 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>,
 180 L<Catalyst::Controller::REST>,
 181
 182 =head1 AUTHOR
 183
 184 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway.
 185
 186 Marchex, Inc. paid me while I developed this module.  (http://www.marchex.com)
 187
 188 =head1 LICENSE
 189
 190 You may distribute this code under the same terms as Perl itself.
 191
 192 =cut
 193