lib/Catalyst/Action/Deserialize/JSON.pm

   1 package Catalyst::Action::Deserialize::JSON;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5 use Scalar::Util qw(openhandle);
   6
   7 extends 'Catalyst::Action';
   8 use JSON::MaybeXS qw(JSON);
   9
  10 # VERSION
  11
  12 sub execute {
  13     my $self = shift;
  14     my ( $controller, $c, $test ) = @_;
  15
  16     my $rbody;
  17
  18     # could be a string or a FH
  19     if ( my $body = $c->request->body ) {
  20         if(openhandle $body) {
  21             seek($body, 0, 0); # in case something has already read from it
  22             while ( defined( my $line = <$body> ) ) {
  23                 $rbody .= $line;
  24             }
  25         } else {
  26             $rbody = $body;
  27         }
  28     }
  29
  30     if ( $rbody ) {
  31         my $json = JSON->new->utf8;
  32         if (my $options = $controller->{json_options}) {
  33             foreach my $opt (keys %$options) {
  34                 $json->$opt( $options->{$opt} );
  35             }
  36         }
  37         my $rdata = eval { $json->decode( $rbody ) };
  38         if ($@) {
  39             return $@;
  40         }
  41         $c->request->data($rdata);
  42     } else {
  43         $c->log->debug(
  44             'I would have deserialized, but there was nothing in the body!')
  45             if $c->debug;
  46     }
  47     return 1;
  48 }
  49
  50 __PACKAGE__->meta->make_immutable;
  51
  52 1;