lib/Catalyst/Action/REST.pm

   1 package Catalyst::Action::REST;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action';
   7 use Class::Inspector;
   8 use Catalyst::Request::REST;
   9 use Catalyst::Controller::REST;
  10
  11 BEGIN { require 5.008001; }
  12
  13 our $VERSION = '0.98';
  14 $VERSION = eval $VERSION;
  15
  16 sub BUILDARGS {
  17     my $class  = shift;
  18     my $config = shift;
  19     Catalyst::Request::REST->_insert_self_into( $config->{class} );
  20     return $class->SUPER::BUILDARGS($config, @_);
  21 }
  22
  23 =head1 NAME
  24
  25 Catalyst::Action::REST - Automated REST Method Dispatching
  26
  27 =head1 SYNOPSIS
  28
  29     sub foo :Local :ActionClass('REST') {
  30       ... do setup for HTTP method specific handlers ...
  31     }
  32
  33     sub foo_GET {
  34       ... do something for GET requests ...
  35     }
  36
  37     # alternatively use an Action
  38     sub foo_PUT : Action {
  39       ... do something for PUT requests ...
  40     }
  41
  42 =head1 DESCRIPTION
  43
  44 This Action handles doing automatic method dispatching for REST requests.  It
  45 takes a normal Catalyst action, and changes the dispatch to append an
  46 underscore and method name.  First it will try dispatching to an action with
  47 the generated name, and failing that it will try to dispatch to a regular
  48 method.
  49
  50 For example, in the synopsis above, calling GET on "/foo" would result in
  51 the foo_GET method being dispatched.
  52
  53 If a method is requested that is not implemented, this action will
  54 return a status 405 (Method Not Found).  It will populate the "Allow" header
  55 with the list of implemented request methods.  You can override this behavior
  56 by implementing a custom 405 handler like so:
  57
  58    sub foo_not_implemented {
  59       ... handle not implemented methods ...
  60    }
  61
  62 If you do not provide an _OPTIONS subroutine, we will automatically respond
  63 with a 200 OK.  The "Allow" header will be populated with the list of
  64 implemented request methods.
  65
  66 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  67 which brings this class together with automatic Serialization of requests
  68 and responses.
  69
  70 When you use this module, it adds the L<Catalyst::TraitFor::Request::REST>
  71 role to your request class.
  72
  73 =head1 METHODS
  74
  75 =over 4
  76
  77 =item dispatch
  78
  79 This method overrides the default dispatch mechanism to the re-dispatching
  80 mechanism described above.
  81
  82 =cut
  83
  84 sub dispatch {
  85     my $self = shift;
  86     my $c    = shift;
  87
  88     my $rest_method = $self->name . "_" . uc( $c->request->method );
  89
  90     return $self->_dispatch_rest_method( $c, $rest_method );
  91 }
  92
  93 sub _dispatch_rest_method {
  94     my $self        = shift;
  95     my $c           = shift;
  96     my $rest_method = shift;
  97
  98     my $controller = $c->component( $self->class );
  99
 100     my ($code, $name);
 101
 102     # Common case, for foo_GET etc
 103     if ( $code = $controller->action_for($rest_method) ) {
 104         $c->execute( $self->class, $self, @{ $c->req->args } ); # Execute normal 'foo' action.
 105         return $c->forward( $code,  $c->req->args ); # Forward to foo_GET if it's an action
 106     }
 107     elsif ($code = $controller->can($rest_method)) {
 108         # Execute normal action
 109         $c->execute( $self->class, $self, @{ $c->req->args } );
 110         $name = $rest_method; # Stash name and code to run 'foo_GET' like an action below.
 111     }
 112
 113     # Generic handling for foo_OPTIONS
 114     if (!$code) {
 115         if ( $c->request->method eq "OPTIONS") {
 116             $name = $rest_method;
 117             $code = sub { $self->_return_options($self->name, @_) };
 118         }
 119         else {
 120             # Otherwise, not implemented.
 121             $name = $self->name . "_not_implemented";
 122             $code = $controller->can($name) # User method
 123                 # Generic not implemented
 124                 || sub { $self->_return_not_implemented($self->name, @_) };
 125         }
 126     }
 127
 128     # localise stuff so we can dispatch the action 'as normal, but get
 129     # different stats shown, and different code run.
 130     local $self->{code} = $code;
 131     local $self->{reverse} = $name;
 132
 133     $c->execute( $self->class, $self, @{ $c->req->args } );
 134 }
 135
 136 sub _get_allowed_methods {
 137     my ( $self, $controller, $c, $name ) = @_;
 138     my $class = ref($controller) ? ref($controller) : $controller;
 139     my $methods = Class::Inspector->methods($class);
 140     return map { /^$name\_(.+)$/ } @$methods;
 141 };
 142
 143 sub _return_options {
 144     my ( $self, $method_name, $controller, $c) = @_;
 145     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 146     $c->response->content_type('text/plain');
 147     $c->response->status(200);
 148     $c->response->header( 'Allow' => \@allowed );
 149 }
 150
 151 sub _return_not_implemented {
 152     my ( $self, $method_name, $controller, $c ) = @_;
 153
 154     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 155     $c->response->content_type('text/plain');
 156     $c->response->status(405);
 157     $c->response->header( 'Allow' => \@allowed );
 158     $c->response->body( "Method "
 159           . $c->request->method
 160           . " not implemented for "
 161           . $c->uri_for( $method_name ) );
 162 }
 163
 164 __PACKAGE__->meta->make_immutable;
 165
 166 1;
 167
 168 =back
 169
 170 =head1 SEE ALSO
 171
 172 You likely want to look at L<Catalyst::Controller::REST>, which implements a
 173 sensible set of defaults for a controller doing REST.
 174
 175 This class automatically adds the L<Catalyst::TraitFor::Request::REST> role to
 176 your request class.  If you're writing a web application which provides RESTful
 177 responses and still needs to accommodate web browsers, you may prefer to use
 178 L<Catalyst::TraitFor::Request::REST::ForBrowsers> instead.
 179
 180 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 181
 182 =head1 TROUBLESHOOTING
 183
 184 =over 4
 185
 186 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 187
 188 A:  Most likely, you haven't set Content-type equal to "application/json", or
 189 one of the accepted return formats.  You can do this by setting it in your query
 190 accepted return formats.  You can do this by setting it in your query string
 191 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 192
 193 B<NOTE> Apache will refuse %2F unless configured otherwise.
 194 Make sure C<AllowEncodedSlashes On> is in your httpd.conf file in order
 195 for this to run smoothly.
 196
 197 =back
 198
 199 =head1 AUTHOR
 200
 201 Adam Jacob E<lt>adam@stalecoffee.orgE<gt>, with lots of help from mst and jrockway
 202
 203 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 204
 205 =head1 CONTRIBUTORS
 206
 207 Tomas Doran (t0m) E<lt>bobtfish@bobtfish.netE<gt>
 208
 209 John Goulah
 210
 211 Christopher Laco
 212
 213 Daisuke Maki E<lt>daisuke@endeworks.jpE<gt>
 214
 215 Hans Dieter Pearcey
 216
 217 Brian Phillips E<lt>bphillips@cpan.orgE<gt>
 218
 219 Dave Rolsky E<lt>autarch@urth.orgE<gt>
 220
 221 Luke Saunders
 222
 223 Arthur Axel "fREW" Schmidt E<lt>frioux@gmail.comE<gt>
 224
 225 J. Shirley E<lt>jshirley@gmail.comE<gt>
 226
 227 Gavin Henry E<lt>ghenry@surevoip.co.ukE<gt>
 228
 229 Gerv http://www.gerv.net/
 230
 231 Colin Newell <colin@opusvl.com>
 232
 233 =head1 COPYRIGHT
 234
 235 Copyright (c) 2006-2012 the above named AUTHOR and CONTRIBUTORS
 236
 237 =head1 LICENSE
 238
 239 You may distribute this code under the same terms as Perl itself.
 240
 241 =cut
 242