lib/Catalyst/Action/REST.pm

   1 package Catalyst::Action::REST;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action';
   7 use Class::Inspector;
   8 use Catalyst::Request::REST;
   9 use Catalyst::Controller::REST;
  10
  11 BEGIN { require 5.008001; }
  12
  13 our $VERSION = '0.79';
  14 $VERSION = eval $VERSION;
  15
  16 sub new {
  17   my $class  = shift;
  18   my $config = shift;
  19   Catalyst::Request::REST->_insert_self_into( $config->{class} );
  20   return $class->next::method($config, @_);
  21 }
  22
  23 =head1 NAME
  24
  25 Catalyst::Action::REST - Automated REST Method Dispatching
  26
  27 =head1 SYNOPSIS
  28
  29     sub foo :Local :ActionClass('REST') {
  30       ... do setup for HTTP method specific handlers ...
  31     }
  32
  33     sub foo_GET {
  34       ... do something for GET requests ...
  35     }
  36
  37     # alternatively use an Action
  38     sub foo_PUT : Action {
  39       ... do something for PUT requests ...
  40     }
  41
  42 =head1 DESCRIPTION
  43
  44 This Action handles doing automatic method dispatching for REST requests.  It
  45 takes a normal Catalyst action, and changes the dispatch to append an
  46 underscore and method name.  First it will try dispatching to an action with
  47 the generated name, and failing that it will try to dispatch to a regular
  48 method.
  49
  50 For example, in the synopsis above, calling GET on "/foo" would result in
  51 the foo_GET method being dispatched.
  52
  53 If a method is requested that is not implemented, this action will
  54 return a status 405 (Method Not Found).  It will populate the "Allow" header
  55 with the list of implemented request methods.  You can override this behavior
  56 by implementing a custom 405 handler like so:
  57
  58    sub foo_not_implemented {
  59       ... handle not implemented methods ...
  60    }
  61
  62 If you do not provide an _OPTIONS subroutine, we will automatically respond
  63 with a 200 OK.  The "Allow" header will be populated with the list of
  64 implemented request methods.
  65
  66 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  67 which brings this class together with automatic Serialization of requests
  68 and responses.
  69
  70 When you use this module, the request class will be changed to
  71 L<Catalyst::Request::REST>.
  72
  73 =head1 METHODS
  74
  75 =over 4
  76
  77 =item dispatch
  78
  79 This method overrides the default dispatch mechanism to the re-dispatching
  80 mechanism described above.
  81
  82 =cut
  83
  84 sub dispatch {
  85     my $self = shift;
  86     my $c    = shift;
  87
  88     my $controller = $c->component( $self->class );
  89     my $rest_method = $self->name . "_" . uc( $c->request->method );
  90
  91     my ($code, $name);
  92
  93     # Common case, for foo_GET etc
  94     if ( $code = $controller->action_for($rest_method) ) {
  95         $c->execute( $self->class, $self, @{ $c->req->args } );
  96         return $c->forward( $code,  $c->req->args );
  97      } elsif ($code = $controller->can($rest_method)) {
  98         # Exceute normal action
  99         $c->execute( $self->class, $self, @{ $c->req->args } );
 100         $name = $rest_method;
 101     }
 102
 103     # Generic handling for foo_OPTIONS
 104     if (!$code && $c->request->method eq "OPTIONS") {
 105         $name = $rest_method;
 106         $code = sub { $self->_return_options($self->name, @_) };
 107     }
 108
 109     # Otherwise, not implemented.
 110     if (!$code) {
 111         $name = $self->name . "_not_implemented";
 112         $code = $controller->can($name) # User method
 113             # Generic not implemented
 114             || sub { $self->_return_not_implemented($self->name, @_) };
 115     }
 116
 117     # localise stuff so we can dispatch the action 'as normal, but get
 118     # different stats shown, and different code run.
 119     local $self->{code} = $code;
 120     local $self->{reverse} = $name;
 121
 122     $c->execute( $self->class, $self, @{ $c->req->args } );
 123 }
 124
 125 sub _get_allowed_methods {
 126     my ( $self, $controller, $c, $name ) = @_;
 127     my $class = ref($controller) ? ref($controller) : $controller;
 128     my $methods    = Class::Inspector->methods($class);
 129     my @allowed;
 130     foreach my $method ( @{$methods} ) {
 131         if ( $method =~ /^$name\_(.+)$/ ) {
 132             push( @allowed, $1 );
 133         }
 134     }
 135     return @allowed;
 136 };
 137
 138 sub _return_options {
 139     my ( $self, $method_name, $controller, $c) = @_;
 140     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 141     $c->response->content_type('text/plain');
 142     $c->response->status(200);
 143     $c->response->header( 'Allow' => \@allowed );
 144 }
 145
 146 sub _return_not_implemented {
 147     my ( $self, $method_name, $controller, $c ) = @_;
 148
 149     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 150     $c->response->content_type('text/plain');
 151     $c->response->status(405);
 152     $c->response->header( 'Allow' => \@allowed );
 153     $c->response->body( "Method "
 154           . $c->request->method
 155           . " not implemented for "
 156           . $c->uri_for( $method_name ) );
 157 }
 158
 159 1;
 160
 161 =back
 162
 163 =head1 SEE ALSO
 164
 165 You likely want to look at L<Catalyst::Controller::REST>, which implements
 166 a sensible set of defaults for a controller doing REST.
 167
 168 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 169
 170 =head1 TROUBLESHOOTING
 171
 172 =over 4
 173
 174 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 175
 176 A:  Most likely, you haven't set Content-type equal to "application/json", or
 177 one of the accepted return formats.  You can do this by setting it in your query
 178 accepted return formats.  You can do this by setting it in your query string
 179 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 180
 181 B<NOTE> Apache will refuse %2F unless configured otherwise.
 182 Make sure C<AllowEncodedSlashes On> is in your httpd.conf file in order
 183 for this to run smoothly.
 184
 185 =back
 186
 187 =head1 AUTHOR
 188
 189 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 190
 191 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 192
 193 =head1 CONTRIBUTORS
 194
 195 Arthur Axel "fREW" Schmidt <frioux@gmail.com>
 196
 197 Christopher Laco
 198
 199 Luke Saunders
 200
 201 John Goulah
 202
 203 Daisuke Maki <daisuke@endeworks.jp>
 204
 205 J. Shirley <jshirley@gmail.com>
 206
 207 Hans Dieter Pearcey
 208
 209 Tomas Doran (t0m) <bobtfish@bobtfish.net>
 210
 211 =head1 COPYRIGHT
 212
 213 Copyright the above named AUTHOR and CONTRIBUTORS
 214
 215 =head1 LICENSE
 216
 217 You may distribute this code under the same terms as Perl itself.
 218
 219 =cut
 220