lib/Catalyst/Action/REST.pm

   1 #
   2 # REST.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 # Created on: 10/12/2006 03:00:32 PM PDT
   5 #
   6 # $Id$
   7
   8 package Catalyst::Action::REST;
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'Catalyst::Action';
  14 use Class::Inspector;
  15 use Catalyst;
  16 use Catalyst::Request::REST;
  17 use Catalyst::Controller::REST;
  18
  19 BEGIN { require 5.008001; }
  20
  21 our $VERSION = '0.67';
  22
  23 sub new {
  24   my $class  = shift;
  25   my $config = shift;
  26   Catalyst::Request::REST->_insert_self_into($config->{class});
  27   return $class->SUPER::new($config, @_);
  28 }
  29
  30 =head1 NAME
  31
  32 Catalyst::Action::REST - Automated REST Method Dispatching
  33
  34 =head1 SYNOPSIS
  35
  36     sub foo :Local :ActionClass('REST') {
  37       ... do setup for HTTP method specific handlers ...
  38     }
  39
  40     sub foo_GET {
  41       ... do something for GET requests ...
  42     }
  43
  44     sub foo_PUT {
  45       ... do somethign for PUT requests ...
  46     }
  47
  48 =head1 DESCRIPTION
  49
  50 This Action handles doing automatic method dispatching for REST requests.  It
  51 takes a normal Catalyst action, and changes the dispatch to append an
  52 underscore and method name.
  53
  54 For example, in the synopsis above, calling GET on "/foo" would result in
  55 the foo_GET method being dispatched.
  56
  57 If a method is requested that is not implemented, this action will
  58 return a status 405 (Method Not Found).  It will populate the "Allow" header
  59 with the list of implemented request methods.  You can override this behavior
  60 by implementing a custom 405 handler like so:
  61
  62    sub foo_not_implemented {
  63       ... handle not implemented methods ...
  64    }
  65
  66 If you do not provide an _OPTIONS subroutine, we will automatically respond
  67 with a 200 OK.  The "Allow" header will be populated with the list of
  68 implemented request methods.
  69
  70 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  71 which brings this class together with automatic Serialization of requests
  72 and responses.
  73
  74 When you use this module, the request class will be changed to
  75 L<Catalyst::Request::REST>.
  76
  77 =head1 METHODS
  78
  79 =over 4
  80
  81 =item dispatch
  82
  83 This method overrides the default dispatch mechanism to the re-dispatching
  84 mechanism described above.
  85
  86 =cut
  87
  88 sub dispatch {
  89     my $self = shift;
  90     my $c    = shift;
  91
  92     my $controller = $c->component( $self->class );
  93     my $method     = $self->name . "_" . uc( $c->request->method );
  94     if ( $controller->can($method) ) {
  95         $c->execute( $self->class, $self, @{ $c->req->args } );
  96         return $controller->$method( $c, @{ $c->req->args } );
  97     } else {
  98         if ( $c->request->method eq "OPTIONS" ) {
  99             return $self->_return_options($c);
 100         } else {
 101             my $handle_ni = $self->name . "_not_implemented";
 102             if ( $controller->can($handle_ni) ) {
 103                 return $controller->$handle_ni( $c, @{ $c->req->args } );
 104             } else {
 105                 return $self->_return_not_implemented($c);
 106             }
 107         }
 108     }
 109 }
 110
 111 sub _return_options {
 112     my ( $self, $c ) = @_;
 113
 114     my @allowed = $self->_get_allowed_methods($c);
 115     $c->response->content_type('text/plain');
 116     $c->response->status(200);
 117     $c->response->header( 'Allow' => \@allowed );
 118 }
 119
 120 sub _get_allowed_methods {
 121     my ( $self, $c ) = @_;
 122
 123     my $controller = $self->class;
 124     my $methods    = Class::Inspector->methods($controller);
 125     my @allowed;
 126     foreach my $method ( @{$methods} ) {
 127         my $name = $self->name;
 128         if ( $method =~ /^$name\_(.+)$/ ) {
 129             push( @allowed, $1 );
 130         }
 131     }
 132     return @allowed;
 133 }
 134
 135 sub _return_not_implemented {
 136     my ( $self, $c ) = @_;
 137
 138     my @allowed = $self->_get_allowed_methods($c);
 139     $c->response->content_type('text/plain');
 140     $c->response->status(405);
 141     $c->response->header( 'Allow' => \@allowed );
 142     $c->response->body( "Method "
 143           . $c->request->method
 144           . " not implemented for "
 145           . $c->uri_for( $self->reverse ) );
 146 }
 147
 148 1;
 149
 150 =back
 151
 152 =head1 SEE ALSO
 153
 154 You likely want to look at L<Catalyst::Controller::REST>, which implements
 155 a sensible set of defaults for a controller doing REST.
 156
 157 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 158
 159 =head1 TROUBLESHOOTING
 160
 161 =over 4
 162
 163 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 164
 165 A:  Most likely, you haven't set Content-type equal to "application/json", or one of the
 166 accepted return formats.  You can do this by setting it in your query string thusly:
 167 ?content-type=application%2Fjson (where %2F == / uri escaped).
 168
 169 **NOTE** Apache will refuse %2F unless configured otherise.
 170 Make sure AllowEncodedSlashes On is in your httpd.conf file in order for this to run smoothly.
 171
 172 =cut
 173
 174 =cut
 175
 176
 177
 178
 179 =head1 MAINTAINER
 180
 181 J. Shirley <jshirley@gmail.com>
 182
 183 =head1 CONTRIBUTORS
 184
 185 Christopher Laco
 186
 187 Luke Saunders
 188
 189 John Goulah
 190
 191 Daisuke Maki <daisuke@endeworks.jp>
 192
 193 =head1 AUTHOR
 194
 195 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 196
 197 Marchex, Inc. paid me while I developed this module.  (http://www.marchex.com)
 198
 199 =head1 LICENSE
 200
 201 You may distribute this code under the same terms as Perl itself.
 202
 203 =cut
 204