lib/Catalyst/Action/SerializeBase.pm

   1 package Catalyst::Action::SerializeBase;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action';
   7 use Module::Pluggable::Object;
   8 use Catalyst::Request::REST;
   9 use Catalyst::Utils ();
  10
  11 our $VERSION = '0.90';
  12 $VERSION = eval $VERSION;
  13
  14 after BUILDARGS => sub {
  15     my $class  = shift;
  16     my $config = shift;
  17     Catalyst::Request::REST->_insert_self_into( $config->{class} );
  18 };
  19
  20 has [qw(_serialize_plugins _loaded_plugins)] => ( is => 'rw' );
  21
  22 sub _load_content_plugins {
  23     my $self = shift;
  24     my ( $search_path, $controller, $c ) = @_;
  25
  26     unless ( defined( $self->_loaded_plugins ) ) {
  27         $self->_loaded_plugins( {} );
  28     }
  29
  30     # Load the Serialize Classes
  31     unless ( defined( $self->_serialize_plugins ) ) {
  32         my @plugins;
  33         my $mpo =
  34           Module::Pluggable::Object->new( 'search_path' => [$search_path], );
  35         @plugins = $mpo->plugins;
  36         $self->_serialize_plugins( \@plugins );
  37     }
  38
  39     # Finally, we load the class.  If you have a default serializer,
  40     # and we still don't have a content-type that exists in the map,
  41     # we'll use it.
  42     my $sclass = $search_path . "::";
  43     my $sarg;
  44     my $map;
  45
  46     my $config;
  47
  48     if ( exists $controller->{'serialize'} ) {
  49         $c->log->info("Catalyst::Action::REST - deprecated use of 'serialize' for configuration.");
  50         $c->log->info("Please see 'CONFIGURATION' in Catalyst::Controller::REST.");
  51         $config = $controller->{'serialize'};
  52         # if they're using the deprecated config, they may be expecting a
  53         # default mapping too.
  54         $config->{map} ||= $controller->{map};
  55     } else {
  56         $config = $controller;
  57     }
  58     $map = $config->{'map'};
  59
  60     # pick preferred content type
  61     my @accepted_types; # priority order, best first
  62     # give top priority to content type specified by stash, if any
  63     my $content_type_stash_key = $config->{content_type_stash_key};
  64     if ($content_type_stash_key
  65         and my $stashed = $c->stash->{$content_type_stash_key}
  66     ) {
  67         # convert to array if not already a ref
  68         $stashed = [ $stashed ] if not ref $stashed;
  69         push @accepted_types, @$stashed;
  70     }
  71     # then content types requested by caller
  72     push @accepted_types,
  73         $search_path =~ m{Deserialize}
  74             ?  @{ $c->request->accepted_content_types }
  75             :  @{ $c->request->accepted_response_content_types }
  76             ;
  77
  78     # then the default
  79     push @accepted_types, $config->{'default'} if $config->{'default'};
  80     # pick the best match that we have a serializer mapping for
  81     my ($content_type) = grep { $map->{$_} } @accepted_types;
  82
  83     return $self->_unsupported_media_type($c, $content_type)
  84         if not $content_type;
  85
  86     # carp about old text/x-json
  87     if ($content_type eq 'text/x-json') {
  88         $c->log->info('Using deprecated text/x-json content-type.');
  89         $c->log->info('Use application/json instead!');
  90     }
  91
  92     if ( exists( $map->{$content_type} ) ) {
  93         my $mc;
  94         if ( ref( $map->{$content_type} ) eq "ARRAY" ) {
  95             $mc   = $map->{$content_type}->[0];
  96             $sarg = $map->{$content_type}->[1];
  97         } else {
  98             $mc = $map->{$content_type};
  99         }
 100         # TODO: Handle custom serializers more elegantly.. this is a start,
 101         # but how do we determine which is Serialize and Deserialize?
 102         #if ($mc =~ /^+/) {
 103         #    $sclass = $mc;
 104         #    $sclass =~ s/^+//g;
 105         #} else {
 106         $sclass .= $mc;
 107         #}
 108         if ( !grep( /^$sclass$/, @{ $self->_serialize_plugins } ) ) {
 109             return $self->_unsupported_media_type($c, $content_type);
 110         }
 111     } else {
 112         return $self->_unsupported_media_type($c, $content_type);
 113     }
 114     unless ( exists( $self->_loaded_plugins->{$sclass} ) ) {
 115         my $load_class = $sclass;
 116         $load_class =~ s/::/\//g;
 117         $load_class =~ s/$/.pm/g;
 118         eval { require $load_class; };
 119         if ($@) {
 120             $c->log->error(
 121                 "Error loading $sclass for " . $content_type . ": $!" );
 122             return $self->_unsupported_media_type($c, $content_type);
 123         } else {
 124             $self->_loaded_plugins->{$sclass} = 1;
 125         }
 126     }
 127
 128     if ($search_path eq "Catalyst::Action::Serialize") {
 129         if ($content_type) {
 130             $c->response->header( 'Vary' => 'Content-Type' );
 131         } elsif ($c->request->accept_only) {
 132             $c->response->header( 'Vary' => 'Accept' );
 133         }
 134         $c->response->content_type($content_type);
 135     }
 136
 137     return $sclass, $sarg, $content_type;
 138 }
 139
 140 sub _unsupported_media_type {
 141     my ( $self, $c, $content_type ) = @_;
 142     $c->res->content_type('text/plain');
 143     $c->res->status(415);
 144     if (defined($content_type) && $content_type ne "") {
 145         $c->res->body(
 146             "Content-Type " . $content_type . " is not supported.\r\n" );
 147     } else {
 148         $c->res->body(
 149             "Cannot find a Content-Type supported by your client.\r\n" );
 150     }
 151     return undef;
 152 }
 153
 154 sub _serialize_bad_request {
 155     my ( $self, $c, $content_type, $error ) = @_;
 156     $c->res->content_type('text/plain');
 157     $c->res->status(400);
 158     $c->res->body(
 159         "Content-Type " . $content_type . " had a problem with your request.\r\n***ERROR***\r\n$error" );
 160     return undef;
 161 }
 162
 163 __PACKAGE__->meta->make_immutable;
 164
 165 1;
 166
 167 =head1 NAME
 168
 169 Catalyst::Action::SerializeBase - Base class for Catalyst::Action::Serialize and Catlayst::Action::Deserialize.
 170
 171 =head1 DESCRIPTION
 172
 173 This module implements the plugin loading and content-type negotiating
 174 code for L<Catalyst::Action::Serialize> and L<Catalyst::Action::Deserialize>.
 175
 176 =head1 SEE ALSO
 177
 178 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>,
 179 L<Catalyst::Controller::REST>,
 180
 181 =head1 AUTHORS
 182
 183 See L<Catalyst::Action::REST> for authors.
 184
 185 =head1 LICENSE
 186
 187 You may distribute this code under the same terms as Perl itself.
 188
 189 =cut