lib/Catalyst/Action/REST.pm

   1 #
   2 # REST.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 # Created on: 10/12/2006 03:00:32 PM PDT
   5 #
   6 # $Id$
   7
   8 package Catalyst::Action::REST;
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'Catalyst::Action';
  14 use Class::Inspector;
  15 use Catalyst::Request::REST;
  16 use Catalyst::Controller::REST;
  17
  18 BEGIN { require 5.008001; }
  19
  20 our $VERSION = '0.78';
  21 $VERSION = eval $VERSION;
  22
  23 sub new {
  24   my $class  = shift;
  25   my $config = shift;
  26   Catalyst::Request::REST->_insert_self_into( $config->{class} );
  27   return $class->next::method($config, @_);
  28 }
  29
  30 =head1 NAME
  31
  32 Catalyst::Action::REST - Automated REST Method Dispatching
  33
  34 =head1 SYNOPSIS
  35
  36     sub foo :Local :ActionClass('REST') {
  37       ... do setup for HTTP method specific handlers ...
  38     }
  39
  40     sub foo_GET {
  41       ... do something for GET requests ...
  42     }
  43
  44     # alternatively use an Action
  45     sub foo_PUT : Action {
  46       ... do something for PUT requests ...
  47     }
  48
  49 =head1 DESCRIPTION
  50
  51 This Action handles doing automatic method dispatching for REST requests.  It
  52 takes a normal Catalyst action, and changes the dispatch to append an
  53 underscore and method name.  First it will try dispatching to an action with
  54 the generated name, and failing that it will try to dispatch to a regular
  55 method.
  56
  57 For example, in the synopsis above, calling GET on "/foo" would result in
  58 the foo_GET method being dispatched.
  59
  60 If a method is requested that is not implemented, this action will
  61 return a status 405 (Method Not Found).  It will populate the "Allow" header
  62 with the list of implemented request methods.  You can override this behavior
  63 by implementing a custom 405 handler like so:
  64
  65    sub foo_not_implemented {
  66       ... handle not implemented methods ...
  67    }
  68
  69 If you do not provide an _OPTIONS subroutine, we will automatically respond
  70 with a 200 OK.  The "Allow" header will be populated with the list of
  71 implemented request methods.
  72
  73 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  74 which brings this class together with automatic Serialization of requests
  75 and responses.
  76
  77 When you use this module, the request class will be changed to
  78 L<Catalyst::Request::REST>.
  79
  80 =head1 METHODS
  81
  82 =over 4
  83
  84 =item dispatch
  85
  86 This method overrides the default dispatch mechanism to the re-dispatching
  87 mechanism described above.
  88
  89 =cut
  90
  91 sub dispatch {
  92     my $self = shift;
  93     my $c    = shift;
  94
  95     my $controller = $c->component( $self->class );
  96     my $rest_method = $self->name . "_" . uc( $c->request->method );
  97
  98     my ($code, $name);
  99
 100     # Common case, for foo_GET etc
 101     if ( $code = $controller->action_for($rest_method) ) {
 102         $c->execute( $self->class, $self, @{ $c->req->args } );
 103         return $c->forward( $code,  $c->req->args );
 104      } elsif ($code = $controller->can($rest_method)) {
 105         # Exceute normal action
 106         $c->execute( $self->class, $self, @{ $c->req->args } );
 107         $name = $rest_method;
 108     }
 109
 110     # Generic handling for foo_OPTIONS
 111     if (!$code && $c->request->method eq "OPTIONS") {
 112         $name = $rest_method;
 113         $code = sub { $self->_return_options($self->name, @_) };
 114     }
 115
 116     # Otherwise, not implemented.
 117     if (!$code) {
 118         $name = $self->name . "_not_implemented";
 119         $code = $controller->can($name) # User method
 120             # Generic not implemented
 121             || sub { $self->_return_not_implemented($self->name, @_) };
 122     }
 123
 124     # localise stuff so we can dispatch the action 'as normal, but get
 125     # different stats shown, and different code run.
 126     local $self->{code} = $code;
 127     local $self->{reverse} = $name;
 128
 129     $c->execute( $self->class, $self, @{ $c->req->args } );
 130 }
 131
 132 sub _get_allowed_methods {
 133     my ( $self, $controller, $c, $name ) = @_;
 134     my $class = ref($controller) ? ref($controller) : $controller;
 135     my $methods    = Class::Inspector->methods($class);
 136     my @allowed;
 137     foreach my $method ( @{$methods} ) {
 138         if ( $method =~ /^$name\_(.+)$/ ) {
 139             push( @allowed, $1 );
 140         }
 141     }
 142     return @allowed;
 143 };
 144
 145 sub _return_options {
 146     my ( $self, $method_name, $controller, $c) = @_;
 147     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 148     $c->response->content_type('text/plain');
 149     $c->response->status(200);
 150     $c->response->header( 'Allow' => \@allowed );
 151 }
 152
 153 sub _return_not_implemented {
 154     my ( $self, $method_name, $controller, $c ) = @_;
 155
 156     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 157     $c->response->content_type('text/plain');
 158     $c->response->status(405);
 159     $c->response->header( 'Allow' => \@allowed );
 160     $c->response->body( "Method "
 161           . $c->request->method
 162           . " not implemented for "
 163           . $c->uri_for( $method_name ) );
 164 }
 165
 166 1;
 167
 168 =back
 169
 170 =head1 SEE ALSO
 171
 172 You likely want to look at L<Catalyst::Controller::REST>, which implements
 173 a sensible set of defaults for a controller doing REST.
 174
 175 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 176
 177 =head1 TROUBLESHOOTING
 178
 179 =over 4
 180
 181 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 182
 183 A:  Most likely, you haven't set Content-type equal to "application/json", or
 184 one of the accepted return formats.  You can do this by setting it in your query
 185 accepted return formats.  You can do this by setting it in your query string
 186 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 187
 188 B<NOTE> Apache will refuse %2F unless configured otherise.
 189 Make sure C<< AllowEncodedSlashes On >> is in your httpd.conf file in orde
 190 for this to run smoothly.
 191
 192 =back
 193
 194 =head1 AUTHOR
 195
 196 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 197
 198 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 199
 200 =head1 CONTRIBUTORS
 201
 202 Arthur Axel "fREW" Schmidt <frioux@gmail.com>
 203
 204 Christopher Laco
 205
 206 Luke Saunders
 207
 208 John Goulah
 209
 210 Daisuke Maki <daisuke@endeworks.jp>
 211
 212 J. Shirley <jshirley@gmail.com>
 213
 214 Hans Dieter Pearcey
 215
 216 Tomas Doran (t0m) <bobtfish@bobtfish.net>
 217
 218 =head1 COPYRIGHT
 219
 220 Copyright the above named AUTHOR and CONTRIBUTORS
 221
 222 =head1 LICENSE
 223
 224 You may distribute this code under the same terms as Perl itself.
 225
 226 =cut
 227