lib/Catalyst/Action/REST.pm

   1 #
   2 # REST.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 # Created on: 10/12/2006 03:00:32 PM PDT
   5 #
   6 # $Id$
   7
   8 package Catalyst::Action::REST;
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'Catalyst::Action';
  14 use Class::Inspector;
  15 use Catalyst::Request::REST;
  16 use Catalyst::Controller::REST;
  17
  18 BEGIN { require 5.008001; }
  19
  20 our $VERSION = '0.74';
  21
  22 sub new {
  23   my $class  = shift;
  24   my $config = shift;
  25   Catalyst::Request::REST->_insert_self_into( $config->{class} );
  26   return $class->next::method($config, @_);
  27 }
  28
  29 =head1 NAME
  30
  31 Catalyst::Action::REST - Automated REST Method Dispatching
  32
  33 =head1 SYNOPSIS
  34
  35     sub foo :Local :ActionClass('REST') {
  36       ... do setup for HTTP method specific handlers ...
  37     }
  38
  39     sub foo_GET {
  40       ... do something for GET requests ...
  41     }
  42
  43     sub foo_PUT {
  44       ... do somethign for PUT requests ...
  45     }
  46
  47 =head1 DESCRIPTION
  48
  49 This Action handles doing automatic method dispatching for REST requests.  It
  50 takes a normal Catalyst action, and changes the dispatch to append an
  51 underscore and method name.
  52
  53 For example, in the synopsis above, calling GET on "/foo" would result in
  54 the foo_GET method being dispatched.
  55
  56 If a method is requested that is not implemented, this action will
  57 return a status 405 (Method Not Found).  It will populate the "Allow" header
  58 with the list of implemented request methods.  You can override this behavior
  59 by implementing a custom 405 handler like so:
  60
  61    sub foo_not_implemented {
  62       ... handle not implemented methods ...
  63    }
  64
  65 If you do not provide an _OPTIONS subroutine, we will automatically respond
  66 with a 200 OK.  The "Allow" header will be populated with the list of
  67 implemented request methods.
  68
  69 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  70 which brings this class together with automatic Serialization of requests
  71 and responses.
  72
  73 When you use this module, the request class will be changed to
  74 L<Catalyst::Request::REST>.
  75
  76 =head1 METHODS
  77
  78 =over 4
  79
  80 =item dispatch
  81
  82 This method overrides the default dispatch mechanism to the re-dispatching
  83 mechanism described above.
  84
  85 =cut
  86
  87 sub dispatch {
  88     my $self = shift;
  89     my $c    = shift;
  90
  91     my $controller = $c->component( $self->class );
  92     my $rest_method = $self->name . "_" . uc( $c->request->method );
  93
  94     my ($code, $name);
  95
  96     # Common case, for foo_GET etc
  97     if ( $code = $controller->action_for($rest_method) ) {
  98         $c->execute( $self->class, $self, @{ $c->req->args } );
  99         return $c->forward( $code,  $c->req->args );
 100      } elsif ($code = $controller->can($rest_method)) {
 101         # Exceute normal action
 102         $c->execute( $self->class, $self, @{ $c->req->args } );
 103         $name = $rest_method;
 104     }
 105
 106     # Generic handling for foo_OPTIONS
 107     if (!$code && $c->request->method eq "OPTIONS") {
 108         $name = $rest_method;
 109         $code = sub { $self->_return_options($self->name, @_) };
 110     }
 111
 112     # Otherwise, not implemented.
 113     if (!$code) {
 114         $name = $self->name . "_not_implemented";
 115         $code = $controller->can($name) # User method
 116             # Generic not implemented
 117             || sub { $self->_return_not_implemented($self->name, @_) };
 118     }
 119
 120     # localise stuff so we can dispatch the action 'as normal, but get
 121     # different stats shown, and different code run.
 122     local $self->{code} = $code;
 123     local $self->{reverse} = $name;
 124
 125     $c->execute( $self->class, $self, @{ $c->req->args } );
 126 }
 127
 128 sub _get_allowed_methods {
 129     my ( $self, $controller, $c, $name ) = @_;
 130     my $class = ref($controller) ? ref($controller) : $controller;
 131     my $methods    = Class::Inspector->methods($class);
 132     my @allowed;
 133     foreach my $method ( @{$methods} ) {
 134         if ( $method =~ /^$name\_(.+)$/ ) {
 135             push( @allowed, $1 );
 136         }
 137     }
 138     return @allowed;
 139 };
 140
 141 sub _return_options {
 142     my ( $self, $method_name, $controller, $c) = @_;
 143     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 144     $c->response->content_type('text/plain');
 145     $c->response->status(200);
 146     $c->response->header( 'Allow' => \@allowed );
 147 }
 148
 149 sub _return_not_implemented {
 150     my ( $self, $method_name, $controller, $c ) = @_;
 151
 152     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 153     $c->response->content_type('text/plain');
 154     $c->response->status(405);
 155     $c->response->header( 'Allow' => \@allowed );
 156     $c->response->body( "Method "
 157           . $c->request->method
 158           . " not implemented for "
 159           . $c->uri_for( $method_name ) );
 160 }
 161
 162 1;
 163
 164 =back
 165
 166 =head1 SEE ALSO
 167
 168 You likely want to look at L<Catalyst::Controller::REST>, which implements
 169 a sensible set of defaults for a controller doing REST.
 170
 171 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 172
 173 =head1 TROUBLESHOOTING
 174
 175 =over 4
 176
 177 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 178
 179 A:  Most likely, you haven't set Content-type equal to "application/json", or
 180 one of the accepted return formats.  You can do this by setting it in your query
 181 accepted return formats.  You can do this by setting it in your query string
 182 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 183
 184 B<NOTE> Apache will refuse %2F unless configured otherise.
 185 Make sure C<< AllowEncodedSlashes On >> is in your httpd.conf file in orde
 186 for this to run smoothly.
 187
 188 =back
 189
 190 =head1 CONTRIBUTORS
 191
 192 Christopher Laco
 193
 194 Luke Saunders
 195
 196 John Goulah
 197
 198 Daisuke Maki <daisuke@endeworks.jp>
 199
 200 J. Shirley <jshirley@gmail.com>
 201
 202 Hans Dieter Pearcey
 203
 204 Tomas Doran (t0m) <bobtfish@bobtfish.net>
 205
 206 =head1 AUTHOR
 207
 208 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 209
 210 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 211
 212 =head1 LICENSE
 213
 214 You may distribute this code under the same terms as Perl itself.
 215
 216 =cut
 217