lib/Catalyst/Action/Serialize.pm

   1 package Catalyst::Action::Serialize;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action::SerializeBase';
   7 use Module::Pluggable::Object;
   8 use MRO::Compat;
   9
  10 sub execute {
  11     my $self = shift;
  12     my ( $controller, $c ) = @_;
  13
  14     $self->maybe::next::method(@_);
  15
  16     return 1 if $c->req->method eq 'HEAD';
  17     return 1 if length( $c->response->body );
  18     return 1 if scalar @{ $c->error };
  19     return 1 if $c->response->status =~ /^(?:204|3\d\d)$/;
  20
  21     my ( $sclass, $sarg, $content_type ) =
  22       $self->_load_content_plugins( "Catalyst::Action::Serialize",
  23         $controller, $c );
  24     unless ( defined($sclass) ) {
  25         if ( defined($content_type) ) {
  26             $c->log->info("Could not find a serializer for $content_type");
  27         } else {
  28             $c->log->info(
  29                 "Could not find a serializer for an empty content-type");
  30         }
  31         return 1;
  32     }
  33     $c->log->debug(
  34         "Serializing with $sclass" . ( $sarg ? " [$sarg]" : '' ) ) if $c->debug;
  35
  36     my $rc;
  37     eval {
  38         if ( defined($sarg) ) {
  39             $rc = $sclass->execute( $controller, $c, $sarg );
  40         } else {
  41             $rc = $sclass->execute( $controller, $c );
  42         }
  43     };
  44     if ($@) {
  45         return $self->_serialize_bad_request( $c, $content_type, $@ );
  46     } elsif (!$rc) {
  47         return $self->_unsupported_media_type( $c, $content_type );
  48     }
  49
  50     return 1;
  51 }
  52
  53 1;
  54
  55 =head1 NAME
  56
  57 Catalyst::Action::Serialize - Serialize Data in a Response
  58
  59 =head1 SYNOPSIS
  60
  61     package Foo::Controller::Bar;
  62
  63     __PACKAGE__->config(
  64         'default'   => 'text/x-yaml',
  65         'stash_key' => 'rest',
  66         'map'       => {
  67             'text/html'          => [ 'View', 'TT', ],
  68             'text/x-yaml'        => 'YAML',
  69             'text/x-data-dumper' => [ 'Data::Serializer', 'Data::Dumper' ],
  70         }
  71     );
  72
  73     sub end :ActionClass('Serialize') {}
  74
  75 =head1 DESCRIPTION
  76
  77 This action will serialize the body of an HTTP Response.  The serializer is
  78 selected by introspecting the HTTP Requests content-type header.
  79
  80 It requires that your Catalyst controller is properly configured to set up the
  81 mapping between Content Type's and Serialization classes.
  82
  83 The specifics of serializing each content-type is implemented as a plugin to
  84 L<Catalyst::Action::Serialize>.
  85
  86 Typically, you would use this ActionClass on your C<end> method.  However,
  87 nothing is stopping you from choosing specific methods to Serialize:
  88
  89   sub foo :Local :ActionClass('Serialize') {
  90      .. populate stash with data ..
  91   }
  92
  93 When you use this module, the request class will be changed to
  94 L<Catalyst::Request::REST>.
  95
  96 =head1 CONFIGURATION
  97
  98 =head2 map
  99
 100 Takes a hashref, mapping Content-Types to a given serializer plugin.
 101
 102 =head2 default
 103
 104 This is the 'fall-back' Content-Type if none of the requested or acceptable
 105 types is found in the L</map>. It must be an entry in the L</map>.
 106
 107 =head2 stash_key
 108
 109 Specifies the key of the stash entry holding the data that is to be serialized.
 110 So if the value is "rest", we will serialize the data under:
 111
 112   $c->stash->{'rest'}
 113
 114 =head2 content_type_stash_key
 115
 116 Specifies the key of the stash entry that optionally holds an overriding
 117 Content-Type. If set, and if the specified stash entry has a valid value,
 118 then it takes priority over the requested content types.
 119
 120 This can be useful if you want to dynamically force a particular content type,
 121 perhaps for debugging.
 122
 123 =head1 HELPFUL PEOPLE
 124
 125 Daisuke Maki pointed out that early versions of this Action did not play
 126 well with others, or generally behave in a way that was very consistent
 127 with the rest of Catalyst.
 128
 129 =head1 SEE ALSO
 130
 131 You likely want to look at L<Catalyst::Controller::REST>, which implements
 132 a sensible set of defaults for doing a REST controller.
 133
 134 L<Catalyst::Action::Deserialize>, L<Catalyst::Action::REST>
 135
 136 =head1 AUTHORS
 137
 138 See L<Catalyst::Action::REST> for authors.
 139
 140 =head1 LICENSE
 141
 142 You may distribute this code under the same terms as Perl itself.
 143
 144 =cut