lib/Catalyst/Action/Serialize/JSON.pm

   1 package Catalyst::Action::Serialize::JSON;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action';
   7 use JSON::MaybeXS qw(JSON);
   8
   9 has encoder => (
  10    is => 'ro',
  11    lazy_build => 1,
  12 );
  13
  14 sub _build_encoder {
  15    my $self = shift;
  16    return JSON->new->utf8->convert_blessed;
  17 }
  18
  19 sub execute {
  20     my $self = shift;
  21     my ( $controller, $c ) = @_;
  22
  23     if (my $options = $controller->{json_options_encode}) {
  24         foreach my $opt (keys %$options) {
  25             $self->encoder->$opt( $options->{$opt} );
  26         }
  27     }
  28
  29     my $stash_key = (
  30             $controller->{'serialize'} ?
  31                 $controller->{'serialize'}->{'stash_key'} :
  32                 $controller->{'stash_key'}
  33         ) || 'rest';
  34     my $output = $self->serialize( $c->stash->{$stash_key} );
  35     $c->response->output( $output );
  36     return 1;
  37 }
  38
  39 sub serialize {
  40     my $self = shift;
  41     my $data = shift;
  42     $self->encoder->encode( $data );
  43 }
  44
  45 __PACKAGE__->meta->make_immutable;
  46
  47 1;