lib/Catalyst/Action/SerializeBase.pm

   1 #
   2 # Catlyst::Action::SerializeBase.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 #
   5 # $Id$
   6
   7 package Catalyst::Action::SerializeBase;
   8
   9 use strict;
  10 use warnings;
  11
  12 use base 'Catalyst::Action';
  13 use Module::Pluggable::Object;
  14 use Data::Dump qw(dump);
  15 use Catalyst::Request::REST;
  16
  17 Catalyst->request_class('Catalyst::Request::REST')
  18     unless Catalyst->request_class->isa('Catalyst::Request::REST');
  19
  20 __PACKAGE__->mk_accessors(qw(_serialize_plugins _loaded_plugins));
  21
  22 sub _load_content_plugins {
  23     my $self = shift;
  24     my ( $search_path, $controller, $c ) = @_;
  25
  26     unless ( defined( $self->_loaded_plugins ) ) {
  27         $self->_loaded_plugins( {} );
  28     }
  29
  30     # Load the Serialize Classes
  31     unless ( defined( $self->_serialize_plugins ) ) {
  32         my @plugins;
  33         my $mpo =
  34           Module::Pluggable::Object->new( 'search_path' => [$search_path], );
  35         @plugins = $mpo->plugins;
  36         $self->_serialize_plugins( \@plugins );
  37     }
  38
  39     # Finally, we load the class.  If you have a default serializer,
  40     # and we still don't have a content-type that exists in the map,
  41     # we'll use it.
  42     my $sclass = $search_path . "::";
  43     my $sarg;
  44     my $map;
  45
  46     my $config;
  47
  48     if ( exists $controller->config->{'serialize'} ) {
  49         $c->log->info("Using deprecated configuration for Catalyst::Action::REST!");
  50         $c->log->info("Please see perldoc Catalyst::Action::REST for the update guide");
  51         $config = $controller->config->{'serialize'};
  52     } else {
  53         $config = $controller->config;
  54     }
  55     $map = $config->{'map'};
  56
  57     # pick preferred content type
  58     my @accepted_types; # priority order, best first
  59     # give top priority to content type specified by stash, if any
  60     my $content_type_stash_key = $config->{content_type_stash_key};
  61     if ($content_type_stash_key
  62         and my $stashed = $c->stash->{$content_type_stash_key}
  63     ) {
  64         # convert to array if not already a ref
  65         $stashed = [ $stashed ] if not ref $stashed;
  66         push @accepted_types, @$stashed;
  67     }
  68     # then content types requested by caller
  69     push @accepted_types, @{ $c->request->accepted_content_types };
  70     # then the default
  71     push @accepted_types, $config->{'default'} if $config->{'default'};
  72     # pick the best match that we have a serializer mapping for
  73     my ($content_type) = grep { $map->{$_} } @accepted_types;
  74
  75     return $self->_unsupported_media_type($c, $content_type)
  76         if not $content_type;
  77
  78     # carp about old text/x-json
  79     if ($content_type eq 'text/x-json') {
  80         $c->log->info('Using deprecated text/x-json content-type.');
  81         $c->log->info('Use application/json instead!');
  82     }
  83
  84     if ( exists( $map->{$content_type} ) ) {
  85         my $mc;
  86         if ( ref( $map->{$content_type} ) eq "ARRAY" ) {
  87             $mc   = $map->{$content_type}->[0];
  88             $sarg = $map->{$content_type}->[1];
  89         } else {
  90             $mc = $map->{$content_type};
  91         }
  92         # TODO: Handle custom serializers more elegantly.. this is a start,
  93         # but how do we determine which is Serialize and Deserialize?
  94         #if ($mc =~ /^+/) {
  95         #    $sclass = $mc;
  96         #    $sclass =~ s/^+//g;
  97         #} else {
  98         $sclass .= $mc;
  99         #}
 100         if ( !grep( /^$sclass$/, @{ $self->_serialize_plugins } ) ) {
 101             return $self->_unsupported_media_type($c, $content_type);
 102         }
 103     } else {
 104         return $self->_unsupported_media_type($c, $content_type);
 105     }
 106     unless ( exists( $self->_loaded_plugins->{$sclass} ) ) {
 107         my $load_class = $sclass;
 108         $load_class =~ s/::/\//g;
 109         $load_class =~ s/$/.pm/g;
 110         eval { require $load_class; };
 111         if ($@) {
 112             $c->log->error(
 113                 "Error loading $sclass for " . $content_type . ": $!" );
 114             return $self->_unsupported_media_type($c, $content_type);
 115         } else {
 116             $self->_loaded_plugins->{$sclass} = 1;
 117         }
 118     }
 119
 120     if ($search_path eq "Catalyst::Action::Serialize") {
 121         if ($content_type) {
 122             $c->response->header( 'Vary' => 'Content-Type' );
 123         } elsif ($c->request->accept_only) {
 124             $c->response->header( 'Vary' => 'Accept' );
 125         }
 126         $c->response->content_type($content_type);
 127     }
 128
 129     return $sclass, $sarg, $content_type;
 130 }
 131
 132 sub _unsupported_media_type {
 133     my ( $self, $c, $content_type ) = @_;
 134     $c->res->content_type('text/plain');
 135     $c->res->status(415);
 136     if (defined($content_type) && $content_type ne "") {
 137         $c->res->body(
 138             "Content-Type " . $content_type . " is not supported.\r\n" );
 139     } else {
 140         $c->res->body(
 141             "Cannot find a Content-Type supported by your client.\r\n" );
 142     }
 143     return undef;
 144 }
 145
 146 sub _serialize_bad_request {
 147     my ( $self, $c, $content_type, $error ) = @_;
 148     $c->res->content_type('text/plain');
 149     $c->res->status(400);
 150     $c->res->body(
 151         "Content-Type " . $content_type . " had a problem with your request.\r\n***ERROR***\r\n$error" );
 152     return undef;
 153 }
 154
 155 1;
 156
 157 =head1 NAME
 158
 159 B<Catalyst::Action::SerializeBase>
 160
 161 Base class for Catalyst::Action::Serialize and Catlayst::Action::Deserialize.
 162
 163 =head1 DESCRIPTION
 164
 165 This module implements the plugin loading and content-type negotiating
 166 code for L<Catalyst::Action::Serialize> and L<Catalyst::Action::Deserialize>.
 167
 168 =head1 SEE ALSO
 169
 170 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>,
 171 L<Catalyst::Controller::REST>,
 172
 173 =head1 AUTHOR
 174
 175 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway.
 176
 177 Marchex, Inc. paid me while I developed this module.  (http://www.marchex.com)
 178
 179 =head1 LICENSE
 180
 181 You may distribute this code under the same terms as Perl itself.
 182
 183 =cut
 184