lib/Catalyst/Action/REST.pm

   1 package Catalyst::Action::REST;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action';
   7 use Class::Inspector;
   8 use Catalyst::Request::REST;
   9 use Catalyst::Controller::REST;
  10
  11 BEGIN { require 5.008001; }
  12
  13 our $VERSION = '1.02';
  14 $VERSION = eval $VERSION;
  15
  16 sub BUILDARGS {
  17     my $class  = shift;
  18     my $config = shift;
  19     Catalyst::Request::REST->_insert_self_into( $config->{class} );
  20     return $class->SUPER::BUILDARGS($config, @_);
  21 }
  22
  23 =head1 NAME
  24
  25 Catalyst::Action::REST - Automated REST Method Dispatching
  26
  27 =head1 SYNOPSIS
  28
  29     sub foo :Local :ActionClass('REST') {
  30       ... do setup for HTTP method specific handlers ...
  31     }
  32
  33     sub foo_GET {
  34       ... do something for GET requests ...
  35     }
  36
  37     # alternatively use an Action
  38     sub foo_PUT : Action {
  39       ... do something for PUT requests ...
  40     }
  41
  42 =head1 DESCRIPTION
  43
  44 This Action handles doing automatic method dispatching for REST requests.  It
  45 takes a normal Catalyst action, and changes the dispatch to append an
  46 underscore and method name.  First it will try dispatching to an action with
  47 the generated name, and failing that it will try to dispatch to a regular
  48 method.
  49
  50 For example, in the synopsis above, calling GET on "/foo" would result in
  51 the foo_GET method being dispatched.
  52
  53 If a method is requested that is not implemented, this action will
  54 return a status 405 (Method Not Found).  It will populate the "Allow" header
  55 with the list of implemented request methods.  You can override this behavior
  56 by implementing a custom 405 handler like so:
  57
  58    sub foo_not_implemented {
  59       ... handle not implemented methods ...
  60    }
  61
  62 If you do not provide an _OPTIONS subroutine, we will automatically respond
  63 with a 200 OK.  The "Allow" header will be populated with the list of
  64 implemented request methods.
  65
  66 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  67 which brings this class together with automatic Serialization of requests
  68 and responses.
  69
  70 When you use this module, it adds the L<Catalyst::TraitFor::Request::REST>
  71 role to your request class.
  72
  73 =head1 METHODS
  74
  75 =over 4
  76
  77 =item dispatch
  78
  79 This method overrides the default dispatch mechanism to the re-dispatching
  80 mechanism described above.
  81
  82 =cut
  83
  84 sub dispatch {
  85     my $self = shift;
  86     my $c    = shift;
  87
  88     my $rest_method = $self->name . "_" . uc( $c->request->method );
  89
  90     return $self->_dispatch_rest_method( $c, $rest_method );
  91 }
  92
  93 sub _dispatch_rest_method {
  94     my $self        = shift;
  95     my $c           = shift;
  96     my $rest_method = shift;
  97     my $req         = $c->request;
  98
  99     my $controller = $c->component( $self->class );
 100
 101     my ($code, $name);
 102
 103     # Execute normal 'foo' action.
 104     $c->execute( $self->class, $self, @{ $req->args } );
 105
 106     # Common case, for foo_GET etc
 107     if ( $code = $controller->action_for($rest_method) ) {
 108         return $c->forward( $code,  $req->args ); # Forward to foo_GET if it's an action
 109     }
 110     elsif ($code = $controller->can($rest_method)) {
 111         $name = $rest_method; # Stash name and code to run 'foo_GET' like an action below.
 112     }
 113
 114     # Generic handling for foo_*
 115     if (!$code) {
 116         my $code_action = {
 117             OPTIONS => sub {
 118                 $name = $rest_method;
 119                 $code = sub { $self->_return_options($self->name, @_) };
 120             },
 121             default => sub {
 122                 # Otherwise, not implemented.
 123                 $name = $self->name . "_not_implemented";
 124                 $code = $controller->can($name) # User method
 125                     # Generic not implemented
 126                     || sub { $self->_return_not_implemented($self->name, @_) };
 127             },
 128         };
 129         ($code_action->{$req->method} || $code_action->{'default'})->();
 130     }
 131
 132     # localise stuff so we can dispatch the action 'as normal, but get
 133     # different stats shown, and different code run.
 134     # Also get the full path for the action, and make it look like a forward
 135     local $self->{code} = $code;
 136     my @name = split m{/}, $self->reverse;
 137     $name[-1] = $name;
 138     local $self->{reverse} = "-> " . join('/', @name);
 139
 140     $c->execute( $self->class, $self, @{ $req->args } );
 141 }
 142
 143 sub _get_allowed_methods {
 144     my ( $self, $controller, $c, $name ) = @_;
 145     my $class = ref($controller) ? ref($controller) : $controller;
 146     my $methods = Class::Inspector->methods($class);
 147     return map { /^$name\_(.+)$/ } @$methods;
 148 };
 149
 150 sub _return_options {
 151     my ( $self, $method_name, $controller, $c) = @_;
 152     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 153     $c->response->content_type('text/plain');
 154     $c->response->status(200);
 155     $c->response->header( 'Allow' => \@allowed );
 156 }
 157
 158 sub _return_not_implemented {
 159     my ( $self, $method_name, $controller, $c ) = @_;
 160
 161     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 162     $c->response->content_type('text/plain');
 163     $c->response->status(405);
 164     $c->response->header( 'Allow' => \@allowed );
 165     $c->response->body( "Method "
 166           . $c->request->method
 167           . " not implemented for "
 168           . $c->uri_for( $method_name ) );
 169 }
 170
 171 __PACKAGE__->meta->make_immutable;
 172
 173 1;
 174
 175 =back
 176
 177 =head1 SEE ALSO
 178
 179 You likely want to look at L<Catalyst::Controller::REST>, which implements a
 180 sensible set of defaults for a controller doing REST.
 181
 182 This class automatically adds the L<Catalyst::TraitFor::Request::REST> role to
 183 your request class.  If you're writing a web application which provides RESTful
 184 responses and still needs to accommodate web browsers, you may prefer to use
 185 L<Catalyst::TraitFor::Request::REST::ForBrowsers> instead.
 186
 187 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 188
 189 =head1 TROUBLESHOOTING
 190
 191 =over 4
 192
 193 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 194
 195 A:  Most likely, you haven't set Content-type equal to "application/json", or
 196 one of the accepted return formats.  You can do this by setting it in your query
 197 accepted return formats.  You can do this by setting it in your query string
 198 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 199
 200 B<NOTE> Apache will refuse %2F unless configured otherwise.
 201 Make sure C<AllowEncodedSlashes On> is in your httpd.conf file in order
 202 for this to run smoothly.
 203
 204 =back
 205
 206 =head1 AUTHOR
 207
 208 Adam Jacob E<lt>adam@stalecoffee.orgE<gt>, with lots of help from mst and jrockway
 209
 210 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 211
 212 =head1 CONTRIBUTORS
 213
 214 Tomas Doran (t0m) E<lt>bobtfish@bobtfish.netE<gt>
 215
 216 John Goulah
 217
 218 Christopher Laco
 219
 220 Daisuke Maki E<lt>daisuke@endeworks.jpE<gt>
 221
 222 Hans Dieter Pearcey
 223
 224 Brian Phillips E<lt>bphillips@cpan.orgE<gt>
 225
 226 Dave Rolsky E<lt>autarch@urth.orgE<gt>
 227
 228 Luke Saunders
 229
 230 Arthur Axel "fREW" Schmidt E<lt>frioux@gmail.comE<gt>
 231
 232 J. Shirley E<lt>jshirley@gmail.comE<gt>
 233
 234 Gavin Henry E<lt>ghenry@surevoip.co.ukE<gt>
 235
 236 Gerv http://www.gerv.net/
 237
 238 Colin Newell <colin@opusvl.com>
 239
 240 =head1 COPYRIGHT
 241
 242 Copyright (c) 2006-2012 the above named AUTHOR and CONTRIBUTORS
 243
 244 =head1 LICENSE
 245
 246 You may distribute this code under the same terms as Perl itself.
 247
 248 =cut
 249