lib/Catalyst/Action/REST.pm

   1 #
   2 # REST.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 # Created on: 10/12/2006 03:00:32 PM PDT
   5 #
   6 # $Id$
   7
   8 package Catalyst::Action::REST;
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'Catalyst::Action';
  14 use Class::Inspector;
  15 use Catalyst::Request::REST;
  16 use Catalyst::Controller::REST;
  17
  18 BEGIN { require 5.008001; }
  19
  20 our $VERSION = '0.76';
  21 $VERSION = eval $VERSION;
  22
  23 sub new {
  24   my $class  = shift;
  25   my $config = shift;
  26   Catalyst::Request::REST->_insert_self_into( $config->{class} );
  27   return $class->next::method($config, @_);
  28 }
  29
  30 =head1 NAME
  31
  32 Catalyst::Action::REST - Automated REST Method Dispatching
  33
  34 =head1 SYNOPSIS
  35
  36     sub foo :Local :ActionClass('REST') {
  37       ... do setup for HTTP method specific handlers ...
  38     }
  39
  40     sub foo_GET {
  41       ... do something for GET requests ...
  42     }
  43
  44     sub foo_PUT {
  45       ... do somethign for PUT requests ...
  46     }
  47
  48 =head1 DESCRIPTION
  49
  50 This Action handles doing automatic method dispatching for REST requests.  It
  51 takes a normal Catalyst action, and changes the dispatch to append an
  52 underscore and method name.
  53
  54 For example, in the synopsis above, calling GET on "/foo" would result in
  55 the foo_GET method being dispatched.
  56
  57 If a method is requested that is not implemented, this action will
  58 return a status 405 (Method Not Found).  It will populate the "Allow" header
  59 with the list of implemented request methods.  You can override this behavior
  60 by implementing a custom 405 handler like so:
  61
  62    sub foo_not_implemented {
  63       ... handle not implemented methods ...
  64    }
  65
  66 If you do not provide an _OPTIONS subroutine, we will automatically respond
  67 with a 200 OK.  The "Allow" header will be populated with the list of
  68 implemented request methods.
  69
  70 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  71 which brings this class together with automatic Serialization of requests
  72 and responses.
  73
  74 When you use this module, the request class will be changed to
  75 L<Catalyst::Request::REST>.
  76
  77 =head1 METHODS
  78
  79 =over 4
  80
  81 =item dispatch
  82
  83 This method overrides the default dispatch mechanism to the re-dispatching
  84 mechanism described above.
  85
  86 =cut
  87
  88 sub dispatch {
  89     my $self = shift;
  90     my $c    = shift;
  91
  92     my $controller = $c->component( $self->class );
  93     my $rest_method = $self->name . "_" . uc( $c->request->method );
  94
  95     my ($code, $name);
  96
  97     # Common case, for foo_GET etc
  98     if ( $code = $controller->action_for($rest_method) ) {
  99         $c->execute( $self->class, $self, @{ $c->req->args } );
 100         return $c->forward( $code,  $c->req->args );
 101      } elsif ($code = $controller->can($rest_method)) {
 102         # Exceute normal action
 103         $c->execute( $self->class, $self, @{ $c->req->args } );
 104         $name = $rest_method;
 105     }
 106
 107     # Generic handling for foo_OPTIONS
 108     if (!$code && $c->request->method eq "OPTIONS") {
 109         $name = $rest_method;
 110         $code = sub { $self->_return_options($self->name, @_) };
 111     }
 112
 113     # Otherwise, not implemented.
 114     if (!$code) {
 115         $name = $self->name . "_not_implemented";
 116         $code = $controller->can($name) # User method
 117             # Generic not implemented
 118             || sub { $self->_return_not_implemented($self->name, @_) };
 119     }
 120
 121     # localise stuff so we can dispatch the action 'as normal, but get
 122     # different stats shown, and different code run.
 123     local $self->{code} = $code;
 124     local $self->{reverse} = $name;
 125
 126     $c->execute( $self->class, $self, @{ $c->req->args } );
 127 }
 128
 129 sub _get_allowed_methods {
 130     my ( $self, $controller, $c, $name ) = @_;
 131     my $class = ref($controller) ? ref($controller) : $controller;
 132     my $methods    = Class::Inspector->methods($class);
 133     my @allowed;
 134     foreach my $method ( @{$methods} ) {
 135         if ( $method =~ /^$name\_(.+)$/ ) {
 136             push( @allowed, $1 );
 137         }
 138     }
 139     return @allowed;
 140 };
 141
 142 sub _return_options {
 143     my ( $self, $method_name, $controller, $c) = @_;
 144     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 145     $c->response->content_type('text/plain');
 146     $c->response->status(200);
 147     $c->response->header( 'Allow' => \@allowed );
 148 }
 149
 150 sub _return_not_implemented {
 151     my ( $self, $method_name, $controller, $c ) = @_;
 152
 153     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 154     $c->response->content_type('text/plain');
 155     $c->response->status(405);
 156     $c->response->header( 'Allow' => \@allowed );
 157     $c->response->body( "Method "
 158           . $c->request->method
 159           . " not implemented for "
 160           . $c->uri_for( $method_name ) );
 161 }
 162
 163 1;
 164
 165 =back
 166
 167 =head1 SEE ALSO
 168
 169 You likely want to look at L<Catalyst::Controller::REST>, which implements
 170 a sensible set of defaults for a controller doing REST.
 171
 172 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 173
 174 =head1 TROUBLESHOOTING
 175
 176 =over 4
 177
 178 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 179
 180 A:  Most likely, you haven't set Content-type equal to "application/json", or
 181 one of the accepted return formats.  You can do this by setting it in your query
 182 accepted return formats.  You can do this by setting it in your query string
 183 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 184
 185 B<NOTE> Apache will refuse %2F unless configured otherise.
 186 Make sure C<< AllowEncodedSlashes On >> is in your httpd.conf file in orde
 187 for this to run smoothly.
 188
 189 =back
 190
 191 =head1 CONTRIBUTORS
 192
 193 Christopher Laco
 194
 195 Luke Saunders
 196
 197 John Goulah
 198
 199 Daisuke Maki <daisuke@endeworks.jp>
 200
 201 J. Shirley <jshirley@gmail.com>
 202
 203 Hans Dieter Pearcey
 204
 205 Tomas Doran (t0m) <bobtfish@bobtfish.net>
 206
 207 =head1 AUTHOR
 208
 209 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 210
 211 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 212
 213 =head1 LICENSE
 214
 215 You may distribute this code under the same terms as Perl itself.
 216
 217 =cut
 218