lib/Catalyst/Action/REST.pm

   1 #
   2 # REST.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 # Created on: 10/12/2006 03:00:32 PM PDT
   5 #
   6 # $Id$
   7
   8 package Catalyst::Action::REST;
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'Catalyst::Action';
  14 use Class::Inspector;
  15 use Moose::Util qw(does_role);
  16 use Catalyst;
  17 use Catalyst::RequestRole::REST;
  18 use Catalyst::Controller::REST;
  19 use namespace::clean -except => 'meta';
  20
  21 BEGIN { require 5.008001; }
  22
  23 our $VERSION = '0.71';
  24
  25 =head1 NAME
  26
  27 Catalyst::Action::REST - Automated REST Method Dispatching
  28
  29 =head1 SYNOPSIS
  30
  31     sub foo :Local :ActionClass('REST') {
  32       ... do setup for HTTP method specific handlers ...
  33     }
  34
  35     sub foo_GET {
  36       ... do something for GET requests ...
  37     }
  38
  39     sub foo_PUT {
  40       ... do somethign for PUT requests ...
  41     }
  42
  43 =head1 DESCRIPTION
  44
  45 This Action handles doing automatic method dispatching for REST requests.  It
  46 takes a normal Catalyst action, and changes the dispatch to append an
  47 underscore and method name.
  48
  49 For example, in the synopsis above, calling GET on "/foo" would result in
  50 the foo_GET method being dispatched.
  51
  52 If a method is requested that is not implemented, this action will
  53 return a status 405 (Method Not Found).  It will populate the "Allow" header
  54 with the list of implemented request methods.  You can override this behavior
  55 by implementing a custom 405 handler like so:
  56
  57    sub foo_not_implemented {
  58       ... handle not implemented methods ...
  59    }
  60
  61 If you do not provide an _OPTIONS subroutine, we will automatically respond
  62 with a 200 OK.  The "Allow" header will be populated with the list of
  63 implemented request methods.
  64
  65 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  66 which brings this class together with automatic Serialization of requests
  67 and responses.
  68
  69 When you use this module, the request class will be changed to
  70 L<Catalyst::Request::REST>.
  71
  72 =head1 METHODS
  73
  74 =over 4
  75
  76 =item dispatch
  77
  78 This method overrides the default dispatch mechanism to the re-dispatching
  79 mechanism described above.
  80
  81 =cut
  82
  83 sub dispatch {
  84     my $self = shift;
  85     my $c    = shift;
  86
  87     Catalyst::RequestRole::REST->meta->apply($c->request)
  88         unless does_role($c->request, 'Catalyst::RequestRole::REST');
  89
  90     my $controller = $c->component( $self->class );
  91     my $method     = $self->name . "_" . uc( $c->request->method );
  92     if ( $controller->can($method) ) {
  93         $c->execute( $self->class, $self, @{ $c->req->args } );
  94         return $controller->$method( $c, @{ $c->req->args } );
  95     } else {
  96         if ( $c->request->method eq "OPTIONS" ) {
  97             return $self->_return_options($c);
  98         } else {
  99             my $handle_ni = $self->name . "_not_implemented";
 100             if ( $controller->can($handle_ni) ) {
 101                 return $controller->$handle_ni( $c, @{ $c->req->args } );
 102             } else {
 103                 return $self->_return_not_implemented($c);
 104             }
 105         }
 106     }
 107 }
 108
 109 sub _return_options {
 110     my ( $self, $c ) = @_;
 111
 112     my @allowed = $self->_get_allowed_methods($c);
 113     $c->response->content_type('text/plain');
 114     $c->response->status(200);
 115     $c->response->header( 'Allow' => \@allowed );
 116 }
 117
 118 sub _get_allowed_methods {
 119     my ( $self, $c ) = @_;
 120
 121     my $controller = $self->class;
 122     my $methods    = Class::Inspector->methods($controller);
 123     my @allowed;
 124     foreach my $method ( @{$methods} ) {
 125         my $name = $self->name;
 126         if ( $method =~ /^$name\_(.+)$/ ) {
 127             push( @allowed, $1 );
 128         }
 129     }
 130     return @allowed;
 131 }
 132
 133 sub _return_not_implemented {
 134     my ( $self, $c ) = @_;
 135
 136     my @allowed = $self->_get_allowed_methods($c);
 137     $c->response->content_type('text/plain');
 138     $c->response->status(405);
 139     $c->response->header( 'Allow' => \@allowed );
 140     $c->response->body( "Method "
 141           . $c->request->method
 142           . " not implemented for "
 143           . $c->uri_for( $self->reverse ) );
 144 }
 145
 146 1;
 147
 148 =back
 149
 150 =head1 SEE ALSO
 151
 152 You likely want to look at L<Catalyst::Controller::REST>, which implements
 153 a sensible set of defaults for a controller doing REST.
 154
 155 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 156
 157 =head1 TROUBLESHOOTING
 158
 159 =over 4
 160
 161 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 162
 163 A:  Most likely, you haven't set Content-type equal to "application/json", or one of the
 164 accepted return formats.  You can do this by setting it in your query string thusly:
 165 ?content-type=application%2Fjson (where %2F == / uri escaped).
 166
 167 **NOTE** Apache will refuse %2F unless configured otherise.
 168 Make sure AllowEncodedSlashes On is in your httpd.conf file in order for this to run smoothly.
 169
 170 =cut
 171
 172 =cut
 173
 174
 175
 176
 177 =head1 MAINTAINER
 178
 179 J. Shirley <jshirley@gmail.com>
 180
 181 =head1 CONTRIBUTORS
 182
 183 Christopher Laco
 184
 185 Luke Saunders
 186
 187 John Goulah
 188
 189 Daisuke Maki <daisuke@endeworks.jp>
 190
 191 =head1 AUTHOR
 192
 193 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 194
 195 Marchex, Inc. paid me while I developed this module.  (http://www.marchex.com)
 196
 197 =head1 LICENSE
 198
 199 You may distribute this code under the same terms as Perl itself.
 200
 201 =cut
 202