lib/Catalyst/Action/SerializeBase.pm

   1 package Catalyst::Action::SerializeBase;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action';
   7 use Module::Pluggable::Object;
   8 use Catalyst::Request::REST;
   9 use Catalyst::Utils ();
  10
  11 after BUILDARGS => sub {
  12     my $class  = shift;
  13     my $config = shift;
  14     Catalyst::Request::REST->_insert_self_into( $config->{class} );
  15 };
  16
  17 has [qw(_serialize_plugins _loaded_plugins)] => ( is => 'rw' );
  18
  19 sub _load_content_plugins {
  20     my $self = shift;
  21     my ( $search_path, $controller, $c ) = @_;
  22
  23     unless ( defined( $self->_loaded_plugins ) ) {
  24         $self->_loaded_plugins( {} );
  25     }
  26
  27     # Load the Serialize Classes
  28     unless ( defined( $self->_serialize_plugins ) ) {
  29         my @plugins;
  30         my $mpo =
  31           Module::Pluggable::Object->new( 'search_path' => [$search_path], );
  32         @plugins = $mpo->plugins;
  33         $self->_serialize_plugins( \@plugins );
  34     }
  35
  36     # Finally, we load the class.  If you have a default serializer,
  37     # and we still don't have a content-type that exists in the map,
  38     # we'll use it.
  39     my $sclass = $search_path . "::";
  40     my $sarg;
  41     my $map;
  42
  43     my $config;
  44
  45     if ( exists $controller->{'serialize'} ) {
  46         $c->log->info("Catalyst::Action::REST - deprecated use of 'serialize' for configuration.");
  47         $c->log->info("Please see 'CONFIGURATION' in Catalyst::Controller::REST.");
  48         $config = $controller->{'serialize'};
  49         # if they're using the deprecated config, they may be expecting a
  50         # default mapping too.
  51         $config->{map} ||= $controller->{map};
  52     } else {
  53         $config = $controller;
  54     }
  55     $map = $config->{'map'};
  56
  57     # pick preferred content type
  58     my @accepted_types; # priority order, best first
  59     # give top priority to content type specified by stash, if any
  60     my $content_type_stash_key = $config->{content_type_stash_key};
  61     if ($content_type_stash_key
  62         and my $stashed = $c->stash->{$content_type_stash_key}
  63     ) {
  64         # convert to array if not already a ref
  65         $stashed = [ $stashed ] if not ref $stashed;
  66         push @accepted_types, @$stashed;
  67     }
  68     # then content types requested by caller
  69     push @accepted_types, @{ $c->request->accepted_content_types };
  70     # then the default
  71     push @accepted_types, $config->{'default'} if $config->{'default'};
  72     # pick the best match that we have a serializer mapping for
  73     my ($content_type) = grep { $map->{$_} } @accepted_types;
  74
  75     return $self->unsupported_media_type($c, $content_type)
  76         if not $content_type;
  77
  78     # carp about old text/x-json
  79     if ($content_type eq 'text/x-json') {
  80         $c->log->info('Using deprecated text/x-json content-type.');
  81         $c->log->info('Use application/json instead!');
  82     }
  83
  84     if ( exists( $map->{$content_type} ) ) {
  85         my $mc;
  86         if ( ref( $map->{$content_type} ) eq "ARRAY" ) {
  87             $mc   = $map->{$content_type}->[0];
  88             $sarg = $map->{$content_type}->[1];
  89         } else {
  90             $mc = $map->{$content_type};
  91         }
  92         # TODO: Handle custom serializers more elegantly.. this is a start,
  93         # but how do we determine which is Serialize and Deserialize?
  94         #if ($mc =~ /^+/) {
  95         #    $sclass = $mc;
  96         #    $sclass =~ s/^+//g;
  97         #} else {
  98         $sclass .= $mc;
  99         #}
 100         if ( !grep( /^$sclass$/, @{ $self->_serialize_plugins } ) ) {
 101             return $self->unsupported_media_type($c, $content_type);
 102         }
 103     } else {
 104         return $self->unsupported_media_type($c, $content_type);
 105     }
 106     unless ( exists( $self->_loaded_plugins->{$sclass} ) ) {
 107         my $load_class = $sclass;
 108         $load_class =~ s/::/\//g;
 109         $load_class =~ s/$/.pm/g;
 110         eval { require $load_class; };
 111         if ($@) {
 112             $c->log->error(
 113                 "Error loading $sclass for " . $content_type . ": $!" );
 114             return $self->unsupported_media_type($c, $content_type);
 115         } else {
 116             $self->_loaded_plugins->{$sclass} = 1;
 117         }
 118     }
 119
 120     if ($search_path eq "Catalyst::Action::Serialize") {
 121         if ($content_type) {
 122             $c->response->header( 'Vary' => 'Content-Type' );
 123         } elsif ($c->request->accept_only) {
 124             $c->response->header( 'Vary' => 'Accept' );
 125         }
 126         $c->response->content_type($content_type);
 127     }
 128
 129     return $sclass, $sarg, $content_type;
 130 }
 131
 132 sub unsupported_media_type {
 133     my ( $self, $c, $content_type ) = @_;
 134     $c->res->content_type('text/plain');
 135     $c->res->status(415);
 136     if (defined($content_type) && $content_type ne "") {
 137         $c->res->body(
 138             "Content-Type " . $content_type . " is not supported.\r\n" );
 139     } else {
 140         $c->res->body(
 141             "Cannot find a Content-Type supported by your client.\r\n" );
 142     }
 143     return undef;
 144 }
 145
 146 sub serialize_bad_request {
 147     my ( $self, $c, $content_type, $error ) = @_;
 148     $c->res->content_type('text/plain');
 149     $c->res->status(400);
 150     $c->res->body(
 151         "Content-Type " . $content_type . " had a problem with your request.\r\n***ERROR***\r\n$error" );
 152     return undef;
 153 }
 154
 155 __PACKAGE__->meta->make_immutable;
 156
 157 1;
 158
 159 =head1 NAME
 160
 161 Catalyst::Action::SerializeBase - Base class for Catalyst::Action::Serialize and Catlayst::Action::Deserialize.
 162
 163 =head1 DESCRIPTION
 164
 165 This module implements the plugin loading and content-type negotiating
 166 code for L<Catalyst::Action::Serialize> and L<Catalyst::Action::Deserialize>.
 167
 168 =head1 SEE ALSO
 169
 170 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>,
 171 L<Catalyst::Controller::REST>,
 172
 173 =head1 AUTHORS
 174
 175 See L<Catalyst::Action::REST> for authors.
 176
 177 =head1 LICENSE
 178
 179 You may distribute this code under the same terms as Perl itself.
 180
 181 =cut