lib/Catalyst/Action/REST.pm

   1 package Catalyst::Action::REST;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action';
   7 use Class::Inspector;
   8 use Catalyst::Request::REST;
   9 use Catalyst::Controller::REST;
  10
  11 BEGIN { require 5.008001; }
  12
  13 our $VERSION = '1.02';
  14 $VERSION = eval $VERSION;
  15
  16 sub BUILDARGS {
  17     my $class  = shift;
  18     my $config = shift;
  19     Catalyst::Request::REST->_insert_self_into( $config->{class} );
  20     return $class->SUPER::BUILDARGS($config, @_);
  21 }
  22
  23 =head1 NAME
  24
  25 Catalyst::Action::REST - Automated REST Method Dispatching
  26
  27 =head1 SYNOPSIS
  28
  29     sub foo :Local :ActionClass('REST') {
  30       ... do setup for HTTP method specific handlers ...
  31     }
  32
  33     sub foo_GET {
  34       ... do something for GET requests ...
  35     }
  36
  37     # alternatively use an Action
  38     sub foo_PUT : Action {
  39       ... do something for PUT requests ...
  40     }
  41
  42 =head1 DESCRIPTION
  43
  44 This Action handles doing automatic method dispatching for REST requests.  It
  45 takes a normal Catalyst action, and changes the dispatch to append an
  46 underscore and method name.  First it will try dispatching to an action with
  47 the generated name, and failing that it will try to dispatch to a regular
  48 method.
  49
  50 For example, in the synopsis above, calling GET on "/foo" would result in
  51 the foo_GET method being dispatched.
  52
  53 If a method is requested that is not implemented, this action will
  54 return a status 405 (Method Not Found).  It will populate the "Allow" header
  55 with the list of implemented request methods.  You can override this behavior
  56 by implementing a custom 405 handler like so:
  57
  58    sub foo_not_implemented {
  59       ... handle not implemented methods ...
  60    }
  61
  62 If you do not provide an _OPTIONS subroutine, we will automatically respond
  63 with a 200 OK.  The "Allow" header will be populated with the list of
  64 implemented request methods.
  65
  66 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  67 which brings this class together with automatic Serialization of requests
  68 and responses.
  69
  70 When you use this module, it adds the L<Catalyst::TraitFor::Request::REST>
  71 role to your request class.
  72
  73 =head1 METHODS
  74
  75 =over 4
  76
  77 =item dispatch
  78
  79 This method overrides the default dispatch mechanism to the re-dispatching
  80 mechanism described above.
  81
  82 =cut
  83
  84 sub dispatch {
  85     my $self = shift;
  86     my $c    = shift;
  87
  88     my $rest_method = $self->name . "_" . uc( $c->request->method );
  89
  90     return $self->_dispatch_rest_method( $c, $rest_method );
  91 }
  92
  93 sub _dispatch_rest_method {
  94     my $self        = shift;
  95     my $c           = shift;
  96     my $rest_method = shift;
  97     my $req         = $c->request;
  98
  99     my $controller = $c->component( $self->class );
 100
 101     my ($code, $name);
 102
 103     # Execute normal 'foo' action.
 104     $c->execute( $self->class, $self, @{ $req->args } );
 105
 106     # Common case, for foo_GET etc
 107     if ( $code = $controller->action_for($rest_method) ) {
 108         return $c->forward( $code,  $req->args ); # Forward to foo_GET if it's an action
 109     }
 110     elsif ($code = $controller->can($rest_method)) {
 111         $name = $rest_method; # Stash name and code to run 'foo_GET' like an action below.
 112     }
 113
 114     # Generic handling for foo_*
 115     if (!$code) {
 116         my $code_action = {
 117             OPTIONS => sub {
 118                 $name = $rest_method;
 119                 $code = sub { $self->_return_options($self->name, @_) };
 120             },
 121             HEAD => sub {
 122               $rest_method =~ s{_HEAD$}{_GET}i;
 123               $self->_dispatch_rest_method($c, $rest_method);
 124             },
 125             default => sub {
 126                 # Otherwise, not implemented.
 127                 $name = $self->name . "_not_implemented";
 128                 $code = $controller->can($name) # User method
 129                     # Generic not implemented
 130                     || sub { $self->_return_not_implemented($self->name, @_) };
 131             },
 132         };
 133         my $respond = ($code_action->{$req->method}
 134                        || $code_action->{'default'})->();
 135         return $respond unless $name;
 136     }
 137
 138     # localise stuff so we can dispatch the action 'as normal, but get
 139     # different stats shown, and different code run.
 140     # Also get the full path for the action, and make it look like a forward
 141     local $self->{code} = $code;
 142     my @name = split m{/}, $self->reverse;
 143     $name[-1] = $name;
 144     local $self->{reverse} = "-> " . join('/', @name);
 145
 146     $c->execute( $self->class, $self, @{ $req->args } );
 147 }
 148
 149 sub _get_allowed_methods {
 150     my ( $self, $controller, $c, $name ) = @_;
 151     my $class = ref($controller) ? ref($controller) : $controller;
 152     my $methods = Class::Inspector->methods($class);
 153     return map { /^$name\_(.+)$/ } @$methods;
 154 };
 155
 156 sub _return_options {
 157     my ( $self, $method_name, $controller, $c) = @_;
 158     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 159     $c->response->content_type('text/plain');
 160     $c->response->status(200);
 161     $c->response->header( 'Allow' => \@allowed );
 162     $c->response->body(q{});
 163 }
 164
 165 sub _return_not_implemented {
 166     my ( $self, $method_name, $controller, $c ) = @_;
 167
 168     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 169     $c->response->content_type('text/plain');
 170     $c->response->status(405);
 171     $c->response->header( 'Allow' => \@allowed );
 172     $c->response->body( "Method "
 173           . $c->request->method
 174           . " not implemented for "
 175           . $c->uri_for( $method_name ) );
 176 }
 177
 178 __PACKAGE__->meta->make_immutable;
 179
 180 1;
 181
 182 =back
 183
 184 =head1 SEE ALSO
 185
 186 You likely want to look at L<Catalyst::Controller::REST>, which implements a
 187 sensible set of defaults for a controller doing REST.
 188
 189 This class automatically adds the L<Catalyst::TraitFor::Request::REST> role to
 190 your request class.  If you're writing a web application which provides RESTful
 191 responses and still needs to accommodate web browsers, you may prefer to use
 192 L<Catalyst::TraitFor::Request::REST::ForBrowsers> instead.
 193
 194 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 195
 196 =head1 TROUBLESHOOTING
 197
 198 =over 4
 199
 200 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 201
 202 A:  Most likely, you haven't set Content-type equal to "application/json", or
 203 one of the accepted return formats.  You can do this by setting it in your query
 204 accepted return formats.  You can do this by setting it in your query string
 205 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 206
 207 B<NOTE> Apache will refuse %2F unless configured otherwise.
 208 Make sure C<AllowEncodedSlashes On> is in your httpd.conf file in order
 209 for this to run smoothly.
 210
 211 =back
 212
 213 =head1 AUTHOR
 214
 215 Adam Jacob E<lt>adam@stalecoffee.orgE<gt>, with lots of help from mst and jrockway
 216
 217 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 218
 219 =head1 CONTRIBUTORS
 220
 221 Tomas Doran (t0m) E<lt>bobtfish@bobtfish.netE<gt>
 222
 223 John Goulah
 224
 225 Christopher Laco
 226
 227 Daisuke Maki E<lt>daisuke@endeworks.jpE<gt>
 228
 229 Hans Dieter Pearcey
 230
 231 Brian Phillips E<lt>bphillips@cpan.orgE<gt>
 232
 233 Dave Rolsky E<lt>autarch@urth.orgE<gt>
 234
 235 Luke Saunders
 236
 237 Arthur Axel "fREW" Schmidt E<lt>frioux@gmail.comE<gt>
 238
 239 J. Shirley E<lt>jshirley@gmail.comE<gt>
 240
 241 Gavin Henry E<lt>ghenry@surevoip.co.ukE<gt>
 242
 243 Gerv http://www.gerv.net/
 244
 245 Colin Newell <colin@opusvl.com>
 246
 247 =head1 COPYRIGHT
 248
 249 Copyright (c) 2006-2012 the above named AUTHOR and CONTRIBUTORS
 250
 251 =head1 LICENSE
 252
 253 You may distribute this code under the same terms as Perl itself.
 254
 255 =cut
 256