lib/Catalyst/Action/REST.pm

   1 #
   2 # REST.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 # Created on: 10/12/2006 03:00:32 PM PDT
   5 #
   6 # $Id$
   7
   8 package Catalyst::Action::REST;
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'Catalyst::Action';
  14 use Class::Inspector;
  15 use Catalyst::Request::REST;
  16 use Catalyst::Controller::REST;
  17
  18 BEGIN { require 5.008001; }
  19
  20 our $VERSION = '0.75';
  21 $VERSION = eval $VERSION;
  22
  23 sub new {
  24   my $class  = shift;
  25   my $config = shift;
  26   Catalyst::Request::REST->_insert_self_into( $config->{class} );
  27   return $class->next::method($config, @_);
  28 }
  29
  30 =head1 NAME
  31
  32 Catalyst::Action::REST - Automated REST Method Dispatching
  33
  34 =head1 SYNOPSIS
  35
  36     sub foo :Local :ActionClass('REST') {
  37       ... do setup for HTTP method specific handlers ...
  38     }
  39
  40     sub foo_GET {
  41       ... do something for GET requests ...
  42     }
  43
  44     sub foo_PUT {
  45       ... do somethign for PUT requests ...
  46     }
  47
  48 =head1 DESCRIPTION
  49
  50 This Action handles doing automatic method dispatching for REST requests.  It
  51 takes a normal Catalyst action, and changes the dispatch to append an
  52 underscore and method name.
  53
  54 For example, in the synopsis above, calling GET on "/foo" would result in
  55 the foo_GET method being dispatched.
  56
  57 If a method is requested that is not implemented, this action will
  58 return a status 405 (Method Not Found).  It will populate the "Allow" header
  59 with the list of implemented request methods.  You can override this behavior
  60 by implementing a custom 405 handler like so:
  61
  62    sub foo_not_implemented {
  63       ... handle not implemented methods ...
  64    }
  65
  66 If you do not provide an _OPTIONS subroutine, we will automatically respond
  67 with a 200 OK.  The "Allow" header will be populated with the list of
  68 implemented request methods.
  69
  70 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  71 which brings this class together with automatic Serialization of requests
  72 and responses.
  73
  74 When you use this module, the request class will be changed to
  75 L<Catalyst::Request::REST>.
  76
  77 =head1 METHODS
  78
  79 =over 4
  80
  81 =item dispatch
  82
  83 This method overrides the default dispatch mechanism to the re-dispatching
  84 mechanism described above.
  85
  86 =cut
  87
  88 sub dispatch {
  89     my $self = shift;
  90     my $c    = shift;
  91
  92     my $controller = $c->component( $self->class );
  93     my $rest_method = $self->name . "_" . uc( $c->request->method );
  94
  95     my ($code, $name);
  96
  97     # Common case, for foo_GET etc
  98     if ($code = $controller->can($rest_method)) {
  99         # Exceute normal action
 100         $c->execute( $self->class, $self, @{ $c->req->args } );
 101         $name = $rest_method;
 102     }
 103
 104     # Generic handling for foo_OPTIONS
 105     if (!$code && $c->request->method eq "OPTIONS") {
 106         $name = $rest_method;
 107         $code = sub { $self->_return_options($self->name, @_) };
 108     }
 109
 110     # Otherwise, not implemented.
 111     if (!$code) {
 112         $name = $self->name . "_not_implemented";
 113         $code = $controller->can($name) # User method
 114             # Generic not implemented
 115             || sub { $self->_return_not_implemented($self->name, @_) };
 116     }
 117
 118     # localise stuff so we can dispatch the action 'as normal, but get
 119     # different stats shown, and different code run.
 120     local $self->{code} = $code;
 121     local $self->{reverse} = $name;
 122
 123     $c->execute( $self->class, $self, @{ $c->req->args } );
 124 }
 125
 126 sub _get_allowed_methods {
 127     my ( $self, $controller, $c, $name ) = @_;
 128     my $class = ref($controller) ? ref($controller) : $controller;
 129     my $methods    = Class::Inspector->methods($class);
 130     my @allowed;
 131     foreach my $method ( @{$methods} ) {
 132         if ( $method =~ /^$name\_(.+)$/ ) {
 133             push( @allowed, $1 );
 134         }
 135     }
 136     return @allowed;
 137 };
 138
 139 sub _return_options {
 140     my ( $self, $method_name, $controller, $c) = @_;
 141     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 142     $c->response->content_type('text/plain');
 143     $c->response->status(200);
 144     $c->response->header( 'Allow' => \@allowed );
 145 }
 146
 147 sub _return_not_implemented {
 148     my ( $self, $method_name, $controller, $c ) = @_;
 149
 150     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 151     $c->response->content_type('text/plain');
 152     $c->response->status(405);
 153     $c->response->header( 'Allow' => \@allowed );
 154     $c->response->body( "Method "
 155           . $c->request->method
 156           . " not implemented for "
 157           . $c->uri_for( $method_name ) );
 158 }
 159
 160 1;
 161
 162 =back
 163
 164 =head1 SEE ALSO
 165
 166 You likely want to look at L<Catalyst::Controller::REST>, which implements
 167 a sensible set of defaults for a controller doing REST.
 168
 169 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 170
 171 =head1 TROUBLESHOOTING
 172
 173 =over 4
 174
 175 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 176
 177 A:  Most likely, you haven't set Content-type equal to "application/json", or
 178 one of the accepted return formats.  You can do this by setting it in your query
 179 accepted return formats.  You can do this by setting it in your query string
 180 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 181
 182 B<NOTE> Apache will refuse %2F unless configured otherise.
 183 Make sure C<< AllowEncodedSlashes On >> is in your httpd.conf file in orde
 184 for this to run smoothly.
 185
 186 =back
 187
 188 =head1 CONTRIBUTORS
 189
 190 Christopher Laco
 191
 192 Luke Saunders
 193
 194 John Goulah
 195
 196 Daisuke Maki <daisuke@endeworks.jp>
 197
 198 J. Shirley <jshirley@gmail.com>
 199
 200 Hans Dieter Pearcey
 201
 202 Tomas Doran (t0m) <bobtfish@bobtfish.net>
 203
 204 =head1 AUTHOR
 205
 206 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 207
 208 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 209
 210 =head1 LICENSE
 211
 212 You may distribute this code under the same terms as Perl itself.
 213
 214 =cut
 215