lib/Catalyst/Action/REST.pm

   1 package Catalyst::Action::REST;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action';
   7 use Class::Inspector;
   8 use Catalyst::Request::REST;
   9 use Catalyst::Controller::REST;
  10
  11 BEGIN { require 5.008001; }
  12
  13 our $VERSION = '1.03';
  14 $VERSION = eval $VERSION;
  15
  16 sub BUILDARGS {
  17     my $class  = shift;
  18     my $config = shift;
  19     Catalyst::Request::REST->_insert_self_into( $config->{class} );
  20     return $class->SUPER::BUILDARGS($config, @_);
  21 }
  22
  23 =head1 NAME
  24
  25 Catalyst::Action::REST - Automated REST Method Dispatching
  26
  27 =head1 SYNOPSIS
  28
  29     sub foo :Local :ActionClass('REST') {
  30       ... do setup for HTTP method specific handlers ...
  31     }
  32
  33     sub foo_GET {
  34       ... do something for GET requests ...
  35     }
  36
  37     # alternatively use an Action
  38     sub foo_PUT : Action {
  39       ... do something for PUT requests ...
  40     }
  41
  42 =head1 DESCRIPTION
  43
  44 This Action handles doing automatic method dispatching for REST requests.  It
  45 takes a normal Catalyst action, and changes the dispatch to append an
  46 underscore and method name.  First it will try dispatching to an action with
  47 the generated name, and failing that it will try to dispatch to a regular
  48 method.
  49
  50 For example, in the synopsis above, calling GET on "/foo" would result in
  51 the foo_GET method being dispatched.
  52
  53 If a method is requested that is not implemented, this action will
  54 return a status 405 (Method Not Found).  It will populate the "Allow" header
  55 with the list of implemented request methods.  You can override this behavior
  56 by implementing a custom 405 handler like so:
  57
  58    sub foo_not_implemented {
  59       ... handle not implemented methods ...
  60    }
  61
  62 If you do not provide an _OPTIONS subroutine, we will automatically respond
  63 with a 200 OK.  The "Allow" header will be populated with the list of
  64 implemented request methods. If you do not provide an _HEAD either, we will
  65 auto dispatch to the _GET one in case it exists.
  66
  67 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  68 which brings this class together with automatic Serialization of requests
  69 and responses.
  70
  71 When you use this module, it adds the L<Catalyst::TraitFor::Request::REST>
  72 role to your request class.
  73
  74 =head1 METHODS
  75
  76 =over 4
  77
  78 =item dispatch
  79
  80 This method overrides the default dispatch mechanism to the re-dispatching
  81 mechanism described above.
  82
  83 =cut
  84
  85 sub dispatch {
  86     my $self = shift;
  87     my $c    = shift;
  88
  89     my $rest_method = $self->name . "_" . uc( $c->request->method );
  90
  91     return $self->_dispatch_rest_method( $c, $rest_method );
  92 }
  93
  94 sub _dispatch_rest_method {
  95     my $self        = shift;
  96     my $c           = shift;
  97     my $rest_method = shift;
  98     my $req         = $c->request;
  99
 100     my $controller = $c->component( $self->class );
 101
 102     my ($code, $name);
 103
 104     # Execute normal 'foo' action.
 105     $c->execute( $self->class, $self, @{ $req->args } );
 106
 107     # Common case, for foo_GET etc
 108     if ( $code = $controller->action_for($rest_method) ) {
 109         return $c->forward( $code,  $req->args ); # Forward to foo_GET if it's an action
 110     }
 111     elsif ($code = $controller->can($rest_method)) {
 112         $name = $rest_method; # Stash name and code to run 'foo_GET' like an action below.
 113     }
 114
 115     # Generic handling for foo_*
 116     if (!$code) {
 117         my $code_action = {
 118             OPTIONS => sub {
 119                 $name = $rest_method;
 120                 $code = sub { $self->_return_options($self->name, @_) };
 121             },
 122             HEAD => sub {
 123               $rest_method =~ s{_HEAD$}{_GET}i;
 124               $self->_dispatch_rest_method($c, $rest_method);
 125             },
 126             default => sub {
 127                 # Otherwise, not implemented.
 128                 $name = $self->name . "_not_implemented";
 129                 $code = $controller->can($name) # User method
 130                     # Generic not implemented
 131                     || sub { $self->_return_not_implemented($self->name, @_) };
 132             },
 133         };
 134         my ( $http_method, $action_name ) = ( $rest_method, $self->name );
 135         $http_method =~ s{\Q$action_name\E\_}{};
 136         my $respond = ($code_action->{$http_method}
 137                        || $code_action->{'default'})->();
 138         return $respond unless $name;
 139     }
 140
 141     # localise stuff so we can dispatch the action 'as normal, but get
 142     # different stats shown, and different code run.
 143     # Also get the full path for the action, and make it look like a forward
 144     local $self->{code} = $code;
 145     my @name = split m{/}, $self->reverse;
 146     $name[-1] = $name;
 147     local $self->{reverse} = "-> " . join('/', @name);
 148
 149     $c->execute( $self->class, $self, @{ $req->args } );
 150 }
 151
 152 sub get_allowed_methods {
 153     my ( $self, $controller, $c, $name ) = @_;
 154     my $class = ref($controller) ? ref($controller) : $controller;
 155     my $methods = Class::Inspector->methods($class);
 156     return map { /^$name\_(.+)$/ } @$methods;
 157 };
 158
 159 sub _return_options {
 160     my ( $self, $method_name, $controller, $c) = @_;
 161     my @allowed = $self->get_allowed_methods($controller, $c, $method_name);
 162     $c->response->content_type('text/plain');
 163     $c->response->status(200);
 164     $c->response->header( 'Allow' => \@allowed );
 165     $c->response->body(q{});
 166 }
 167
 168 sub _return_not_implemented {
 169     my ( $self, $method_name, $controller, $c ) = @_;
 170
 171     my @allowed = $self->get_allowed_methods($controller, $c, $method_name);
 172     $c->response->content_type('text/plain');
 173     $c->response->status(405);
 174     $c->response->header( 'Allow' => \@allowed );
 175     $c->response->body( "Method "
 176           . $c->request->method
 177           . " not implemented for "
 178           . $c->uri_for( $method_name ) );
 179 }
 180
 181 __PACKAGE__->meta->make_immutable;
 182
 183 1;
 184
 185 =back
 186
 187 =head1 SEE ALSO
 188
 189 You likely want to look at L<Catalyst::Controller::REST>, which implements a
 190 sensible set of defaults for a controller doing REST.
 191
 192 This class automatically adds the L<Catalyst::TraitFor::Request::REST> role to
 193 your request class.  If you're writing a web application which provides RESTful
 194 responses and still needs to accommodate web browsers, you may prefer to use
 195 L<Catalyst::TraitFor::Request::REST::ForBrowsers> instead.
 196
 197 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 198
 199 =head1 TROUBLESHOOTING
 200
 201 =over 4
 202
 203 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 204
 205 A:  Most likely, you haven't set Content-type equal to "application/json", or
 206 one of the accepted return formats.  You can do this by setting it in your query
 207 accepted return formats.  You can do this by setting it in your query string
 208 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 209
 210 B<NOTE> Apache will refuse %2F unless configured otherwise.
 211 Make sure C<AllowEncodedSlashes On> is in your httpd.conf file in order
 212 for this to run smoothly.
 213
 214 =back
 215
 216 =head1 AUTHOR
 217
 218 Adam Jacob E<lt>adam@stalecoffee.orgE<gt>, with lots of help from mst and jrockway
 219
 220 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 221
 222 =head1 CONTRIBUTORS
 223
 224 Tomas Doran (t0m) E<lt>bobtfish@bobtfish.netE<gt>
 225
 226 John Goulah
 227
 228 Christopher Laco
 229
 230 Daisuke Maki E<lt>daisuke@endeworks.jpE<gt>
 231
 232 Hans Dieter Pearcey
 233
 234 Brian Phillips E<lt>bphillips@cpan.orgE<gt>
 235
 236 Dave Rolsky E<lt>autarch@urth.orgE<gt>
 237
 238 Luke Saunders
 239
 240 Arthur Axel "fREW" Schmidt E<lt>frioux@gmail.comE<gt>
 241
 242 J. Shirley E<lt>jshirley@gmail.comE<gt>
 243
 244 Gavin Henry E<lt>ghenry@surevoip.co.ukE<gt>
 245
 246 Gerv http://www.gerv.net/
 247
 248 Colin Newell <colin@opusvl.com>
 249
 250 Wallace Reis E<lt>wreis@cpan.orgE<gt>
 251
 252 =head1 COPYRIGHT
 253
 254 Copyright (c) 2006-2012 the above named AUTHOR and CONTRIBUTORS
 255
 256 =head1 LICENSE
 257
 258 You may distribute this code under the same terms as Perl itself.
 259
 260 =cut
 261