lib/Catalyst/Action/REST.pm

   1 #
   2 # REST.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 # Created on: 10/12/2006 03:00:32 PM PDT
   5 #
   6 # $Id$
   7
   8 package Catalyst::Action::REST;
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'Catalyst::Action';
  14 use Class::Inspector;
  15 use Catalyst::Request::REST;
  16 use Catalyst::Controller::REST;
  17
  18 BEGIN { require 5.008001; }
  19
  20 our $VERSION = '0.74';
  21
  22 sub new {
  23   my $class  = shift;
  24   my $config = shift;
  25   Catalyst::Request::REST->_insert_self_into( $config->{class} );
  26   return $class->next::method($config, @_);
  27 }
  28
  29 =head1 NAME
  30
  31 Catalyst::Action::REST - Automated REST Method Dispatching
  32
  33 =head1 SYNOPSIS
  34
  35     sub foo :Local :ActionClass('REST') {
  36       ... do setup for HTTP method specific handlers ...
  37     }
  38
  39     sub foo_GET {
  40       ... do something for GET requests ...
  41     }
  42
  43     sub foo_PUT {
  44       ... do somethign for PUT requests ...
  45     }
  46
  47 =head1 DESCRIPTION
  48
  49 This Action handles doing automatic method dispatching for REST requests.  It
  50 takes a normal Catalyst action, and changes the dispatch to append an
  51 underscore and method name.
  52
  53 For example, in the synopsis above, calling GET on "/foo" would result in
  54 the foo_GET method being dispatched.
  55
  56 If a method is requested that is not implemented, this action will
  57 return a status 405 (Method Not Found).  It will populate the "Allow" header
  58 with the list of implemented request methods.  You can override this behavior
  59 by implementing a custom 405 handler like so:
  60
  61    sub foo_not_implemented {
  62       ... handle not implemented methods ...
  63    }
  64
  65 If you do not provide an _OPTIONS subroutine, we will automatically respond
  66 with a 200 OK.  The "Allow" header will be populated with the list of
  67 implemented request methods.
  68
  69 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  70 which brings this class together with automatic Serialization of requests
  71 and responses.
  72
  73 When you use this module, the request class will be changed to
  74 L<Catalyst::Request::REST>.
  75
  76 =head1 METHODS
  77
  78 =over 4
  79
  80 =item dispatch
  81
  82 This method overrides the default dispatch mechanism to the re-dispatching
  83 mechanism described above.
  84
  85 =cut
  86
  87 sub dispatch {
  88     my $self = shift;
  89     my $c    = shift;
  90
  91     my $controller = $c->component( $self->class );
  92     my $rest_method = $self->name . "_" . uc( $c->request->method );
  93
  94     my ($code, $name);
  95
  96     # Common case, for foo_GET etc
  97     if ( my $action = $controller->action_for($rest_method) ) {
  98         return $c->forward( $action,  $c->req->args );
  99      } elsif ($code = $controller->can($rest_method)) {
 100         # Exceute normal action
 101         $c->execute( $self->class, $self, @{ $c->req->args } );
 102         $name = $rest_method;
 103     }
 104
 105     # Generic handling for foo_OPTIONS
 106     if (!$code && $c->request->method eq "OPTIONS") {
 107         $name = $rest_method;
 108         $code = sub { $self->_return_options($self->name, @_) };
 109     }
 110
 111     # Otherwise, not implemented.
 112     if (!$code) {
 113         $name = $self->name . "_not_implemented";
 114         $code = $controller->can($name) # User method
 115             # Generic not implemented
 116             || sub { $self->_return_not_implemented($self->name, @_) };
 117     }
 118
 119     # localise stuff so we can dispatch the action 'as normal, but get
 120     # different stats shown, and different code run.
 121     local $self->{code} = $code;
 122     local $self->{reverse} = $name;
 123
 124     $c->execute( $self->class, $self, @{ $c->req->args } );
 125 }
 126
 127 sub _get_allowed_methods {
 128     my ( $self, $controller, $c, $name ) = @_;
 129     my $class = ref($controller) ? ref($controller) : $controller;
 130     my $methods    = Class::Inspector->methods($class);
 131     my @allowed;
 132     foreach my $method ( @{$methods} ) {
 133         if ( $method =~ /^$name\_(.+)$/ ) {
 134             push( @allowed, $1 );
 135         }
 136     }
 137     return @allowed;
 138 };
 139
 140 sub _return_options {
 141     my ( $self, $method_name, $controller, $c) = @_;
 142     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 143     $c->response->content_type('text/plain');
 144     $c->response->status(200);
 145     $c->response->header( 'Allow' => \@allowed );
 146 }
 147
 148 sub _return_not_implemented {
 149     my ( $self, $method_name, $controller, $c ) = @_;
 150
 151     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 152     $c->response->content_type('text/plain');
 153     $c->response->status(405);
 154     $c->response->header( 'Allow' => \@allowed );
 155     $c->response->body( "Method "
 156           . $c->request->method
 157           . " not implemented for "
 158           . $c->uri_for( $method_name ) );
 159 }
 160
 161 1;
 162
 163 =back
 164
 165 =head1 SEE ALSO
 166
 167 You likely want to look at L<Catalyst::Controller::REST>, which implements
 168 a sensible set of defaults for a controller doing REST.
 169
 170 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 171
 172 =head1 TROUBLESHOOTING
 173
 174 =over 4
 175
 176 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 177
 178 <<<<<<< HEAD:lib/Catalyst/Action/REST.pm
 179 A:  Most likely, you haven't set Content-type equal to "application/json", or one of the
 180 accepted return formats.  You can do this by setting it in your query string thusly:
 181 ?content-type=application%2Fjson (where %2F == / uri escaped).
 182
 183 **NOTE** Apache will refuse %2F unless configured otherise.
 184 Make sure AllowEncodedSlashes On is in your httpd.conf file in order for this to run smoothly.
 185
 186 =cut
 187
 188 =cut
 189
 190 =======
 191 A:  Most likely, you haven't set Content-type equal to "application/json", or
 192 one of the accepted return formats.  You can do this by setting it in your query
 193 accepted return formats.  You can do this by setting it in your query string
 194 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 195 >>>>>>> f04ed654a172628f642bdefe8483c1e6becf9ad1:lib/Catalyst/Action/REST.pm
 196
 197 B<NOTE> Apache will refuse %2F unless configured otherise.
 198 Make sure C<< AllowEncodedSlashes On >> is in your httpd.conf file in orde
 199 for this to run smoothly.
 200
 201 =back
 202
 203 =head1 CONTRIBUTORS
 204
 205 Christopher Laco
 206
 207 Luke Saunders
 208
 209 John Goulah
 210
 211 Daisuke Maki <daisuke@endeworks.jp>
 212
 213 J. Shirley <jshirley@gmail.com>
 214
 215 Hans Dieter Pearcey
 216
 217 Tomas Doran (t0m) <bobtfish@bobtfish.net>
 218
 219 =head1 AUTHOR
 220
 221 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 222
 223 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 224
 225 =head1 LICENSE
 226
 227 You may distribute this code under the same terms as Perl itself.
 228
 229 =cut
 230