lib/Catalyst/Action/REST.pm

   1 #
   2 # REST.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 # Created on: 10/12/2006 03:00:32 PM PDT
   5 #
   6 # $Id$
   7
   8 package Catalyst::Action::REST;
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'Catalyst::Action';
  14 use Class::Inspector;
  15 use Catalyst;
  16 use Catalyst::Request::REST;
  17 use Catalyst::Controller::REST;
  18
  19 BEGIN { require 5.008001; }
  20
  21 our $VERSION = '0.73';
  22
  23 sub new {
  24   my $class  = shift;
  25   my $config = shift;
  26   Catalyst::Request::REST->_insert_self_into( $config->{class} );
  27   return $class->SUPER::new($config, @_);
  28 }
  29
  30 =head1 NAME
  31
  32 Catalyst::Action::REST - Automated REST Method Dispatching
  33
  34 =head1 SYNOPSIS
  35
  36     sub foo :Local :ActionClass('REST') {
  37       ... do setup for HTTP method specific handlers ...
  38     }
  39
  40     sub foo_GET {
  41       ... do something for GET requests ...
  42     }
  43
  44     sub foo_PUT {
  45       ... do somethign for PUT requests ...
  46     }
  47
  48 =head1 DESCRIPTION
  49
  50 This Action handles doing automatic method dispatching for REST requests.  It
  51 takes a normal Catalyst action, and changes the dispatch to append an
  52 underscore and method name.
  53
  54 For example, in the synopsis above, calling GET on "/foo" would result in
  55 the foo_GET method being dispatched.
  56
  57 If a method is requested that is not implemented, this action will
  58 return a status 405 (Method Not Found).  It will populate the "Allow" header
  59 with the list of implemented request methods.  You can override this behavior
  60 by implementing a custom 405 handler like so:
  61
  62    sub foo_not_implemented {
  63       ... handle not implemented methods ...
  64    }
  65
  66 If you do not provide an _OPTIONS subroutine, we will automatically respond
  67 with a 200 OK.  The "Allow" header will be populated with the list of
  68 implemented request methods.
  69
  70 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  71 which brings this class together with automatic Serialization of requests
  72 and responses.
  73
  74 When you use this module, the request class will be changed to
  75 L<Catalyst::Request::REST>.
  76
  77 =head1 METHODS
  78
  79 =over 4
  80
  81 =item dispatch
  82
  83 This method overrides the default dispatch mechanism to the re-dispatching
  84 mechanism described above.
  85
  86 =cut
  87
  88 sub dispatch {
  89     my $self = shift;
  90     my $c    = shift;
  91
  92     my $controller = $c->component( $self->class );
  93     my $method     = $self->name . "_" . uc( $c->request->method );
  94
  95     if (my $code = $controller->can($method)) {
  96         $c->execute( $self->class, $self, @{ $c->req->args } ) if $code;
  97         local $self->{reverse} = $self->{reverse} . "_" . uc( $c->request->method );
  98         local $self->{code} = $code;
  99
 100         return $c->execute( $self->class, $self, @{ $c->req->args } );
 101     }
 102     if ($c->request->method eq "OPTIONS") {
 103         local $self->{reverse} = $self->{reverse} . "_" . uc( $c->request->method );
 104         local $self->{code} = sub { $self->can('_return_options')->($self->name, @_) };
 105         return $c->execute( $self->class, $self, @{ $c->req->args } );
 106     }
 107     my $not_implemented_method = $self->name . "_not_implemented";
 108     local $self->{code} = $controller->can($not_implemented_method)
 109         || sub { $self->can('_return_not_implemented')->($self->name, @_); };
 110
 111     local $self->{reverse} = $not_implemented_method;
 112
 113     $c->execute( $self->class, $self, @{ $c->req->args } );
 114 }
 115
 116 my $_get_allowed_methods = sub {
 117     my ( $controller, $c, $name ) = @_;
 118     my $class = ref($controller) ? ref($controller) : $controller;
 119     my $methods    = Class::Inspector->methods($class);
 120     my @allowed;
 121     foreach my $method ( @{$methods} ) {
 122         if ( $method =~ /^$name\_(.+)$/ ) {
 123             push( @allowed, $1 );
 124         }
 125     }
 126     return @allowed;
 127 };
 128
 129 sub _return_options {
 130     my ( $method_name, $controller, $c) = @_;
 131     my @allowed = $controller->$_get_allowed_methods($c, $method_name);
 132     $c->response->content_type('text/plain');
 133     $c->response->status(200);
 134     $c->response->header( 'Allow' => \@allowed );
 135 }
 136
 137 sub _return_not_implemented {
 138     my ( $method_name, $controller, $c ) = @_;
 139
 140     my @allowed = $controller->$_get_allowed_methods($c, $method_name);
 141     $c->response->content_type('text/plain');
 142     $c->response->status(405);
 143     $c->response->header( 'Allow' => \@allowed );
 144     $c->response->body( "Method "
 145           . $c->request->method
 146           . " not implemented for "
 147           . $c->uri_for( $method_name ) );
 148 }
 149
 150 1;
 151
 152 =back
 153
 154 =head1 SEE ALSO
 155
 156 You likely want to look at L<Catalyst::Controller::REST>, which implements
 157 a sensible set of defaults for a controller doing REST.
 158
 159 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 160
 161 =head1 TROUBLESHOOTING
 162
 163 =over 4
 164
 165 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 166
 167 A:  Most likely, you haven't set Content-type equal to "application/json", or one of the
 168 accepted return formats.  You can do this by setting it in your query string thusly:
 169 ?content-type=application%2Fjson (where %2F == / uri escaped).
 170
 171 **NOTE** Apache will refuse %2F unless configured otherise.
 172 Make sure AllowEncodedSlashes On is in your httpd.conf file in order for this to run smoothly.
 173
 174 =cut
 175
 176 =cut
 177
 178
 179
 180
 181 =head1 MAINTAINER
 182
 183 J. Shirley <jshirley@gmail.com>
 184
 185 =head1 CONTRIBUTORS
 186
 187 Christopher Laco
 188
 189 Luke Saunders
 190
 191 John Goulah
 192
 193 Daisuke Maki <daisuke@endeworks.jp>
 194
 195 =head1 AUTHOR
 196
 197 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 198
 199 Marchex, Inc. paid me while I developed this module.  (http://www.marchex.com)
 200
 201 =head1 LICENSE
 202
 203 You may distribute this code under the same terms as Perl itself.
 204
 205 =cut
 206