lib/Catalyst/Action/REST.pm

   1 #
   2 # REST.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 # Created on: 10/12/2006 03:00:32 PM PDT
   5 #
   6 # $Id$
   7
   8 package Catalyst::Action::REST;
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'Catalyst::Action';
  14 use Class::Inspector;
  15 use Catalyst;
  16 use Catalyst::Request::REST;
  17 use Catalyst::Controller::REST;
  18
  19 BEGIN { require 5.008001; }
  20
  21 our $VERSION = '0.73';
  22
  23 sub new {
  24   my $class  = shift;
  25   my $config = shift;
  26   Catalyst::Request::REST->_insert_self_into( $config->{class} );
  27   return $class->SUPER::new($config, @_);
  28 }
  29
  30 =head1 NAME
  31
  32 Catalyst::Action::REST - Automated REST Method Dispatching
  33
  34 =head1 SYNOPSIS
  35
  36     sub foo :Local :ActionClass('REST') {
  37       ... do setup for HTTP method specific handlers ...
  38     }
  39
  40     sub foo_GET {
  41       ... do something for GET requests ...
  42     }
  43
  44     sub foo_PUT {
  45       ... do somethign for PUT requests ...
  46     }
  47
  48 =head1 DESCRIPTION
  49
  50 This Action handles doing automatic method dispatching for REST requests.  It
  51 takes a normal Catalyst action, and changes the dispatch to append an
  52 underscore and method name.
  53
  54 For example, in the synopsis above, calling GET on "/foo" would result in
  55 the foo_GET method being dispatched.
  56
  57 If a method is requested that is not implemented, this action will
  58 return a status 405 (Method Not Found).  It will populate the "Allow" header
  59 with the list of implemented request methods.  You can override this behavior
  60 by implementing a custom 405 handler like so:
  61
  62    sub foo_not_implemented {
  63       ... handle not implemented methods ...
  64    }
  65
  66 If you do not provide an _OPTIONS subroutine, we will automatically respond
  67 with a 200 OK.  The "Allow" header will be populated with the list of
  68 implemented request methods.
  69
  70 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  71 which brings this class together with automatic Serialization of requests
  72 and responses.
  73
  74 When you use this module, the request class will be changed to
  75 L<Catalyst::Request::REST>.
  76
  77 =head1 METHODS
  78
  79 =over 4
  80
  81 =item dispatch
  82
  83 This method overrides the default dispatch mechanism to the re-dispatching
  84 mechanism described above.
  85
  86 =cut
  87
  88 sub dispatch {
  89     my $self = shift;
  90     my $c    = shift;
  91
  92     my $controller = $c->component( $self->class );
  93     my $method     = $self->name . "_" . uc( $c->request->method );
  94     if ( my $action = $controller->action_for($method) ) {
  95         return $c->forward( $action,  $c->req->args );
  96     } elsif ( $controller->can($method) ) {
  97         $c->execute( $self->class, $self, @{ $c->req->args } );
  98         return $controller->$method( $c, @{ $c->req->args } );
  99     } else {
 100         if ( $c->request->method eq "OPTIONS" ) {
 101             return $self->_return_options($c);
 102         } else {
 103             my $handle_ni = $self->name . "_not_implemented";
 104             if ( $controller->can($handle_ni) ) {
 105                 return $controller->$handle_ni( $c, @{ $c->req->args } );
 106             } else {
 107                 return $self->_return_not_implemented($c);
 108             }
 109         }
 110     }
 111 }
 112
 113 sub _return_options {
 114     my ( $self, $c ) = @_;
 115
 116     my @allowed = $self->_get_allowed_methods($c);
 117     $c->response->content_type('text/plain');
 118     $c->response->status(200);
 119     $c->response->header( 'Allow' => \@allowed );
 120 }
 121
 122 sub _get_allowed_methods {
 123     my ( $self, $c ) = @_;
 124
 125     my $controller = $self->class;
 126     my $methods    = Class::Inspector->methods($controller);
 127     my @allowed;
 128     foreach my $method ( @{$methods} ) {
 129         my $name = $self->name;
 130         if ( $method =~ /^$name\_(.+)$/ ) {
 131             push( @allowed, $1 );
 132         }
 133     }
 134     return @allowed;
 135 }
 136
 137 sub _return_not_implemented {
 138     my ( $self, $c ) = @_;
 139
 140     my @allowed = $self->_get_allowed_methods($c);
 141     $c->response->content_type('text/plain');
 142     $c->response->status(405);
 143     $c->response->header( 'Allow' => \@allowed );
 144     $c->response->body( "Method "
 145           . $c->request->method
 146           . " not implemented for "
 147           . $c->uri_for( $self->reverse ) );
 148 }
 149
 150 1;
 151
 152 =back
 153
 154 =head1 SEE ALSO
 155
 156 You likely want to look at L<Catalyst::Controller::REST>, which implements
 157 a sensible set of defaults for a controller doing REST.
 158
 159 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 160
 161 =head1 TROUBLESHOOTING
 162
 163 =over 4
 164
 165 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 166
 167 A:  Most likely, you haven't set Content-type equal to "application/json", or one of the
 168 accepted return formats.  You can do this by setting it in your query string thusly:
 169 ?content-type=application%2Fjson (where %2F == / uri escaped).
 170
 171 **NOTE** Apache will refuse %2F unless configured otherise.
 172 Make sure AllowEncodedSlashes On is in your httpd.conf file in order for this to run smoothly.
 173
 174 =cut
 175
 176 =cut
 177
 178
 179
 180
 181 =head1 MAINTAINER
 182
 183 J. Shirley <jshirley@gmail.com>
 184
 185 =head1 CONTRIBUTORS
 186
 187 Christopher Laco
 188
 189 Luke Saunders
 190
 191 John Goulah
 192
 193 Daisuke Maki <daisuke@endeworks.jp>
 194
 195 =head1 AUTHOR
 196
 197 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 198
 199 Marchex, Inc. paid me while I developed this module.  (http://www.marchex.com)
 200
 201 =head1 LICENSE
 202
 203 You may distribute this code under the same terms as Perl itself.
 204
 205 =cut
 206