lib/Catalyst/Action/REST.pm

   1 package Catalyst::Action::REST;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action';
   7 use Class::Inspector;
   8 use Catalyst::Request::REST;
   9 use Catalyst::Controller::REST;
  10
  11 BEGIN { require 5.008001; }
  12
  13 our $VERSION = '0.81';
  14 $VERSION = eval $VERSION;
  15
  16 sub new {
  17   my $class  = shift;
  18   my $config = shift;
  19   Catalyst::Request::REST->_insert_self_into( $config->{class} );
  20   return $class->next::method($config, @_);
  21 }
  22
  23 =head1 NAME
  24
  25 Catalyst::Action::REST - Automated REST Method Dispatching
  26
  27 =head1 SYNOPSIS
  28
  29     sub foo :Local :ActionClass('REST') {
  30       ... do setup for HTTP method specific handlers ...
  31     }
  32
  33     sub foo_GET {
  34       ... do something for GET requests ...
  35     }
  36
  37     # alternatively use an Action
  38     sub foo_PUT : Action {
  39       ... do something for PUT requests ...
  40     }
  41
  42 =head1 DESCRIPTION
  43
  44 This Action handles doing automatic method dispatching for REST requests.  It
  45 takes a normal Catalyst action, and changes the dispatch to append an
  46 underscore and method name.  First it will try dispatching to an action with
  47 the generated name, and failing that it will try to dispatch to a regular
  48 method.
  49
  50 For example, in the synopsis above, calling GET on "/foo" would result in
  51 the foo_GET method being dispatched.
  52
  53 If a method is requested that is not implemented, this action will
  54 return a status 405 (Method Not Found).  It will populate the "Allow" header
  55 with the list of implemented request methods.  You can override this behavior
  56 by implementing a custom 405 handler like so:
  57
  58    sub foo_not_implemented {
  59       ... handle not implemented methods ...
  60    }
  61
  62 If you do not provide an _OPTIONS subroutine, we will automatically respond
  63 with a 200 OK.  The "Allow" header will be populated with the list of
  64 implemented request methods.
  65
  66 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  67 which brings this class together with automatic Serialization of requests
  68 and responses.
  69
  70 When you use this module, it adds the L<Catalyst::TraitFor::Request::REST>
  71 role to your request class.
  72
  73 =head1 METHODS
  74
  75 =over 4
  76
  77 =item dispatch
  78
  79 This method overrides the default dispatch mechanism to the re-dispatching
  80 mechanism described above.
  81
  82 =cut
  83
  84 sub dispatch {
  85     my $self = shift;
  86     my $c    = shift;
  87
  88     my $controller = $c->component( $self->class );
  89     my $rest_method = $self->name . "_" . uc( $c->request->method );
  90
  91     my ($code, $name);
  92
  93     # Common case, for foo_GET etc
  94     if ( $code = $controller->action_for($rest_method) ) {
  95         $c->execute( $self->class, $self, @{ $c->req->args } );
  96         return $c->forward( $code,  $c->req->args );
  97      } elsif ($code = $controller->can($rest_method)) {
  98         # Exceute normal action
  99         $c->execute( $self->class, $self, @{ $c->req->args } );
 100         $name = $rest_method;
 101     }
 102
 103     # Generic handling for foo_OPTIONS
 104     if (!$code && $c->request->method eq "OPTIONS") {
 105         $name = $rest_method;
 106         $code = sub { $self->_return_options($self->name, @_) };
 107     }
 108
 109     # Otherwise, not implemented.
 110     if (!$code) {
 111         $name = $self->name . "_not_implemented";
 112         $code = $controller->can($name) # User method
 113             # Generic not implemented
 114             || sub { $self->_return_not_implemented($self->name, @_) };
 115     }
 116
 117     # localise stuff so we can dispatch the action 'as normal, but get
 118     # different stats shown, and different code run.
 119     local $self->{code} = $code;
 120     local $self->{reverse} = $name;
 121
 122     $c->execute( $self->class, $self, @{ $c->req->args } );
 123 }
 124
 125 sub _get_allowed_methods {
 126     my ( $self, $controller, $c, $name ) = @_;
 127     my $class = ref($controller) ? ref($controller) : $controller;
 128     my $methods = Class::Inspector->methods($class);
 129     return map { /^$name\_(.+)$/ } @$methods;
 130 };
 131
 132 sub _return_options {
 133     my ( $self, $method_name, $controller, $c) = @_;
 134     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 135     $c->response->content_type('text/plain');
 136     $c->response->status(200);
 137     $c->response->header( 'Allow' => \@allowed );
 138 }
 139
 140 sub _return_not_implemented {
 141     my ( $self, $method_name, $controller, $c ) = @_;
 142
 143     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 144     $c->response->content_type('text/plain');
 145     $c->response->status(405);
 146     $c->response->header( 'Allow' => \@allowed );
 147     $c->response->body( "Method "
 148           . $c->request->method
 149           . " not implemented for "
 150           . $c->uri_for( $method_name ) );
 151 }
 152
 153 1;
 154
 155 =back
 156
 157 =head1 SEE ALSO
 158
 159 You likely want to look at L<Catalyst::Controller::REST>, which implements a
 160 sensible set of defaults for a controller doing REST.
 161
 162 This class automatically adds the L<Catalyst::TraitFor::Request::REST> role to
 163 your request class.  If you're writing a webapp which provides RESTful
 164 responses and still needs to accommodate web browsers, you may prefer to use
 165 L<Catalyst::TraitFor::Request::REST::ForBrowsers> instead.
 166
 167 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 168
 169 =head1 TROUBLESHOOTING
 170
 171 =over 4
 172
 173 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 174
 175 A:  Most likely, you haven't set Content-type equal to "application/json", or
 176 one of the accepted return formats.  You can do this by setting it in your query
 177 accepted return formats.  You can do this by setting it in your query string
 178 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 179
 180 B<NOTE> Apache will refuse %2F unless configured otherwise.
 181 Make sure C<AllowEncodedSlashes On> is in your httpd.conf file in order
 182 for this to run smoothly.
 183
 184 =back
 185
 186 =head1 AUTHOR
 187
 188 Adam Jacob E<lt>adam@stalecoffee.orgE<gt>, with lots of help from mst and jrockway
 189
 190 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 191
 192 =head1 CONTRIBUTORS
 193
 194 Tomas Doran (t0m) E<lt>bobtfish@bobtfish.netE<gt>
 195
 196 John Goulah
 197
 198 Christopher Laco
 199
 200 Daisuke Maki E<lt>daisuke@endeworks.jpE<gt>
 201
 202 Hans Dieter Pearcey
 203
 204 Dave Rolsky E<lt>autarch@urth.orgE<gt>
 205
 206 Luke Saunders
 207
 208 Arthur Axel "fREW" Schmidt E<lt>frioux@gmail.comE<gt>
 209
 210 J. Shirley E<lt>jshirley@gmail.comE<gt>
 211
 212 =head1 COPYRIGHT
 213
 214 Copyright the above named AUTHOR and CONTRIBUTORS
 215
 216 =head1 LICENSE
 217
 218 You may distribute this code under the same terms as Perl itself.
 219
 220 =cut
 221